net-mail/postfix-logwatch/postfix-logwatch-1.39.07.ebuild

   1 # Copyright 1999-2013 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: /var/cvsroot/gentoo-x86/net-mail/postfix-logwatch/postfix-logwatch-1.39.07.ebuild,v 1.1 2013/12/03 13:28:25 mjo Exp $
   4
   5 EAPI=5
   6
   7 DESCRIPTION="A log analyzer for postfix"
   8 HOMEPAGE="http://logreporters.sourceforge.net/"
   9 SRC_URI="mirror://sourceforge/logreporters/${P}.tgz"
  10
  11 LICENSE="GPL-2"
  12 SLOT="0"
  13 KEYWORDS="~amd64"
  14 IUSE="logwatch"
  15
  16 RDEPEND="dev-lang/perl"
  17
  18 src_compile() {
  19         # The default make target just outputs instructions. We don't want
  20         # the user to see these, so we avoid the default emake.
  21         :
  22 }
  23
  24 src_install() {
  25         # There are two different "versions" of the package in the
  26         # tarball: a standalone executable and a logwatch filter. The
  27         # standalone is always installed. However, the logwatch filter is
  28         # only installed with USE="logwatch".
  29         dodoc Bugs Changes README ${PN}.conf-topn
  30         doman ${PN}.1
  31         dobin ${PN}
  32         insinto /etc
  33         doins ${PN}.conf
  34
  35         if use logwatch; then
  36                 # Remove the taint mode (-T) switch from the header of the
  37                 # standalone executable, and save the result as our logwatch
  38                 # filter.
  39                 sed 's~^#!/usr/bin/perl -T$~#!/usr/bin/perl~' ${PN} > postfix \
  40                         || die "failed to remove the perl taint switch"
  41
  42                 insinto /etc/logwatch/scripts/services
  43                 doins postfix
  44
  45                 insinto /etc/logwatch/conf/services
  46                 newins ${PN}.conf postfix.conf
  47         fi
  48 }