net-mail/amavis-logwatch/amavis-logwatch-1.51.02.ebuild

   1 # Copyright 1999-2013 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI=5
   6
   7 DESCRIPTION="A log analyzer for amavisd-new"
   8 HOMEPAGE="http://logreporters.sourceforge.net/"
   9 SRC_URI="mirror://sourceforge/logreporters/${P}.tgz"
  10
  11 LICENSE="MIT"
  12 SLOT="0"
  13 KEYWORDS="~amd64"
  14
  15 # >=sys-apps/logwatch-7.4.0_p170 ships our logwatch scripts and will
  16 # thus obsolete this use flag.
  17 IUSE="logwatch"
  18
  19 RDEPEND="dev-lang/perl"
  20
  21 src_prepare() {
  22         # Replace the default config file location with ours.
  23         local cfg_default='/usr/local/etc/${progname_prefix}-logwatch.conf'
  24         local cfg_gentoo='/etc/${progname_prefix}-logwatch.conf';
  25         sed -i "s~${cfg_default}~${cfg_gentoo}~" ${PN} \
  26                 || die 'failed to update the default config location'
  27 }
  28
  29 src_compile() {
  30         # The default make target just outputs instructions. We don't want
  31         # the user to see these, so we avoid the default emake.
  32         :
  33 }
  34
  35 src_install() {
  36         # There are two different "versions" of the package in the
  37         # tarball: a standalone executable and a logwatch filter. The
  38         # standalone is always installed. However, the logwatch filter is
  39         # only installed with USE="logwatch".
  40         dodoc Bugs Changes README
  41         doman ${PN}.1
  42         dobin ${PN}
  43         insinto /etc
  44         doins ${PN}.conf
  45
  46         if use logwatch; then
  47                 # Remove the taint mode (-T) switch from the header of the
  48                 # standalone executable, and save the result as our logwatch
  49                 # filter.
  50                 #
  51                 # We don't do this for the standalone script because it's nice
  52                 # to have the taint flag when it works.
  53                 #
  54                 sed 's~^#!/usr/bin/perl -T$~#!/usr/bin/perl~' ${PN} > amavis \
  55                         || die 'failed to remove the perl taint switch'
  56
  57                 insinto /etc/logwatch/scripts/services
  58                 doins amavis
  59
  60                 insinto /etc/logwatch/conf/services
  61                 newins ${PN}.conf amavis.conf
  62         fi
  63 }