net-dns/djbdns/djbdns-1.05-r27.ebuild

   1 # Copyright 1999-2013 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: /var/cvsroot/gentoo-x86/net-dns/djbdns/djbdns-1.05-r27.ebuild,v 1.1 2013/06/23 18:53:24 pinkbyte Exp $
   4
   5 EAPI="2"
   6 inherit eutils flag-o-matic toolchain-funcs user
   7
   8 DESCRIPTION="Excellent high-performance DNS services"
   9 HOMEPAGE="http://cr.yp.to/djbdns.html"
  10 IPV6_PATCH="test23"
  11
  12 SRC_URI="http://cr.yp.to/djbdns/${P}.tar.gz
  13         ipv6? ( http://www.fefe.de/dns/${P}-${IPV6_PATCH}.diff.bz2 )"
  14
  15 SLOT="0"
  16 LICENSE="public-domain"
  17 KEYWORDS="~alpha ~amd64 ~hppa ~mips ~ppc ~ppc64 ~sparc ~x86"
  18 IUSE="doc ipv6 selinux static"
  19
  20 DEPEND=""
  21 RDEPEND="${DEPEND}
  22         virtual/daemontools
  23         sys-apps/ucspi-tcp
  24         doc? ( app-doc/djbdns-man )
  25         selinux? ( sec-policy/selinux-djbdns )
  26 "
  27
  28 src_prepare() {
  29         epatch \
  30                 "${FILESDIR}/headtail.patch" \
  31                 "${FILESDIR}/dnsroots.patch" \
  32                 "${FILESDIR}/dnstracesort.patch" \
  33                 "${FILESDIR}/string_length_255.patch"
  34
  35         # Fix CVE2009-0858
  36         epatch "${FILESDIR}/CVE2009-0858_0001-check-response-domain-name-length.patch"
  37
  38         if use ipv6; then
  39                 elog "At present dnstrace does NOT support IPv6. It will"\
  40                      "be compiled without IPv6 support."
  41                 cp -pR "${S}" "${S}-noipv6"
  42                 # Careful -- >=test21 of the IPv6 patch includes the errno patch
  43                 epatch "${DISTDIR}/${P}-${IPV6_PATCH}.diff.bz2"
  44
  45                 # Fix CVE2008-4392
  46                 epatch \
  47                         "${FILESDIR}/CVE2008-4392_0001-dnscache-merge-similar-outgoing-queries-ipv6.patch" \
  48                         "${FILESDIR}/CVE2008-4392_0002-dnscache-cache-soa-records-ipv6.patch" \
  49                         "${FILESDIR}/makefile-parallel.patch"
  50
  51                 cd "${S}-noipv6"
  52         fi
  53
  54         # Fix CVE2008-4392
  55         epatch \
  56                 "${FILESDIR}/CVE2008-4392_0001-dnscache-merge-similar-outgoing-queries.patch" \
  57                 "${FILESDIR}/CVE2008-4392_0002-dnscache-cache-soa-records.patch"
  58
  59         epatch "${FILESDIR}/${PV}-errno.patch"
  60
  61         epatch_user
  62 }
  63
  64 src_compile() {
  65         use static && append-ldflags -static
  66         echo "$(tc-getCC) ${CFLAGS}" > conf-cc
  67         echo "$(tc-getCC) ${LDFLAGS}" > conf-ld
  68         echo "/usr" > conf-home
  69         emake || die "emake failed"
  70
  71         # If djbdns is compiled with IPv6 support, it breaks dnstrace.
  72         # Therefore we must compile dnstrace separately without IPv6
  73         # support.
  74         if use ipv6; then
  75                 elog "Compiling dnstrace without ipv6 support"
  76                 cd "${S}-noipv6"
  77                 echo "$(tc-getCC) ${CFLAGS}" > conf-cc
  78                 echo "$(tc-getCC) ${LDFLAGS}" > conf-ld
  79                 echo "/usr" > conf-home
  80                 emake dnstrace || die "emake failed"
  81         fi
  82 }
  83
  84 src_install() {
  85         insinto /etc
  86         doins dnsroots.global || die
  87
  88         into /usr
  89         dobin *-conf dnscache tinydns walldns rbldns pickdns axfrdns \
  90                 *-get *-data *-edit dnsip dnsipq dnsname dnstxt dnsmx \
  91                 dnsfilter random-ip dnsqr dnsq dnstrace dnstracesort || die
  92
  93         if use ipv6; then
  94                 dobin dnsip6 dnsip6q "${S}-noipv6/dnstrace" || die
  95         fi
  96
  97         dodoc CHANGES FILES README SYSDEPS TARGETS TODO VERSION || die
  98
  99         dobin "${FILESDIR}/dnscache-setup" || die
 100         dobin "${FILESDIR}/tinydns-setup" || die
 101         dobin "${FILESDIR}/djbdns-setup" || die
 102 }
 103
 104 pkg_preinst() {
 105         # The nofiles group is no longer provided by baselayout.
 106         # Share it with qmail if possible.
 107         enewgroup nofiles 200
 108
 109         enewuser dnscache -1 -1 -1 nofiles
 110         enewuser dnslog -1 -1 -1 nofiles
 111         enewuser tinydns -1 -1 -1 nofiles
 112 }
 113
 114 pkg_postinst() {
 115         elog "Use dnscache-setup & tinydns-setup or djbdns-setup to configure djbdns."
 116 }