net-dns/djbdns/djbdns-1.05-r24.ebuild

   1 # Copyright 1999-2011 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: /var/cvsroot/gentoo-x86/net-dns/djbdns/djbdns-1.05-r24.ebuild,v 1.2 2011/04/04 16:57:45 c1pher Exp $
   4
   5 EAPI="2"
   6 inherit eutils flag-o-matic toolchain-funcs
   7
   8 DESCRIPTION="Excellent high-performance DNS services"
   9 HOMEPAGE="http://cr.yp.to/djbdns.html"
  10 IPV6_PATCH="test23"
  11
  12 SRC_URI="http://cr.yp.to/djbdns/${P}.tar.gz
  13         ipv6? ( http://www.fefe.de/dns/${P}-${IPV6_PATCH}.diff.bz2 )"
  14
  15 SLOT="0"
  16 LICENSE="public-domain"
  17 KEYWORDS="~alpha ~amd64 ~hppa ~mips ~ppc ~ppc64 ~sparc ~x86"
  18 IUSE="doc ipv6 selinux static"
  19
  20 DEPEND=""
  21 RDEPEND="${DEPEND}
  22         virtual/daemontools
  23         sys-apps/ucspi-tcp
  24         doc? ( app-doc/djbdns-man )
  25         selinux? ( sec-policy/selinux-djbdns )
  26 "
  27
  28 src_prepare() {
  29         echo
  30         elog 'Several patches have been dropped from this djbdns ebuild revision.'
  31         elog 'Please use the DJBDNS_PATCH_DIR variable to specify a directory'
  32         elog 'of custom patches.'
  33         elog
  34         elog 'Some of them can be found at http://tinydns.org/ or'
  35         elog 'http://homepages.tesco.net/J.deBoynePollard/Softwares/djbdns/'
  36         elog
  37
  38         epatch \
  39                 "${FILESDIR}/headtail.patch" \
  40                 "${FILESDIR}/dnsroots.patch" \
  41                 "${FILESDIR}/dnstracesort.patch" \
  42                 "${FILESDIR}/string_length_255.patch"
  43
  44         # Fix CVE2009-0858
  45         epatch "${FILESDIR}/CVE2009-0858_0001-check-response-domain-name-length.patch"
  46
  47         if use ipv6; then
  48                 elog "At present dnstrace does NOT support IPv6. It will"\
  49                          "be compiled without IPv6 support."
  50                 cp -pR "${S}" "${S}-noipv6"
  51                 # Careful -- >=test21 of the IPv6 patch includes the errno patch
  52                 epatch "${DISTDIR}/${P}-${IPV6_PATCH}.diff.bz2"
  53
  54                 # Fix CVE2008-4392
  55                 epatch \
  56                         "${FILESDIR}/CVE2008-4392_0001-dnscache-merge-similar-outgoing-queries-ipv6.patch" \
  57                         "${FILESDIR}/CVE2008-4392_0002-dnscache-cache-soa-records-ipv6.patch"
  58
  59                 cd "${S}-noipv6"
  60         fi
  61
  62         # Fix CVE2008-4392
  63         epatch \
  64                 "${FILESDIR}/CVE2008-4392_0001-dnscache-merge-similar-outgoing-queries.patch" \
  65                 "${FILESDIR}/CVE2008-4392_0002-dnscache-cache-soa-records.patch"
  66
  67         epatch "${FILESDIR}/${PV}-errno.patch"
  68
  69         if [[ -n "${DJBDNS_PATCH_DIR}" && -d "${DJBDNS_PATCH_DIR}" ]]
  70         then
  71                 echo
  72                 ewarn "You enabled custom patches from ${DJBDNS_PATCH_DIR}."
  73                 ewarn "Be warned that you won't get any support when using "
  74                 ewarn "this feature. You're on your own from now!"
  75                 echo
  76                 ebeep
  77                 cd "${S}" && epatch "${DJBDNS_PATCH_DIR}/"*
  78         fi
  79 }
  80
  81 src_compile() {
  82         use static && append-ldflags -static
  83         echo "$(tc-getCC) ${CFLAGS}" > conf-cc
  84         echo "$(tc-getCC) ${LDFLAGS}" > conf-ld
  85         echo "/usr" > conf-home
  86         emake || die "emake failed"
  87
  88         # If djbdns is compiled with IPv6 support, it breaks dnstrace.
  89         # Therefore we must compile dnstrace separately without IPv6
  90         # support.
  91         if use ipv6; then
  92                 elog "Compiling dnstrace without ipv6 support"
  93                 cd "${S}-noipv6"
  94                 echo "$(tc-getCC) ${CFLAGS}" > conf-cc
  95                 echo "$(tc-getCC) ${LDFLAGS}" > conf-ld
  96                 echo "/usr" > conf-home
  97                 emake dnstrace || die "emake failed"
  98         fi
  99 }
 100
 101 src_install() {
 102         insinto /etc
 103         doins dnsroots.global || die
 104
 105         into /usr
 106         dobin *-conf dnscache tinydns walldns rbldns pickdns axfrdns \
 107                 *-get *-data *-edit dnsip dnsipq dnsname dnstxt dnsmx \
 108                 dnsfilter random-ip dnsqr dnsq dnstrace dnstracesort || die
 109
 110         if use ipv6; then
 111                 dobin dnsip6 dnsip6q "${S}-noipv6/dnstrace" || die
 112         fi
 113
 114         dodoc CHANGES FILES README SYSDEPS TARGETS TODO VERSION || die
 115
 116         dobin "${FILESDIR}/dnscache-setup" || die
 117         dobin "${FILESDIR}/tinydns-setup" || die
 118         newbin "${FILESDIR}/djbdns-setup-r17" djbdns-setup || die
 119 }
 120
 121 pkg_preinst() {
 122         # The nofiles group is provided by baselayout
 123         enewuser dnscache -1 -1 -1 nofiles
 124         enewuser dnslog -1 -1 -1 nofiles
 125         enewuser tinydns -1 -1 -1 nofiles
 126 }
 127
 128 pkg_postinst() {
 129         elog "Use dnscache-setup & tinydns-setup or djbdns-setup to configure djbdns."
 130 }