net-dns/djbdns/djbdns-1.05-r23.ebuild

   1 # Copyright 1999-2012 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: /var/cvsroot/gentoo-x86/net-dns/djbdns/djbdns-1.05-r23.ebuild,v 1.10 2012/06/14 02:04:37 zmedico Exp $
   4
   5 IUSE="doc ipv6 selinux static"
   6
   7 inherit eutils flag-o-matic toolchain-funcs user
   8
   9 DESCRIPTION="Excellent high-performance DNS services"
  10 HOMEPAGE="http://cr.yp.to/djbdns.html"
  11 IPV6_PATCH="test23"
  12
  13 SRC_URI="
  14         http://cr.yp.to/djbdns/${P}.tar.gz
  15         ipv6? ( http://www.fefe.de/dns/${P}-${IPV6_PATCH}.diff.bz2 )
  16 "
  17
  18 SLOT="0"
  19 LICENSE="public-domain"
  20 KEYWORDS="alpha amd64 hppa ~mips ppc ppc64 sparc x86"
  21
  22 RDEPEND="
  23         virtual/daemontools
  24         sys-apps/ucspi-tcp
  25         doc? ( app-doc/djbdns-man )
  26         selinux? ( sec-policy/selinux-djbdns )
  27 "
  28
  29 src_unpack() {
  30         unpack "${P}.tar.gz"
  31         cd "${S}"
  32
  33         echo
  34         elog 'Several patches have been dropped from this djbdns ebuild revision.'
  35         elog 'Please use the DJBDNS_PATCH_DIR variable to specify a directory'
  36         elog 'of custom patches.'
  37         elog
  38         elog 'Some of them can be found at http://tinydns.org/ or'
  39         elog 'http://homepages.tesco.net/J.deBoynePollard/Softwares/djbdns/'
  40         elog
  41
  42         epatch \
  43                 "${FILESDIR}/headtail.patch" \
  44                 "${FILESDIR}/dnsroots.patch" \
  45                 "${FILESDIR}/dnstracesort.patch"
  46
  47         # Fix CVE2009-0858
  48         epatch "${FILESDIR}/CVE2009-0858_0001-check-response-domain-name-length.patch"
  49
  50         if use ipv6; then
  51                 elog "At present dnstrace does NOT support IPv6. It will"\
  52                      "be compiled without IPv6 support."
  53                 cp -pR "${S}" "${S}-noipv6"
  54                 # Careful -- >=test21 of the IPv6 patch includes the errno patch
  55                 epatch "${DISTDIR}/${P}-${IPV6_PATCH}.diff.bz2"
  56
  57                 # Fix CVE2008-4392
  58                 epatch \
  59                         "${FILESDIR}/CVE2008-4392_0001-dnscache-merge-similar-outgoing-queries-ipv6.patch" \
  60                         "${FILESDIR}/CVE2008-4392_0002-dnscache-cache-soa-records-ipv6.patch"
  61
  62                 cd "${S}-noipv6"
  63         fi
  64
  65         # Fix CVE2008-4392
  66         epatch \
  67                 "${FILESDIR}/CVE2008-4392_0001-dnscache-merge-similar-outgoing-queries.patch" \
  68                 "${FILESDIR}/CVE2008-4392_0002-dnscache-cache-soa-records.patch"
  69
  70         epatch "${FILESDIR}/${PV}-errno.patch"
  71
  72         if [[ -n "${DJBDNS_PATCH_DIR}" && -d "${DJBDNS_PATCH_DIR}" ]]
  73         then
  74                 echo
  75                 ewarn "You enabled custom patches from ${DJBDNS_PATCH_DIR}."
  76                 ewarn "Be warned that you won't get any support when using "
  77                 ewarn "this feature. You're on your own from now!"
  78                 echo
  79                 ebeep
  80                 cd "${S}" && epatch "${DJBDNS_PATCH_DIR}/"*
  81         fi
  82 }
  83
  84 src_compile() {
  85         use static && append-ldflags -static
  86         echo "$(tc-getCC) ${CFLAGS}" > conf-cc
  87         echo "$(tc-getCC) ${LDFLAGS}" > conf-ld
  88         echo "/usr" > conf-home
  89         emake -j1 || die "emake failed"
  90
  91         # If djbdns is compiled with IPv6 support, it breaks dnstrace.
  92         # Therefore we must compile dnstrace separately without IPv6
  93         # support.
  94         if use ipv6; then
  95                 elog "Compiling dnstrace without ipv6 support"
  96                 cd "${S}-noipv6"
  97                 echo "$(tc-getCC) ${CFLAGS}" > conf-cc
  98                 echo "$(tc-getCC) ${LDFLAGS}" > conf-ld
  99                 echo "/usr" > conf-home
 100                 emake -j1 dnstrace || die "emake failed"
 101         fi
 102 }
 103
 104 src_install() {
 105         insinto /etc
 106         doins dnsroots.global
 107
 108         into /usr
 109         dobin *-conf dnscache tinydns walldns rbldns pickdns axfrdns \
 110                 *-get *-data *-edit dnsip dnsipq dnsname dnstxt dnsmx \
 111                 dnsfilter random-ip dnsqr dnsq dnstrace dnstracesort
 112
 113         use ipv6 && dobin dnsip6 dnsip6q "${S}-noipv6/dnstrace"
 114
 115         dodoc CHANGES FILES README SYSDEPS TARGETS TODO VERSION
 116
 117         dobin "${FILESDIR}/dnscache-setup" || die
 118         dobin "${FILESDIR}/tinydns-setup" || die
 119         dobin "${FILESDIR}/djbdns-setup" || die
 120 }
 121
 122 pkg_setup() {
 123         # The nofiles group is provided by baselayout
 124         enewuser dnscache -1 -1 -1 nofiles
 125         enewuser dnslog -1 -1 -1 nofiles
 126         enewuser tinydns -1 -1 -1 nofiles
 127 }
 128
 129 pkg_postinst() {
 130         elog "Use dnscache-setup & tinydns-setup or djbdns-setup to configure djbdns."
 131 }