net-analyzer/linkchecker/linkchecker-9.2-r1.ebuild

   1 # Copyright 1999-2014 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI=5
   6
   7 PYTHON_COMPAT=( python2_7 )
   8 PYTHON_REQ_USE="sqlite?"
   9
  10 inherit bash-completion-r1 distutils-r1 eutils multilib
  11
  12 MY_PN="${PN/linkchecker/LinkChecker}"
  13 MY_P="${MY_PN}-${PV}"
  14
  15 DESCRIPTION="Check websites for broken links"
  16 HOMEPAGE="http://wummel.github.com/linkchecker/ http://pypi.python.org/pypi/linkchecker/"
  17 SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
  18
  19 LICENSE="GPL-2"
  20 SLOT="0"
  21 KEYWORDS="~amd64 ~x86 ~ppc-macos ~x64-solaris"
  22 IUSE="bash-completion clamav geoip gnome login sqlite X"
  23
  24 RDEPEND="
  25         dev-python/dnspython[${PYTHON_USEDEP}]
  26         >=dev-python/requests-2.2.1[${PYTHON_USEDEP}]
  27         bash-completion? ( dev-python/argcomplete[${PYTHON_USEDEP}] )
  28         clamav? ( app-antivirus/clamav )
  29         geoip? ( dev-python/geoip-python[${PYTHON_USEDEP}] )
  30         gnome? ( dev-python/pygtk:2[${PYTHON_USEDEP}] )
  31         login? ( dev-python/twill[${PYTHON_USEDEP}] )
  32         X? (
  33                 dev-python/PyQt4[X,help,${PYTHON_USEDEP}]
  34                 dev-python/qscintilla-python[${PYTHON_USEDEP}]
  35                 )"
  36 DEPEND="
  37         X? (
  38                 dev-qt/qthelp:4
  39                 dev-python/markdown2[${PYTHON_USEDEP}]
  40                 )"
  41
  42 RESTRICT="test"
  43
  44 S="${WORKDIR}/${MY_P}"
  45
  46 python_prepare_all() {
  47         local PATCHES=(
  48                 "${FILESDIR}"/${P}-unbundle.patch
  49                 )
  50
  51         emake -C doc/html
  52
  53         distutils-r1_python_prepare_all
  54 }
  55
  56 python_install_all() {
  57         DOCS=(
  58                 doc/upgrading.txt
  59                 doc/python3.txt
  60                 doc/changelog.txt
  61                 doc/development.txt
  62         )
  63         distutils-r1_python_install_all
  64         if ! use X; then
  65                 delete_gui() {
  66                                 rm -rf \
  67                                         "${ED}"/usr/bin/linkchecker-gui* \
  68                                         "${ED}"/$(python_get_sitedir)/linkcheck/gui* || die
  69                 }
  70                 python_foreach_impl delete_gui
  71         fi
  72         dohtml doc/html/*
  73         use bash-completion && dobashcomp config/linkchecker-completion
  74 }