src/OptionalConfiguration.hs

   1 {-# LANGUAGE DeriveDataTypeable #-}
   2 {-# LANGUAGE OverloadedStrings #-}
   3
   4 -- | An OptionalConfiguration is just like a 'Configuration', except
   5 --   all of its fields are optional. The user can set options in two
   6 --   places: the command-line, and a configuration file. Obviously if
   7 --   a parameter is set in one place, it doesn't need to be set in the
   8 --   other. Thus, the latter needs to be optional.
   9 --
  10
  11 module OptionalConfiguration (
  12   OptionalConfiguration(..),
  13   from_rc,
  14   merge_maybes )
  15 where
  16
  17 import qualified Data.Configurator as DC (
  18   Worth(Optional),
  19   load,
  20   lookup )
  21 import Data.Data ( Data )
  22 import Data.Typeable ( Typeable )
  23 import Data.Monoid ( Monoid(..) )
  24 import Paths_mailbox_count ( getSysconfDir )
  25 import System.Directory ( getHomeDirectory )
  26 import System.FilePath ( (</>) )
  27 import System.IO.Error ( catchIOError )
  28
  29
  30 -- | The same as Configuration, except everything is optional. It's easy to
  31 --   merge two of these by simply dropping the Nothings in favor of
  32 --   the Justs. The 'feed_hosts' are left un-maybed so that cmdargs
  33 --   can parse more than one of them.
  34 --
  35 data OptionalConfiguration =
  36   OptionalConfiguration {
  37     database :: Maybe String,
  38     detail   :: Maybe Bool,
  39     host     :: Maybe String,
  40     password :: Maybe String,
  41     port     :: Maybe Int,
  42     username :: Maybe String }
  43   deriving (Show, Data, Typeable)
  44
  45
  46 -- | Combine two Maybes into one, essentially mashing them
  47 --   together. We give precedence to the second argument when both are
  48 --   Justs.
  49 merge_maybes :: (Maybe a) -> (Maybe a) -> (Maybe a)
  50 merge_maybes Nothing Nothing   = Nothing
  51 merge_maybes (Just x) Nothing  = Just x
  52 merge_maybes Nothing (Just x)  = Just x
  53 merge_maybes (Just _) (Just y) = Just y
  54
  55
  56 -- | The Monoid instance for these lets us "combine" two
  57 --   OptionalConfigurations. The "combine" operation that we'd like to
  58 --   perform is, essentially, to mash them together. So if we have two
  59 --   OptionalConfigurations, each half full, we could combine them
  60 --   into one big one.
  61 --
  62 --   This is used to merge command-line and config-file settings.
  63 --
  64 instance Monoid OptionalConfiguration where
  65   -- | An empty OptionalConfiguration.
  66   mempty = OptionalConfiguration
  67              Nothing
  68              Nothing
  69              Nothing
  70              Nothing
  71              Nothing
  72              Nothing
  73
  74   -- | Combine @cfg1@ and @cfg2@, giving precedence to @cfg2@.
  75   cfg1 `mappend` cfg2 =
  76     OptionalConfiguration
  77       (merge_maybes (database cfg1) (database cfg2))
  78       (merge_maybes (detail cfg1) (detail cfg2))
  79       (merge_maybes (host cfg1) (host cfg2))
  80       (merge_maybes (password cfg1) (password cfg2))
  81       (merge_maybes (port cfg1) (port cfg2))
  82       (merge_maybes (username cfg1) (username cfg2))
  83
  84
  85 -- | Obtain an OptionalConfiguration from mailbox-countrc in either
  86 --   the global configuration directory or the user's home
  87 --   directory. The one in $HOME is prefixed by a dot so that it is
  88 --   hidden.
  89 --
  90 --   We make an attempt at cross-platform compatibility; we will try
  91 --   to find the correct directory even on Windows. But if the calls
  92 --   to getHomeDirectory/getSysconfDir fail for whatever reason, we
  93 --   fall back to using the Unix-specific /etc and $HOME.
  94 --
  95 from_rc :: IO OptionalConfiguration
  96 from_rc = do
  97   etc  <- catchIOError getSysconfDir (\e -> do
  98                                         putStrLn $ "ERROR: " ++ (show e)
  99                                         return "/etc")
 100   home <- catchIOError getHomeDirectory (\e -> do
 101                                            putStrLn $ "ERROR: " ++ (show e)
 102                                            return "$(HOME)")
 103   let global_config_path = etc </> "mailbox-countrc"
 104   let user_config_path = home </> ".mailbox-countrc"
 105   cfg <- DC.load [ DC.Optional global_config_path,
 106                    DC.Optional user_config_path ]
 107   cfg_database <- DC.lookup cfg "database"
 108   cfg_detail <- DC.lookup cfg "detail"
 109   cfg_host <- DC.lookup cfg "host"
 110   cfg_password <- DC.lookup cfg "password"
 111   cfg_port <- DC.lookup cfg "port"
 112   cfg_username <- DC.lookup cfg "username"
 113
 114   return $ OptionalConfiguration
 115              cfg_database
 116              cfg_detail
 117              cfg_host
 118              cfg_password
 119              cfg_port
 120              cfg_username