src/TSN/XML/Weather.hs

   1 {-# LANGUAGE FlexibleInstances #-}
   2 {-# LANGUAGE GADTs #-}
   3 {-# LANGUAGE QuasiQuotes #-}
   4 {-# LANGUAGE RecordWildCards #-}
   5 {-# LANGUAGE TemplateHaskell #-}
   6 {-# LANGUAGE TypeFamilies #-}
   7
   8 -- | Parse TSN XML for the DTD \"weatherxml.dtd\". Each document
   9 --   contains a bunch of forecasts, which each contain zero or more
  10 --   leagues, which in turn (each) contain a bunch of listings.
  11 --
  12 module TSN.XML.Weather (
  13   dtd,
  14   is_type1,
  15   pickle_message,
  16   teams_are_normal,
  17   -- * Tests
  18   weather_tests,
  19   -- * WARNING: these are private but exported to silence warnings
  20   WeatherConstructor(..),
  21   WeatherDetailedWeatherListingItemConstructor(..),
  22   WeatherForecastConstructor(..),
  23   WeatherForecastListingConstructor(..) )
  24 where
  25
  26 -- System imports.
  27 import Control.Monad ( forM_ )
  28 import Data.Time ( UTCTime )
  29 import Data.Tuple.Curry ( uncurryN )
  30 import Database.Groundhog (
  31   countAll,
  32   deleteAll,
  33   insert_,
  34   migrate,
  35   runMigration,
  36   silentMigrationLogger )
  37 import Database.Groundhog.Core ( DefaultKey )
  38 import Database.Groundhog.Generic ( runDbConn )
  39 import Database.Groundhog.Sqlite ( withSqliteConn )
  40 import Database.Groundhog.TH (
  41   groundhog,
  42   mkPersist )
  43 import Test.Tasty ( TestTree, testGroup )
  44 import Test.Tasty.HUnit ( (@?=), testCase )
  45 import Text.XML.HXT.Core (
  46   PU,
  47   XmlTree,
  48   (/>),
  49   (>>>),
  50   addNav,
  51   descendantAxis,
  52   filterAxis,
  53   followingSiblingAxis,
  54   hasName,
  55   readDocument,
  56   remNav,
  57   runLA,
  58   runX,
  59   xp8Tuple,
  60   xp9Tuple,
  61   xpAttr,
  62   xpElem,
  63   xpInt,
  64   xpList,
  65   xpOption,
  66   xpPair,
  67   xpText,
  68   xpTriple,
  69   xpWrap )
  70
  71 -- Local imports.
  72 import TSN.Codegen (
  73   tsn_codegen_config )
  74 import TSN.DbImport ( DbImport(..), ImportResult(..), run_dbmigrate )
  75 import TSN.Picklers ( xp_datetime, xp_gamedate, xp_time_stamp )
  76 import TSN.XmlImport ( XmlImport(..), XmlImportFk(..) )
  77 import Xml (
  78   Child(..),
  79   FromXml(..),
  80   FromXmlFk(..),
  81   ToDb(..),
  82   parse_opts,
  83   pickle_unpickle,
  84   unpickleable,
  85   unsafe_unpickle )
  86
  87
  88
  89 -- | The DTD to which this module corresponds. Used to invoke dbimport.
  90 --
  91 dtd :: String
  92 dtd = "weatherxml.dtd"
  93
  94
  95 --
  96 -- DB/XML Data types
  97 --
  98
  99 -- * WeatherForecastListing/WeatherForecastListingXml
 100
 101 -- | XML representation of a weather forecast listing.
 102 --
 103 data WeatherForecastListingXml =
 104   WeatherForecastListingXml {
 105     xml_teams :: String,
 106     xml_weather :: String }
 107   deriving (Eq, Show)
 108
 109
 110 -- | Database representation of a weather forecast listing. The
 111 --   'db_league_name' field should come from the containing \<league\>
 112 --   element which is not stored in the database.
 113 --
 114 data WeatherForecastListing =
 115   WeatherForecastListing {
 116     db_weather_forecasts_id :: DefaultKey WeatherForecast,
 117     db_league_name :: Maybe String,
 118     db_teams :: String,
 119     db_weather :: String }
 120
 121
 122 -- | We don't make 'WeatherForecastListingXml' an instance of
 123 --   'FromXmlFk' because it needs some additional information, namely
 124 --   the league name from its containing \<league\> element.
 125 --
 126 --   When supplied with a forecast id and a league name, this will
 127 --   turn an XML listing into a database one.
 128 --
 129 from_xml_fk_league :: DefaultKey WeatherForecast
 130                    -> (Maybe String)
 131                    -> WeatherForecastListingXml
 132                    -> WeatherForecastListing
 133 from_xml_fk_league fk ln WeatherForecastListingXml{..} =
 134     WeatherForecastListing {
 135       db_weather_forecasts_id = fk,
 136       db_league_name = ln,
 137       db_teams = xml_teams,
 138       db_weather = xml_weather }
 139
 140
 141 -- * WeatherLeague
 142
 143 -- | XML representation of a league, as they appear in the weather
 144 --   documents. There is no associated database representation because
 145 --   the league element really adds no information besides its own
 146 --   (usually empty) name. The leagues contain listings, so we
 147 --   associate the league name with each listing instead.
 148 --
 149 data WeatherLeague =
 150   WeatherLeague {
 151     league_name :: Maybe String,
 152     listings    :: [WeatherForecastListingXml] }
 153   deriving (Eq, Show)
 154
 155
 156 -- * WeatherForecast/WeatherForecastXml
 157
 158 -- | Database representation of a weather forecast.
 159 --
 160 data WeatherForecast =
 161   WeatherForecast {
 162     db_weather_id :: DefaultKey Weather,
 163     db_game_date :: UTCTime }
 164
 165
 166 -- | XML representation of a weather forecast.
 167 --
 168 data WeatherForecastXml =
 169   WeatherForecastXml {
 170     xml_game_date :: UTCTime,
 171     xml_leagues :: [WeatherLeague] }
 172   deriving (Eq, Show)
 173
 174
 175 instance ToDb WeatherForecastXml where
 176   -- | The database representation of a 'WeatherForecastXml' is a
 177   --   'WeatherForecast'.
 178   --
 179   type Db WeatherForecastXml = WeatherForecast
 180
 181
 182 instance Child WeatherForecastXml where
 183   -- | The database type containing a 'WeatherForecastXml' is
 184   --   'Weather'.
 185   type Parent WeatherForecastXml = Weather
 186
 187
 188 instance FromXmlFk WeatherForecastXml where
 189
 190   -- | To convert a 'WeatherForecastXml' into a 'WeatherForecast', we
 191   --   add the foreign key to the containing 'Weather', and copy the
 192   --   game date.
 193   --
 194   from_xml_fk fk WeatherForecastXml{..} =
 195     WeatherForecast {
 196       db_weather_id  = fk,
 197       db_game_date   = xml_game_date }
 198
 199
 200 -- | This allows us to call 'insert_xml' on an 'WeatherForecastXml'
 201 --   without first converting it to the database representation.
 202 --
 203 instance XmlImportFk WeatherForecastXml
 204
 205 -- * WeatherDetailedWeatherXml
 206
 207 -- | XML Representation of a \<Detailed_Weather\>, which just contains
 208 --   a bunch iof \<DW_Listing\>s. There is no associated database type
 209 --   since these don't really contain any information.
 210 --
 211 data WeatherDetailedWeatherXml =
 212   WeatherDetailedWeatherXml {
 213     xml_detailed_listings :: [WeatherDetailedWeatherListingXml] }
 214   deriving (Eq, Show)
 215
 216
 217 -- * WeatherDetailedWeatherXml
 218
 219 -- | XML Representation of a \<DW_Listing\>. The sport and sport code
 220 --   come as attributes, but then these just contain a bunch of
 221 --   \<Item\>s. There is no associated database type since these don't
 222 --   contain much information. The sport we already know from the
 223 --   \<message\>, while the sport code is ignored since it's already
 224 --   present in each \<Item\>s.
 225 --
 226 data WeatherDetailedWeatherListingXml =
 227   WeatherDetailedWeatherListingXml {
 228     xml_dtl_listing_sport :: String,
 229     xml_dtl_listing_sport_code :: String,
 230     xml_items :: [WeatherDetailedWeatherListingItemXml] }
 231   deriving (Eq, Show)
 232
 233 -- * WeatherDetailedWeatherListingItem / WeatherDetailedWeatherListingItemXml
 234
 235 -- | Database representation of a detailed weather item. The away/home
 236 --   teams don't use the representation in "TSN.Team" because all
 237 --   we're given is a name, and a team id is required for "TSN.Team".
 238 --
 239 --   We also drop the sport name, because it's given in the parent
 240 --   'Weather'.
 241 --
 242 data WeatherDetailedWeatherListingItem =
 243   WeatherDetailedWeatherListingItem {
 244     db_dtl_weather_id :: DefaultKey Weather, -- ^ Avoid name collision by
 245                                              --   using \"dtl\" prefix.
 246     db_sport_code :: String,
 247     db_game_id :: Int,
 248     db_dtl_game_date :: UTCTime, -- ^ Avoid name clash with \"dtl\" prefix
 249     db_away_team :: String,
 250     db_home_team :: String,
 251     db_weather_type :: Int,
 252     db_description :: String,
 253     db_temp_adjust :: Maybe String,
 254     db_temperature :: Int }
 255
 256
 257 -- | XML representation of a detailed weather item. Same as the
 258 --   database representation, only without the foreign key and the
 259 --   sport name that comes from the containing listing.
 260 data WeatherDetailedWeatherListingItemXml =
 261   WeatherDetailedWeatherListingItemXml {
 262     xml_sport_code :: String,
 263     xml_game_id :: Int,
 264     xml_dtl_game_date :: UTCTime,
 265     xml_away_team :: String,
 266     xml_home_team :: String,
 267     xml_weather_type :: Int,
 268     xml_description :: String,
 269     xml_temp_adjust :: Maybe String,
 270     xml_temperature :: Int }
 271   deriving (Eq, Show)
 272
 273
 274 instance ToDb WeatherDetailedWeatherListingItemXml where
 275   -- | Our database analogue is a 'WeatherDetailedWeatherListingItem'.
 276   type Db WeatherDetailedWeatherListingItemXml =
 277     WeatherDetailedWeatherListingItem
 278
 279 instance Child WeatherDetailedWeatherListingItemXml where
 280   -- | We skip two levels of containers and say that the items belong
 281   --   to the top-level 'Weather'.
 282   type Parent WeatherDetailedWeatherListingItemXml = Weather
 283
 284 instance FromXmlFk WeatherDetailedWeatherListingItemXml where
 285   -- | To convert from the XML to database representation, we simply
 286   --   add the foreign key (to Weather) and copy the rest of the fields.
 287   from_xml_fk fk WeatherDetailedWeatherListingItemXml{..} =
 288     WeatherDetailedWeatherListingItem {
 289       db_dtl_weather_id = fk,
 290       db_sport_code = xml_sport_code,
 291       db_game_id = xml_game_id,
 292       db_dtl_game_date = xml_dtl_game_date,
 293       db_away_team = xml_away_team,
 294       db_home_team = xml_home_team,
 295       db_weather_type = xml_weather_type,
 296       db_description = xml_description,
 297       db_temp_adjust = xml_temp_adjust,
 298       db_temperature = xml_temperature }
 299
 300 -- | This allows us to insert the XML representation directly without
 301 --   having to do the manual XML -\> DB conversion.
 302 --
 303 instance XmlImportFk WeatherDetailedWeatherListingItemXml
 304
 305 -- * Weather/Message
 306
 307 -- | The database representation of a weather message. We don't
 308 -- contain the forecasts or the detailed weather since those are
 309 -- foreigned-keyed to us.
 310 --
 311 data Weather =
 312   Weather {
 313     db_xml_file_id :: Int,
 314     db_sport :: String,
 315     db_title :: String,
 316     db_time_stamp :: UTCTime }
 317
 318
 319 -- | The XML representation of a weather message.
 320 --
 321 data Message =
 322   Message {
 323     xml_xml_file_id :: Int,
 324     xml_heading :: String,
 325     xml_category :: String,
 326     xml_sport :: String,
 327     xml_title :: String,
 328     xml_forecasts :: [WeatherForecastXml],
 329     xml_detailed_weather :: Maybe WeatherDetailedWeatherXml,
 330     xml_time_stamp :: UTCTime }
 331   deriving (Eq, Show)
 332
 333 instance ToDb Message where
 334   -- | The database representation of 'Message' is 'Weather'.
 335   --
 336   type Db Message = Weather
 337
 338 instance FromXml Message where
 339   -- | To get a 'Weather' from a 'Message', we drop a bunch of
 340   --   unwanted fields.
 341   --
 342   from_xml Message{..} =
 343     Weather {
 344       db_xml_file_id = xml_xml_file_id,
 345       db_sport = xml_sport,
 346       db_title = xml_title,
 347       db_time_stamp = xml_time_stamp }
 348
 349 -- | This allows us to insert the XML representation 'Message'
 350 --   directly.
 351 --
 352 instance XmlImport Message
 353
 354
 355 --
 356 -- * Database stuff
 357 --
 358
 359 mkPersist tsn_codegen_config [groundhog|
 360 - entity: Weather
 361   constructors:
 362     - name: Weather
 363       uniques:
 364         - name: unique_weather
 365           type: constraint
 366           # Prevent multiple imports of the same message.
 367           fields: [db_xml_file_id]
 368
 369 - entity: WeatherForecast
 370   dbName: weather_forecasts
 371   constructors:
 372     - name: WeatherForecast
 373       fields:
 374         - name: db_weather_id
 375           reference:
 376             onDelete: cascade
 377
 378 - entity: WeatherForecastListing
 379   dbName: weather_forecast_listings
 380   constructors:
 381     - name: WeatherForecastListing
 382       fields:
 383         - name: db_weather_forecasts_id
 384           reference:
 385             onDelete: cascade
 386
 387 # We rename the two fields that needed a "dtl" prefix to avoid a name clash.
 388 - entity: WeatherDetailedWeatherListingItem
 389   dbName: weather_detailed_items
 390   constructors:
 391     - name: WeatherDetailedWeatherListingItem
 392       fields:
 393         - name: db_dtl_weather_id
 394           dbName: weather_id
 395           reference:
 396             onDelete: cascade
 397         - name: db_dtl_game_date
 398           dbName: game_date
 399
 400 |]
 401
 402
 403
 404 -- | There are two different types of documents that claim to be
 405 --   \"weatherxml.dtd\". The first, more common type has listings
 406 --   within forecasts. The second type has forecasts within
 407 --   listings. Clearly we can't parse both of these using the same
 408 --   parser!
 409 --
 410 --   For now we're simply punting on the issue and refusing to parse
 411 --   the second type. This will check the given @xmltree@ to see if
 412 --   there are any forecasts contained within listings. If there are,
 413 --   then it's the second type that we don't know what to do with.
 414 --
 415 is_type1 :: XmlTree -> Bool
 416 is_type1 xmltree =
 417   case elements of
 418     [] -> True
 419     _  -> False
 420   where
 421     parse :: XmlTree -> [XmlTree]
 422     parse = runLA $  hasName "/"
 423                   /> hasName "message"
 424                   /> hasName "listing"
 425                   /> hasName "forecast"
 426
 427     elements = parse xmltree
 428
 429
 430 -- | Some weatherxml documents even have the Home/Away teams in the
 431 --   wrong order. We can't parse that! This next bit of voodoo detects
 432 --   whether or not there are any \<HomeTeam\> elements that are
 433 --   directly followed by sibling \<AwayTeam\> elements. This is the
 434 --   opposite of the usual order.
 435 --
 436 teams_are_normal :: XmlTree -> Bool
 437 teams_are_normal xmltree =
 438   case elements of
 439     [] -> True
 440     _  -> False
 441   where
 442     parse :: XmlTree -> [XmlTree]
 443     parse = runLA $  hasName "/"
 444                   /> hasName "message"
 445                   /> hasName "Detailed_Weather"
 446                   /> hasName "DW_Listing"
 447                   /> hasName "Item"
 448                   >>> addNav
 449                   >>> descendantAxis
 450                   >>> filterAxis (hasName "HomeTeam")
 451                   >>> followingSiblingAxis
 452                   >>> remNav
 453                   >>> hasName "AwayTeam"
 454
 455     elements = parse xmltree
 456
 457
 458 instance DbImport Message where
 459   dbmigrate _ =
 460     run_dbmigrate $ do
 461       migrate (undefined :: Weather)
 462       migrate (undefined :: WeatherForecast)
 463       migrate (undefined :: WeatherForecastListing)
 464       migrate (undefined :: WeatherDetailedWeatherListingItem)
 465
 466   dbimport m = do
 467     -- First we insert the top-level weather record.
 468     weather_id <- insert_xml m
 469
 470     -- Next insert all of the forecasts, one at a time.
 471     forM_ (xml_forecasts m) $ \forecast -> do
 472       forecast_id <- insert_xml_fk weather_id forecast
 473
 474       -- With the forecast id in hand, loop through this forecast's
 475       -- leagues...
 476       forM_ (xml_leagues forecast) $ \league -> do
 477         -- Construct the function that converts an XML listing to a
 478         -- database one.
 479         let todb = from_xml_fk_league forecast_id (league_name league)
 480
 481         -- Now use it to convert all of the XML listings.
 482         let db_listings = map todb (listings league)
 483
 484         -- And finally, insert those DB listings.
 485         mapM_ insert_ db_listings
 486
 487     return ImportSucceeded
 488
 489
 490 --
 491 -- * Pickling
 492 --
 493
 494 -- | Pickler to convert a 'WeatherForecastListingXml' to/from XML.
 495 --
 496 pickle_listing :: PU WeatherForecastListingXml
 497 pickle_listing =
 498   xpElem "listing" $
 499     xpWrap (from_pair, to_pair) $
 500       xpPair
 501         (xpElem "teams" xpText)
 502         (xpElem "weather" xpText)
 503   where
 504     from_pair = uncurry WeatherForecastListingXml
 505     to_pair WeatherForecastListingXml{..} = (xml_teams, xml_weather)
 506
 507
 508 -- | Pickler to convert a 'WeatherLeague' to/from XML.
 509 --
 510 pickle_league :: PU WeatherLeague
 511 pickle_league =
 512   xpElem "league" $
 513     xpWrap (from_pair, to_pair) $
 514       xpPair
 515         (xpAttr "name" $ xpOption xpText)
 516         (xpList pickle_listing)
 517   where
 518     from_pair = uncurry WeatherLeague
 519     to_pair WeatherLeague{..} = (league_name, listings)
 520
 521
 522 -- | Pickler to convert a 'WeatherForecastXml' to/from XML.
 523 --
 524 pickle_forecast :: PU WeatherForecastXml
 525 pickle_forecast =
 526   xpElem "forecast" $
 527     xpWrap (from_pair, to_pair) $
 528       xpPair
 529         (xpAttr "gamedate" xp_gamedate)
 530         (xpList pickle_league)
 531   where
 532     from_pair = uncurry WeatherForecastXml
 533     to_pair WeatherForecastXml{..} = (xml_game_date,
 534                                       xml_leagues)
 535
 536
 537
 538 -- | (Un)pickle a 'WeatherDetailedWeatherListingItemXml'.
 539 --
 540 pickle_item :: PU WeatherDetailedWeatherListingItemXml
 541 pickle_item =
 542   xpElem "Item" $
 543     xpWrap (from_tuple, to_tuple) $
 544     xp9Tuple (xpElem "Sportcode" xpText)
 545              (xpElem "GameID" xpInt)
 546              (xpElem "Gamedate" xp_datetime)
 547              (xpElem "AwayTeam" xpText)
 548              (xpElem "HomeTeam" xpText)
 549              (xpElem "WeatherType" xpInt)
 550              (xpElem "Description" xpText)
 551              (xpElem "TempAdjust" (xpOption xpText))
 552              (xpElem "Temperature" xpInt)
 553   where
 554     from_tuple = uncurryN WeatherDetailedWeatherListingItemXml
 555     to_tuple w = (xml_sport_code w,
 556                   xml_game_id w,
 557                   xml_dtl_game_date w,
 558                   xml_away_team w,
 559                   xml_home_team w,
 560                   xml_weather_type w,
 561                   xml_description w,
 562                   xml_temp_adjust w,
 563                   xml_temperature w)
 564
 565
 566 -- | (Un)pickle a 'WeatherDetailedWeatherListingXml'.
 567 --
 568 pickle_dw_listing :: PU WeatherDetailedWeatherListingXml
 569 pickle_dw_listing =
 570   xpElem "DW_Listing" $
 571     xpWrap (from_tuple, to_tuple) $
 572     xpTriple (xpAttr "SportCode" xpText)
 573              (xpAttr "Sport" xpText)
 574              (xpList pickle_item)
 575   where
 576     from_tuple = uncurryN WeatherDetailedWeatherListingXml
 577     to_tuple w = (xml_dtl_listing_sport w,
 578                   xml_dtl_listing_sport_code w,
 579                   xml_items w)
 580
 581
 582 -- | (Un)pickle a 'WeatherDetailedWeatherXml'
 583 --
 584 pickle_detailed_weather :: PU WeatherDetailedWeatherXml
 585 pickle_detailed_weather =
 586   xpElem "Detailed_Weather" $
 587     xpWrap (WeatherDetailedWeatherXml, xml_detailed_listings)
 588     (xpList pickle_dw_listing)
 589
 590
 591 -- | Pickler to convert a 'Message' to/from XML.
 592 --
 593 pickle_message :: PU Message
 594 pickle_message =
 595   xpElem "message" $
 596     xpWrap (from_tuple, to_tuple) $
 597       xp8Tuple
 598         (xpElem "XML_File_ID" xpInt)
 599         (xpElem "heading" xpText)
 600         (xpElem "category" xpText)
 601         (xpElem "sport" xpText)
 602         (xpElem "title" xpText)
 603         (xpList pickle_forecast)
 604         (xpOption pickle_detailed_weather)
 605         (xpElem "time_stamp" xp_time_stamp)
 606   where
 607     from_tuple = uncurryN Message
 608     to_tuple Message{..} = (xml_xml_file_id,
 609                             xml_heading,
 610                             xml_category,
 611                             xml_sport,
 612                             xml_title,
 613                             xml_forecasts,
 614                             xml_detailed_weather,
 615                             xml_time_stamp)
 616
 617
 618 --
 619 -- * Tasty tests
 620 --
 621 weather_tests :: TestTree
 622 weather_tests =
 623   testGroup
 624     "Weather tests"
 625     [ test_on_delete_cascade,
 626       test_pickle_of_unpickle_is_identity,
 627       test_unpickle_succeeds,
 628       test_types_detected_correctly,
 629       test_normal_teams_detected_correctly ]
 630
 631
 632 -- | If we unpickle something and then pickle it, we should wind up
 633 --   with the same thing we started with. WARNING: success of this
 634 --   test does not mean that unpickling succeeded.
 635 --
 636 test_pickle_of_unpickle_is_identity :: TestTree
 637 test_pickle_of_unpickle_is_identity = testGroup "pickle-unpickle tests"
 638   [ check "pickle composed with unpickle is the identity"
 639           "test/xml/weatherxml.xml",
 640
 641     check "pickle composed with unpickle is the identity (detailed)"
 642           "test/xml/weatherxml-detailed.xml" ]
 643   where
 644     check desc path = testCase desc $ do
 645       (expected, actual) <- pickle_unpickle pickle_message path
 646       actual @?= expected
 647
 648
 649 -- | Make sure we can actually unpickle these things.
 650 --
 651 test_unpickle_succeeds :: TestTree
 652 test_unpickle_succeeds = testGroup "unpickle tests"
 653   [ check "unpickling succeeds"
 654           "test/xml/weatherxml.xml",
 655     check "unpickling succeeds (detailed)"
 656           "test/xml/weatherxml-detailed.xml" ]
 657   where
 658     check desc path = testCase desc $ do
 659       actual <- unpickleable path pickle_message
 660       let expected = True
 661       actual @?= expected
 662
 663
 664 -- | Make sure everything gets deleted when we delete the top-level
 665 --   record.
 666 --
 667 test_on_delete_cascade :: TestTree
 668 test_on_delete_cascade = testGroup "cascading delete tests"
 669   [ check "deleting weather deletes its children"
 670           "test/xml/weatherxml.xml",
 671     check "deleting weather deletes its children (detailed)"
 672           "test/xml/weatherxml-detailed.xml" ]
 673   where
 674     check desc path = testCase desc $ do
 675       weather <- unsafe_unpickle path pickle_message
 676       let a = undefined :: Weather
 677       let b = undefined :: WeatherForecast
 678       let c = undefined :: WeatherForecastListing
 679       let d = undefined :: WeatherDetailedWeatherListingItem
 680       actual <- withSqliteConn ":memory:" $ runDbConn $ do
 681                   runMigration silentMigrationLogger $ do
 682                     migrate a
 683                     migrate b
 684                     migrate c
 685                     migrate d
 686                   _ <- dbimport weather
 687                   deleteAll a
 688                   count_a <- countAll a
 689                   count_b <- countAll b
 690                   count_c <- countAll c
 691                   count_d <- countAll d
 692                   return $ count_a + count_b + count_c + count_d
 693       let expected = 0
 694       actual @?= expected
 695
 696
 697 -- | This is used in a few tests to extract an 'XmlTree' from a path.
 698 --
 699 unsafe_get_xmltree :: String -> IO XmlTree
 700 unsafe_get_xmltree path =
 701   fmap head $ runX $ readDocument parse_opts path
 702
 703
 704 -- | We want to make sure type1 documents are detected as type1, and
 705 --   type2 documents detected as type2..
 706 --
 707 test_types_detected_correctly :: TestTree
 708 test_types_detected_correctly =
 709   testGroup "weatherxml types detected correctly" $
 710     [ check "test/xml/weatherxml.xml"
 711             "first type detected correctly"
 712             True,
 713       check "test/xml/weatherxml-detailed.xml"
 714             "first type detected correctly (detailed)"
 715             True,
 716       check "test/xml/weatherxml-type2.xml"
 717             "second type detected correctly"
 718             False ]
 719   where
 720     check path desc expected = testCase desc $ do
 721       xmltree <- unsafe_get_xmltree path
 722       let actual = is_type1 xmltree
 723       actual @?= expected
 724
 725
 726 -- | We want to make sure normal teams are detected as normal, and the
 727 --   backwards ones are flagged as backwards.
 728 --
 729 test_normal_teams_detected_correctly :: TestTree
 730 test_normal_teams_detected_correctly =
 731   testGroup "team order is detected correctly" [
 732
 733     check "normal teams are detected correctly"
 734           "test/xml/weatherxml.xml"
 735           True,
 736
 737     check "backwards teams are detected correctly"
 738           "test/xml/weatherxml-backwards-teams.xml"
 739           False ]
 740   where
 741     check desc path expected = testCase desc $ do
 742       xmltree <- unsafe_get_xmltree path
 743       let actual = teams_are_normal xmltree
 744       actual @?= expected