src/TSN/XML/Odds.hs

   1 {-# LANGUAGE DeriveDataTypeable #-}
   2 {-# LANGUAGE FlexibleInstances #-}
   3 {-# LANGUAGE GADTs #-}
   4 {-# LANGUAGE QuasiQuotes #-}
   5 {-# LANGUAGE RecordWildCards #-}
   6 {-# LANGUAGE StandaloneDeriving #-}
   7 {-# LANGUAGE TemplateHaskell #-}
   8 {-# LANGUAGE TypeFamilies #-}
   9
  10 -- | Parse TSN XML for the DTD "Odds_XML.dtd". Each document contains
  11 --   a root element \<message\> that contains a bunch of other
  12 --   unorganized crap.
  13 --
  14 module TSN.XML.Odds (
  15   pickle_message,
  16   -- * Tests
  17   odds_tests,
  18   -- * WARNING: these are private but exported to silence warnings
  19   Odds_OddsGameConstructor(..),
  20   OddsCasinoConstructor(..),
  21   OddsConstructor(..),
  22   OddsGame_OddsGameTeamConstructor(..),
  23   OddsGameConstructor(..),
  24   OddsGameLineConstructor(..),
  25   OddsGameTeamConstructor(..) )
  26 where
  27
  28 -- System imports.
  29 import Control.Monad ( forM_, join )
  30 import Data.Time ( UTCTime )
  31 import Data.Tuple.Curry ( uncurryN )
  32 import Database.Groundhog (
  33   (=.),
  34   (==.),
  35   insert_,
  36   insertByAll,
  37   migrate,
  38   update )
  39 import Database.Groundhog.Core ( DefaultKey )
  40 import Database.Groundhog.TH (
  41   groundhog,
  42   mkPersist )
  43 import Test.Tasty ( TestTree, testGroup )
  44 import Test.Tasty.HUnit ( (@?=), testCase )
  45 import Text.Read ( readMaybe )
  46 import Text.XML.HXT.Core (
  47   PU,
  48   xp5Tuple,
  49   xp6Tuple,
  50   xp8Tuple,
  51   xpAttr,
  52   xpElem,
  53   xpInt,
  54   xpList,
  55   xpOption,
  56   xpPair,
  57   xpText,
  58   xpTriple,
  59   xpWrap )
  60
  61 -- Local imports.
  62 import TSN.Codegen (
  63   tsn_codegen_config )
  64 import TSN.DbImport ( DbImport(..), ImportResult(..), run_dbmigrate )
  65 import TSN.Picklers ( xp_date, xp_team_id, xp_time )
  66 import TSN.XmlImport ( XmlImport(..) )
  67 import Xml ( FromXml(..), pickle_unpickle, unpickleable )
  68
  69
  70
  71 -- | The home/away lines are 'Double's, but the over/under lines are
  72 --   textual. If we want to use one data type for both, we have to go
  73 --   with a 'String' and then attempt to 'read' a 'Double' later when we
  74 --   go to insert the thing.
  75 --
  76 data OddsGameCasinoXml =
  77   OddsGameCasinoXml {
  78     xml_casino_client_id :: Int,
  79     xml_casino_name      :: String,
  80     xml_casino_line      :: Maybe String }
  81   deriving (Eq, Show)
  82
  83
  84 -- | Try to get a 'Double' out of the 'xml_casino_line' which is a
  85 --   priori textual (because it might be an over/under line).
  86 --
  87 home_away_line :: OddsGameCasinoXml -> Maybe Double
  88 home_away_line = join . (fmap readMaybe) . xml_casino_line
  89
  90
  91 -- | The casinos should have their own table, but the lines don't
  92 --   belong in that table (there should be another table joining the
  93 --   casinos and the thing the lines are for together.)
  94 --
  95 --   We drop the 'Game' prefix because the Casinos really aren't
  96 --   children of the games; the XML just makes it seem that way.
  97 --
  98 data OddsCasino =
  99   OddsCasino {
 100     casino_client_id :: Int,
 101     casino_name :: String }
 102   deriving (Eq, Show)
 103
 104
 105 instance FromXml OddsGameCasinoXml where
 106   -- | The database representation of an 'OddsGameCasinoXml' is an
 107   --   'OddsCasino'.
 108   --
 109   type Db OddsGameCasinoXml = OddsCasino
 110
 111   -- | We convert from XML to the database by dropping the line field.
 112   from_xml OddsGameCasinoXml{..} =
 113     OddsCasino {
 114       casino_client_id = xml_casino_client_id,
 115       casino_name      = xml_casino_name }
 116
 117 -- | This allows us to call 'insert_xml' on an 'OddsGameCasinoXml'
 118 --   without first converting it to the database representation.
 119 instance XmlImport OddsGameCasinoXml
 120
 121
 122 -- | The database representation of teams as they appear in odds
 123 --   games.
 124 --
 125 data OddsGameTeam =
 126   OddsGameTeam {
 127     db_team_id         :: String, -- ^ The home/away team IDs are 3 characters
 128     db_abbr            :: String,
 129     db_team_name       :: String }
 130   deriving (Eq, Show)
 131
 132
 133 -- | The XML representation of a \<HomeTeam\>, as found in \<Game\>s.
 134 --
 135 data OddsGameHomeTeamXml =
 136   OddsGameHomeTeamXml {
 137     xml_home_team_id         :: String, -- ^ These are three-character IDs.
 138     xml_home_rotation_number :: Int,
 139     xml_home_abbr            :: String,
 140     xml_home_team_name       :: String,
 141     xml_home_casinos         :: [OddsGameCasinoXml] }
 142   deriving (Eq, Show)
 143
 144 instance FromXml OddsGameHomeTeamXml where
 145   -- | The database representation of an 'OddsGameHomeTeamXml' is an
 146   --   'OddsGameTeam'.
 147   --
 148   type Db OddsGameHomeTeamXml = OddsGameTeam
 149
 150   -- | We convert from XML to the database by dropping the lines and
 151   --   rotation number (which are specific to the games, not the teams
 152   --   themselves).
 153   --
 154   from_xml OddsGameHomeTeamXml{..} =
 155     OddsGameTeam {
 156       db_team_id   = xml_home_team_id,
 157       db_abbr      = xml_home_abbr,
 158       db_team_name = xml_home_team_name }
 159
 160 -- | XmlImport allows us to call 'insert_xml' directly on an
 161 --   'OddsGameHomeTeamXml' without explicitly converting it to the
 162 --   associated database type.
 163 --
 164 instance XmlImport OddsGameHomeTeamXml where
 165
 166
 167 -- | The XML representation of a \<AwayTeam\>, as found in \<Game\>s.
 168 --
 169 data OddsGameAwayTeamXml =
 170   OddsGameAwayTeamXml {
 171     xml_away_team_id         :: String, -- ^ These are 3 character IDs.
 172     xml_away_rotation_number :: Int,
 173     xml_away_abbr            :: String,
 174     xml_away_team_name       :: String,
 175     xml_away_casinos         :: [OddsGameCasinoXml] }
 176   deriving (Eq, Show)
 177
 178 instance FromXml OddsGameAwayTeamXml where
 179   -- | The database representation of an 'OddsGameAwayTeamXml' is an
 180   --   'OddsGameTeam'.
 181   --
 182   type Db OddsGameAwayTeamXml = OddsGameTeam
 183
 184   -- | We convert from XML to the database by dropping the lines and
 185   --   rotation number (which are specific to the games, not the teams
 186   --   themselves).
 187   --
 188   from_xml OddsGameAwayTeamXml{..} = OddsGameTeam
 189                                        xml_away_team_id
 190                                        xml_away_abbr
 191                                        xml_away_team_name
 192
 193 -- | XmlImport allows us to call 'insert_xml' directly on an
 194 --   'OddsGameAwayTeamXml' without explicitly converting it to the
 195 --   associated database type.
 196 --
 197 instance XmlImport OddsGameAwayTeamXml where
 198
 199
 200 -- | Database mapping between games and their home/away teams.
 201 data OddsGame_OddsGameTeam =
 202   OddsGame_OddsGameTeam {
 203     ogogt_odds_games_id :: DefaultKey OddsGame,
 204     ogogt_away_team_id  :: DefaultKey OddsGameTeam,
 205     ogogt_home_team_id  :: DefaultKey OddsGameTeam }
 206
 207
 208 -- | XML representation of the over/under. A wrapper around a bunch of
 209 --   casino elements.
 210 --
 211 newtype OddsGameOverUnderXml =
 212   OddsGameOverUnderXml { xml_casinos :: [OddsGameCasinoXml] }
 213   deriving (Eq, Show)
 214
 215
 216 -- | This database representation of the casino lines can't be
 217 --   constructed from the one in the XML. The casinos within
 218 --   Game>HomeTeam, Game>AwayTeam, and Game>Over_Under are all more or
 219 --   less the same. We don't need a bajillion different tables to
 220 --   store that, just one tying the casino/game pair to the three
 221 --   lines.
 222 --
 223 --   The one small difference between the over/under casinos and the
 224 --   home/away ones is that the home/away lines are all 'Double's, but
 225 --   the over/under lines appear to be textual.
 226 --
 227 data OddsGameLine =
 228   OddsGameLine {
 229     ogl_odds_games_id   :: DefaultKey OddsGame,
 230     ogl_odds_casinos_id :: DefaultKey OddsCasino,
 231     ogl_over_under      :: Maybe String,
 232     ogl_away_line       :: Maybe Double,
 233     ogl_home_line       :: Maybe Double }
 234
 235
 236 -- | Database representation of a game. We retain the rotation number
 237 --   of the home/away teams, since those are specific to the game and
 238 --   not the teams.
 239 --
 240 data OddsGame =
 241   OddsGame {
 242     db_game_id           :: Int,
 243     db_game_date         :: UTCTime,
 244     db_game_time         :: UTCTime,
 245     db_game_away_team_rotation_number :: Int,
 246     db_game_home_team_rotation_number :: Int }
 247   deriving (Eq, Show)
 248
 249 -- | XML representation of a game.
 250 --
 251 data OddsGameXml =
 252   OddsGameXml {
 253     xml_game_id         :: Int,
 254     xml_game_date       :: UTCTime,
 255     xml_game_time       :: UTCTime,
 256     xml_game_away_team  :: OddsGameAwayTeamXml,
 257     xml_game_home_team  :: OddsGameHomeTeamXml,
 258     xml_game_over_under :: OddsGameOverUnderXml }
 259   deriving (Eq, Show)
 260
 261 -- | Pseudo-field that lets us get the 'OddsGameCasinoXml's out of
 262 --   xml_game_over_under.
 263 --
 264 xml_game_over_under_casinos :: OddsGameXml -> [OddsGameCasinoXml]
 265 xml_game_over_under_casinos = xml_casinos . xml_game_over_under
 266
 267
 268 instance FromXml OddsGameXml where
 269   -- | The database representation of an 'OddsGameXml' is an
 270   --   'OddsGame'.
 271   --
 272   type Db OddsGameXml = OddsGame
 273
 274   -- | To convert from the XML representation to the database one, we
 275   --   drop the home/away teams and the casino lines, but retain the
 276   --   home/away rotation numbers.
 277   --
 278   from_xml OddsGameXml{..} =
 279     OddsGame {
 280       db_game_id   = xml_game_id,
 281       db_game_date = xml_game_date,
 282       db_game_time = xml_game_time,
 283       db_game_away_team_rotation_number =
 284         (xml_away_rotation_number xml_game_away_team),
 285       db_game_home_team_rotation_number =
 286         (xml_home_rotation_number xml_game_home_team) }
 287
 288 -- | This lets us call 'insert_xml' directly on an 'OddsGameXml'
 289 --   without converting it to the database representation explicitly.
 290 --
 291 instance XmlImport OddsGameXml
 292
 293
 294 -- | Database and representation of the top-level Odds object (a
 295 --   'Message').
 296 data Odds =
 297   Odds {
 298     db_sport :: String,
 299     db_title :: String,
 300     db_line_time :: String }
 301
 302
 303 -- | Map 'Odds' to their children 'OddsGame's.
 304 --
 305 data Odds_OddsGame = Odds_OddsGame
 306                        (DefaultKey Odds)
 307                        (DefaultKey OddsGame)
 308
 309
 310 -- | This is our best guess at what occurs in the Odds_XML
 311 --   documents. It looks like each consecutive set of games can
 312 --   optionally have some notes appear before it. Each "note" comes as
 313 --   its own <Notes>...</Notes> element.
 314 --
 315 --   The notes are ignored completely in the database; we only bother
 316 --   with them to ensure that we're (un)pickling correctly.
 317 --
 318 --   We can't group the notes with a "set" of 'OddsGame's, because that
 319 --   leads to ambiguity in parsing. Since we're going to ignore the
 320 --   notes anyway, we just stick them with an arbitrary game. C'est la
 321 --   vie.
 322 --
 323 data OddsGameWithNotes =
 324   OddsGameWithNotes {
 325     notes :: [String],
 326     game :: OddsGameXml }
 327   deriving (Eq, Show)
 328
 329 -- | The XML representation of 'Odds'.
 330 data Message =
 331   Message {
 332     xml_xml_file_id :: Int,
 333     xml_heading :: String,
 334     xml_category :: String,
 335     xml_sport :: String,
 336     xml_title :: String,
 337     xml_line_time :: String,
 338     xml_games_with_notes :: [OddsGameWithNotes],
 339     xml_time_stamp :: String }
 340   deriving (Eq, Show)
 341
 342 -- | Pseudo-field that lets us get the 'OddsGame's out of
 343 --   'xml_games_with_notes'.
 344 --
 345 xml_games :: Message -> [OddsGameXml]
 346 xml_games m = map game (xml_games_with_notes m)
 347
 348
 349 instance FromXml Message where
 350   -- | The database representation of a 'Message' is 'Odds'.
 351   --
 352   type Db Message = Odds
 353
 354   -- | To convert from the XML representation to the database one, we
 355   --   just drop a bunch of fields.
 356   --
 357   from_xml Message{..} =
 358     Odds {
 359       db_sport = xml_sport,
 360       db_title = xml_title,
 361       db_line_time = xml_line_time }
 362
 363 -- | This lets us call 'insert_xml' on a Message directly, without
 364 --   having to convert it to its database representation explicitly.
 365 --
 366 instance XmlImport Message
 367
 368
 369
 370 -- Groundhog database schema. This must come before the DbImport
 371 -- instance definition.
 372 mkPersist tsn_codegen_config [groundhog|
 373 - entity: Odds
 374
 375 - entity: OddsCasino
 376   dbName: odds_casinos
 377   constructors:
 378     - name: OddsCasino
 379       uniques:
 380         - name: unique_odds_casino
 381           type: constraint
 382           fields: [casino_client_id]
 383
 384 - entity: OddsGameTeam
 385   dbName: odds_games_teams
 386   constructors:
 387     - name: OddsGameTeam
 388       fields:
 389         - name: db_team_id
 390           type: varchar(3) # We've only seen 3, so far...
 391       uniques:
 392         - name: unique_odds_games_team
 393           type: constraint
 394           fields: [db_team_id]
 395
 396
 397 - entity: OddsGame
 398   dbName: odds_games
 399   constructors:
 400     - name: OddsGame
 401       uniques:
 402         - name: unique_odds_game
 403           type: constraint
 404           fields: [db_game_id]
 405
 406 - entity: OddsGameLine
 407   dbName: odds_games_lines
 408
 409 - entity: Odds_OddsGame
 410   dbName: odds__odds_games
 411   constructors:
 412     - name: Odds_OddsGame
 413       fields:
 414         - name: odds_OddsGame0 # Default created by mkNormalFieldName
 415           dbName: odds_id
 416         - name: odds_OddsGame1 # Default created by mkNormalFieldName
 417           dbName: odds_games_id
 418
 419 - entity: OddsGame_OddsGameTeam
 420   dbName: odds_games__odds_games_teams
 421 |]
 422
 423 instance DbImport Message where
 424   dbmigrate _=
 425     run_dbmigrate $ do
 426       migrate (undefined :: Odds)
 427       migrate (undefined :: OddsCasino)
 428       migrate (undefined :: OddsGameTeam)
 429       migrate (undefined :: OddsGame)
 430       migrate (undefined :: Odds_OddsGame)
 431       migrate (undefined :: OddsGame_OddsGameTeam)
 432       migrate (undefined :: OddsGameLine)
 433
 434   dbimport m = do
 435     -- Insert the root "odds" element and acquire its primary key (id).
 436     odds_id <- insert_xml m
 437
 438     -- Next, we insert the home and away teams. We do this before
 439     -- inserting the game itself because the game has two foreign keys
 440     -- pointing to odds_games_teams.
 441     forM_ (xml_games m) $ \g -> do
 442       game_id <- insert_xml_or_select g
 443       -- Insert a record into odds__odds_game mapping this game
 444       -- to its parent in the odds table.
 445       insert_ (Odds_OddsGame odds_id game_id)
 446
 447       -- Next to insert the home and away teams.
 448       away_team_id <- insert_xml_or_select (xml_game_away_team g)
 449       home_team_id <- insert_xml_or_select (xml_game_home_team g)
 450
 451       -- Insert a record into odds_games__odds_games_teams mapping the
 452       -- home/away teams to this game. Use the full record syntax
 453       -- because the types would let us mix up the home/away teams.
 454       insert_ OddsGame_OddsGameTeam {
 455                 ogogt_odds_games_id = game_id,
 456                 ogogt_away_team_id = away_team_id,
 457                 ogogt_home_team_id = home_team_id }
 458
 459       -- Finaly, we insert the lines. The over/under entries for this
 460       -- game and the lines for the casinos all wind up in the same
 461       -- table, odds_games_lines. We can insert the over/under entries
 462       -- freely with empty away/home lines:
 463       forM_ (xml_game_over_under_casinos g) $ \c -> do
 464         -- Start by inderting the casino.
 465         ou_casino_id <- insert_xml_or_select c
 466
 467         -- Now add the over/under entry with the casino's id.
 468         let ogl = OddsGameLine {
 469                     ogl_odds_games_id = game_id,
 470                     ogl_odds_casinos_id = ou_casino_id,
 471                     ogl_over_under = (xml_casino_line c),
 472                     ogl_away_line = Nothing,
 473                     ogl_home_line = Nothing }
 474
 475         insertByAll ogl
 476
 477       -- ...but then when we insert the home/away team lines, we
 478       -- prefer to update the existing entry rather than overwrite it
 479       -- or add a new record.
 480       forM_ (xml_away_casinos $ xml_game_away_team g) $ \c ->do
 481         -- insert, or more likely retrieve the existing, casino
 482         a_casino_id <- insert_xml_or_select c
 483
 484         -- Get a Maybe Double instead of the Maybe String that's in there.
 485         let away_line = home_away_line c
 486
 487         -- Unconditionally update that casino's away team line with ours.
 488         update [Ogl_Away_Line =. away_line] $ -- WHERE
 489           Ogl_Odds_Casinos_Id ==. a_casino_id
 490
 491       -- Repeat all that for the home team.
 492       forM_ (xml_home_casinos $ xml_game_home_team g) $ \c ->do
 493         h_casino_id <- insert_xml_or_select c
 494         let home_line = home_away_line c
 495         update [Ogl_Home_Line =. home_line] $ -- WHERE
 496           Ogl_Odds_Casinos_Id ==. h_casino_id
 497
 498       return game_id
 499
 500     return ImportSucceeded
 501
 502 -- | Pickler for an 'OddsGame' optionally preceded by some notes.
 503 --
 504 pickle_game_with_notes :: PU OddsGameWithNotes
 505 pickle_game_with_notes =
 506   xpWrap (from_pair, to_pair) $
 507     xpPair
 508       (xpList $ xpElem "Notes" xpText)
 509       pickle_game
 510   where
 511     from_pair = uncurry OddsGameWithNotes
 512     to_pair OddsGameWithNotes{..} = (notes, game)
 513
 514
 515 -- | Pickler for an 'OddsGameCasinoXml'.
 516 --
 517 pickle_casino :: PU OddsGameCasinoXml
 518 pickle_casino =
 519   xpElem "Casino" $
 520   xpWrap (from_tuple, to_tuple) $
 521   xpTriple
 522     (xpAttr "ClientID" xpInt)
 523     (xpAttr "Name" xpText)
 524     (xpOption xpText)
 525   where
 526     from_tuple = uncurryN OddsGameCasinoXml
 527     -- Use record wildcards to avoid unused field warnings.
 528     to_tuple OddsGameCasinoXml{..} = (xml_casino_client_id,
 529                                       xml_casino_name,
 530                                       xml_casino_line)
 531
 532
 533 -- | Pickler for an 'OddsGameHomeTeamXml'.
 534 --
 535 pickle_home_team :: PU OddsGameHomeTeamXml
 536 pickle_home_team =
 537   xpElem "HomeTeam" $
 538     xpWrap (from_tuple, to_tuple) $
 539       xp5Tuple
 540         (xpElem "HomeTeamID" xp_team_id)
 541         (xpElem "HomeRotationNumber" xpInt)
 542         (xpElem "HomeAbbr" xpText)
 543         (xpElem "HomeTeamName" xpText)
 544         (xpList pickle_casino)
 545   where
 546     from_tuple = uncurryN OddsGameHomeTeamXml
 547     -- Use record wildcards to avoid unused field warnings.
 548     to_tuple OddsGameHomeTeamXml{..} = (xml_home_team_id,
 549                                         xml_home_rotation_number,
 550                                         xml_home_abbr,
 551                                         xml_home_team_name,
 552                                         xml_home_casinos)
 553
 554
 555 -- | Pickler for an 'OddsGameAwayTeamXml'.
 556 --
 557 pickle_away_team :: PU OddsGameAwayTeamXml
 558 pickle_away_team =
 559   xpElem "AwayTeam" $
 560     xpWrap (from_tuple, to_tuple) $
 561       xp5Tuple
 562         (xpElem "AwayTeamID" xp_team_id)
 563         (xpElem "AwayRotationNumber" xpInt)
 564         (xpElem "AwayAbbr" xpText)
 565         (xpElem "AwayTeamName" xpText)
 566         (xpList pickle_casino)
 567   where
 568     from_tuple = uncurryN OddsGameAwayTeamXml
 569     -- Use record wildcards to avoid unused field warnings.
 570     to_tuple OddsGameAwayTeamXml{..} = (xml_away_team_id,
 571                                         xml_away_rotation_number,
 572                                         xml_away_abbr,
 573                                         xml_away_team_name,
 574                                         xml_away_casinos)
 575
 576
 577
 578 -- | Pickler for an 'OddsGameOverUnderXml'.
 579 --
 580 pickle_over_under :: PU OddsGameOverUnderXml
 581 pickle_over_under =
 582   xpElem "Over_Under" $
 583   xpWrap (to_newtype, from_newtype) $
 584     xpList pickle_casino
 585   where
 586     from_newtype (OddsGameOverUnderXml cs) = cs
 587     to_newtype = OddsGameOverUnderXml
 588
 589
 590 -- | Pickler for an 'OddsGameXml'.
 591 --
 592 pickle_game :: PU OddsGameXml
 593 pickle_game =
 594   xpElem "Game" $
 595   xpWrap (from_tuple, to_tuple) $
 596   xp6Tuple
 597     (xpElem "GameID" xpInt)
 598     (xpElem "Game_Date" xp_date)
 599     (xpElem "Game_Time" xp_time)
 600     pickle_away_team
 601     pickle_home_team
 602     pickle_over_under
 603   where
 604     from_tuple = uncurryN OddsGameXml
 605     -- Use record wildcards to avoid unused field warnings.
 606     to_tuple OddsGameXml{..} = (xml_game_id,
 607                                 xml_game_date,
 608                                 xml_game_time,
 609                                 xml_game_away_team,
 610                                 xml_game_home_team,
 611                                 xml_game_over_under)
 612
 613
 614 -- | Pickler for the top-level 'Message'.
 615 --
 616 pickle_message :: PU Message
 617 pickle_message =
 618   xpElem "message" $
 619     xpWrap (from_tuple, to_tuple) $
 620     xp8Tuple (xpElem "XML_File_ID" xpInt)
 621              (xpElem "heading" xpText)
 622              (xpElem "category" xpText)
 623              (xpElem "sport" xpText)
 624              (xpElem "Title" xpText)
 625              (xpElem "Line_Time" xpText)
 626              (xpList pickle_game_with_notes)
 627              (xpElem "time_stamp" xpText)
 628   where
 629     from_tuple = uncurryN Message
 630     to_tuple m = (xml_xml_file_id m,
 631                   xml_heading m,
 632                   xml_category m,
 633                   xml_sport m,
 634                   xml_title m,
 635                   xml_line_time m,
 636                   xml_games_with_notes m,
 637                   xml_time_stamp m)
 638
 639
 640 --
 641 -- Tasty Tests
 642 --
 643
 644 -- | A list of all tests for this module.
 645 --
 646 odds_tests :: TestTree
 647 odds_tests =
 648   testGroup
 649     "Odds tests"
 650     [ test_pickle_of_unpickle_is_identity,
 651       test_unpickle_succeeds ]
 652
 653
 654 -- | If we unpickle something and then pickle it, we should wind up
 655 --   with the same thing we started with. WARNING: succeess of this
 656 --   test does not mean that unpickling succeeded.
 657 --
 658 test_pickle_of_unpickle_is_identity :: TestTree
 659 test_pickle_of_unpickle_is_identity = testGroup "pickle-unpickle tests"
 660   [ check "pickle composed with unpickle is the identity"
 661          "test/xml/Odds_XML.xml",
 662
 663     check "pickle composed with unpickle is the identity (non-int team_id)"
 664           "test/xml/Odds_XML-noninteger-team-id.xml",
 665
 666     check "pickle composed with unpickle is the identity (positive(+) line)"
 667           "test/xml/Odds_XML-positive-line.xml",
 668
 669     check "pickle composed with unpickle is the identity (large file)"
 670           "test/xml/Odds_XML-largefile.xml" ]
 671   where
 672     check desc path = testCase desc $ do
 673       (expected, actual) <- pickle_unpickle pickle_message path
 674       actual @?= expected
 675
 676
 677 -- | Make sure we can actually unpickle these things.
 678 --
 679 test_unpickle_succeeds :: TestTree
 680 test_unpickle_succeeds = testGroup "unpickle tests"
 681   [ check "unpickling succeeds"
 682           "test/xml/Odds_XML.xml",
 683
 684     check "unpickling succeeds (non-int team_id)"
 685           "test/xml/Odds_XML-noninteger-team-id.xml",
 686
 687     check "unpickling succeeds (positive(+) line)"
 688           "test/xml/Odds_XML-positive-line.xml",
 689
 690     check "unpickling succeeds (large file)"
 691           "test/xml/Odds_XML-largefile.xml" ]
 692   where
 693     check desc path = testCase desc $ do
 694       actual <- unpickleable path pickle_message
 695       let expected = True
 696       actual @?= expected