src/TSN/XML/Odds.hs

   1 {-# LANGUAGE DeriveDataTypeable #-}
   2 {-# LANGUAGE FlexibleInstances #-}
   3 {-# LANGUAGE GADTs #-}
   4 {-# LANGUAGE QuasiQuotes #-}
   5 {-# LANGUAGE RecordWildCards #-}
   6 {-# LANGUAGE StandaloneDeriving #-}
   7 {-# LANGUAGE TemplateHaskell #-}
   8 {-# LANGUAGE TypeFamilies #-}
   9
  10 -- | Parse TSN XML for the DTD "Odds_XML.dtd". Each document contains
  11 --   a root element \<message\> that contains a bunch of other
  12 --   unorganized crap.
  13 --
  14 module TSN.XML.Odds (
  15   pickle_message,
  16   -- * Tests
  17   odds_tests,
  18   -- * WARNING: these are private but exported to silence warnings
  19   Odds_OddsGameConstructor(..),
  20   OddsCasinoConstructor(..),
  21   OddsConstructor(..),
  22   OddsGame_OddsGameTeamConstructor(..),
  23   OddsGameConstructor(..),
  24   OddsGameLineConstructor(..),
  25   OddsGameTeamConstructor(..) )
  26 where
  27
  28 -- System imports.
  29 import Control.Monad ( forM_, join )
  30 import Data.Time ( UTCTime(..) )
  31 import Data.Tuple.Curry ( uncurryN )
  32 import Database.Groundhog (
  33   (=.),
  34   (==.),
  35   insert_,
  36   insertByAll,
  37   migrate,
  38   update )
  39 import Database.Groundhog.Core ( DefaultKey )
  40 import Database.Groundhog.TH (
  41   groundhog,
  42   mkPersist )
  43 import Test.Tasty ( TestTree, testGroup )
  44 import Test.Tasty.HUnit ( (@?=), testCase )
  45 import Text.Read ( readMaybe )
  46 import Text.XML.HXT.Core (
  47   PU,
  48   xp5Tuple,
  49   xp6Tuple,
  50   xp8Tuple,
  51   xpAttr,
  52   xpElem,
  53   xpInt,
  54   xpList,
  55   xpOption,
  56   xpPair,
  57   xpText,
  58   xpTriple,
  59   xpWrap )
  60
  61 -- Local imports.
  62 import TSN.Codegen (
  63   tsn_codegen_config )
  64 import TSN.DbImport ( DbImport(..), ImportResult(..), run_dbmigrate )
  65 import TSN.Picklers ( xp_date, xp_time )
  66 import TSN.XmlImport ( XmlImport(..) )
  67 import Xml ( FromXml(..), pickle_unpickle, unpickleable )
  68
  69
  70
  71 -- | The home/away lines are 'Double's, but the over/under lines are
  72 --   textual. If we want to use one data type for both, we have to go
  73 --   with a 'String' and then attempt to 'read' a 'Double' later when we
  74 --   go to insert the thing.
  75 --
  76 data OddsGameCasinoXml =
  77   OddsGameCasinoXml {
  78     xml_casino_client_id :: Int,
  79     xml_casino_name      :: String,
  80     xml_casino_line      :: Maybe String }
  81   deriving (Eq, Show)
  82
  83
  84 -- | Try to get a 'Double' out of the 'xml_casino_line' which is a
  85 --   priori textual (because it might be an over/under line).
  86 --
  87 home_away_line :: OddsGameCasinoXml -> Maybe Double
  88 home_away_line = join . (fmap readMaybe) . xml_casino_line
  89
  90
  91 -- | The casinos should have their own table, but the lines don't
  92 --   belong in that table (there should be another table joining the
  93 --   casinos and the thing the lines are for together.)
  94 --
  95 --   We drop the 'Game' prefix because the Casinos really aren't
  96 --   children of the games; the XML just makes it seem that way.
  97 --
  98 data OddsCasino =
  99   OddsCasino {
 100     casino_client_id :: Int,
 101     casino_name :: String }
 102   deriving (Eq, Show)
 103
 104
 105 instance FromXml OddsGameCasinoXml where
 106   -- | The database representation of an 'OddsGameCasinoXml' is an
 107   --   'OddsCasino'.
 108   --
 109   type Db OddsGameCasinoXml = OddsCasino
 110
 111   -- | We convert from XML to the database by dropping the line field.
 112   from_xml OddsGameCasinoXml{..} =
 113     OddsCasino {
 114       casino_client_id = xml_casino_client_id,
 115       casino_name      = xml_casino_name }
 116
 117 -- | This allows us to call 'insert_xml' on an 'OddsGameCasinoXml'
 118 --   without first converting it to the database representation.
 119 instance XmlImport OddsGameCasinoXml
 120
 121
 122 -- | The database representation of teams as they appear in odds
 123 --   games.
 124 --
 125 data OddsGameTeam =
 126   OddsGameTeam {
 127     db_team_id         :: String, -- ^ The home/away team IDs are
 128                                   --   three characters but Postgres
 129                                   --   imposes no performance penalty
 130                                   --   on lengthless text fields, so
 131                                   --   we ignore the probable upper
 132                                   --   bound of three characters.
 133     db_abbr            :: String,
 134     db_team_name       :: String }
 135   deriving (Eq, Show)
 136
 137
 138 -- | The XML representation of a \<HomeTeam\>, as found in \<Game\>s.
 139 --
 140 data OddsGameHomeTeamXml =
 141   OddsGameHomeTeamXml {
 142     xml_home_team_id         :: String, -- ^ The home/away team IDs
 143                                         --   are three characters but
 144                                         --   Postgres imposes no
 145                                         --   performance penalty on
 146                                         --   lengthless text fields,
 147                                         --   so we ignore the probable
 148                                         --   upper bound of three
 149                                         --   characters.
 150     xml_home_rotation_number :: Int,
 151     xml_home_abbr            :: String,
 152     xml_home_team_name       :: String,
 153     xml_home_casinos         :: [OddsGameCasinoXml] }
 154   deriving (Eq, Show)
 155
 156 instance FromXml OddsGameHomeTeamXml where
 157   -- | The database representation of an 'OddsGameHomeTeamXml' is an
 158   --   'OddsGameTeam'.
 159   --
 160   type Db OddsGameHomeTeamXml = OddsGameTeam
 161
 162   -- | We convert from XML to the database by dropping the lines and
 163   --   rotation number (which are specific to the games, not the teams
 164   --   themselves).
 165   --
 166   from_xml OddsGameHomeTeamXml{..} =
 167     OddsGameTeam {
 168       db_team_id   = xml_home_team_id,
 169       db_abbr      = xml_home_abbr,
 170       db_team_name = xml_home_team_name }
 171
 172 -- | XmlImport allows us to call 'insert_xml' directly on an
 173 --   'OddsGameHomeTeamXml' without explicitly converting it to the
 174 --   associated database type.
 175 --
 176 instance XmlImport OddsGameHomeTeamXml where
 177
 178
 179 -- | The XML representation of a \<AwayTeam\>, as found in \<Game\>s.
 180 --
 181 data OddsGameAwayTeamXml =
 182   OddsGameAwayTeamXml {
 183     xml_away_team_id         :: String, -- ^ The home/away team IDs are
 184                                         --   three characters but Postgres
 185                                         --   imposes no performance penalty
 186                                         --   on lengthless text fields, so
 187                                         --   we ignore the probable upper
 188                                         --   bound of three characters
 189     xml_away_rotation_number :: Int,
 190     xml_away_abbr            :: String,
 191     xml_away_team_name       :: String,
 192     xml_away_casinos         :: [OddsGameCasinoXml] }
 193   deriving (Eq, Show)
 194
 195 instance FromXml OddsGameAwayTeamXml where
 196   -- | The database representation of an 'OddsGameAwayTeamXml' is an
 197   --   'OddsGameTeam'.
 198   --
 199   type Db OddsGameAwayTeamXml = OddsGameTeam
 200
 201   -- | We convert from XML to the database by dropping the lines and
 202   --   rotation number (which are specific to the games, not the teams
 203   --   themselves).
 204   --
 205   from_xml OddsGameAwayTeamXml{..} = OddsGameTeam
 206                                        xml_away_team_id
 207                                        xml_away_abbr
 208                                        xml_away_team_name
 209
 210 -- | XmlImport allows us to call 'insert_xml' directly on an
 211 --   'OddsGameAwayTeamXml' without explicitly converting it to the
 212 --   associated database type.
 213 --
 214 instance XmlImport OddsGameAwayTeamXml where
 215
 216
 217 -- | Database mapping between games and their home/away teams.
 218 data OddsGame_OddsGameTeam =
 219   OddsGame_OddsGameTeam {
 220     ogogt_odds_games_id :: DefaultKey OddsGame,
 221     ogogt_away_team_id  :: DefaultKey OddsGameTeam,
 222     ogogt_home_team_id  :: DefaultKey OddsGameTeam }
 223
 224
 225 -- | XML representation of the over/under. A wrapper around a bunch of
 226 --   casino elements.
 227 --
 228 newtype OddsGameOverUnderXml =
 229   OddsGameOverUnderXml { xml_casinos :: [OddsGameCasinoXml] }
 230   deriving (Eq, Show)
 231
 232
 233 -- | This database representation of the casino lines can't be
 234 --   constructed from the one in the XML. The casinos within
 235 --   Game>HomeTeam, Game>AwayTeam, and Game>Over_Under are all more or
 236 --   less the same. We don't need a bajillion different tables to
 237 --   store that, just one tying the casino/game pair to the three
 238 --   lines.
 239 --
 240 --   The one small difference between the over/under casinos and the
 241 --   home/away ones is that the home/away lines are all 'Double's, but
 242 --   the over/under lines appear to be textual.
 243 --
 244 data OddsGameLine =
 245   OddsGameLine {
 246     ogl_odds_games_id   :: DefaultKey OddsGame,
 247     ogl_odds_casinos_id :: DefaultKey OddsCasino,
 248     ogl_over_under      :: Maybe String,
 249     ogl_away_line       :: Maybe Double,
 250     ogl_home_line       :: Maybe Double }
 251
 252
 253 -- | Database representation of a game. We retain the rotation number
 254 --   of the home/away teams, since those are specific to the game and
 255 --   not the teams.
 256 --
 257 data OddsGame =
 258   OddsGame {
 259     db_game_id           :: Int,
 260     db_game_time         :: UTCTime, -- ^ Contains both the date and time.
 261     db_game_away_team_rotation_number :: Int,
 262     db_game_home_team_rotation_number :: Int }
 263   deriving (Eq, Show)
 264
 265 -- | XML representation of a game.
 266 --
 267 data OddsGameXml =
 268   OddsGameXml {
 269     xml_game_id         :: Int,
 270     xml_game_date       :: UTCTime, -- ^ Contains only the date
 271     xml_game_time       :: UTCTime, -- ^ Contains only the time
 272     xml_game_away_team  :: OddsGameAwayTeamXml,
 273     xml_game_home_team  :: OddsGameHomeTeamXml,
 274     xml_game_over_under :: OddsGameOverUnderXml }
 275   deriving (Eq, Show)
 276
 277 -- | Pseudo-field that lets us get the 'OddsGameCasinoXml's out of
 278 --   xml_game_over_under.
 279 --
 280 xml_game_over_under_casinos :: OddsGameXml -> [OddsGameCasinoXml]
 281 xml_game_over_under_casinos = xml_casinos . xml_game_over_under
 282
 283
 284 instance FromXml OddsGameXml where
 285   -- | The database representation of an 'OddsGameXml' is an
 286   --   'OddsGame'.
 287   --
 288   type Db OddsGameXml = OddsGame
 289
 290   -- | To convert from the XML representation to the database one, we
 291   --   drop the home/away teams and the casino lines, but retain the
 292   --   home/away rotation numbers.
 293   --
 294   from_xml OddsGameXml{..} =
 295     OddsGame {
 296       db_game_id   = xml_game_id,
 297
 298       db_game_time = UTCTime
 299                        (utctDay xml_game_date) -- Take the day part from one,
 300                        (utctDayTime xml_game_time), -- the time from the other.
 301
 302       db_game_away_team_rotation_number =
 303         (xml_away_rotation_number xml_game_away_team),
 304
 305       db_game_home_team_rotation_number =
 306         (xml_home_rotation_number xml_game_home_team) }
 307
 308 -- | This lets us call 'insert_xml' directly on an 'OddsGameXml'
 309 --   without converting it to the database representation explicitly.
 310 --
 311 instance XmlImport OddsGameXml
 312
 313
 314 -- | Database and representation of the top-level Odds object (a
 315 --   'Message').
 316 data Odds =
 317   Odds {
 318     db_sport :: String,
 319     db_title :: String,
 320     db_line_time :: String -- ^ We don't parse these as a 'UTCTime'
 321                            --   because their timezones are ambiguous
 322                            --   (and the date is less than useful when
 323                            --   it might be off by an hour).
 324   }
 325
 326
 327 -- | Map 'Odds' to their children 'OddsGame's.
 328 --
 329 data Odds_OddsGame = Odds_OddsGame
 330                        (DefaultKey Odds)
 331                        (DefaultKey OddsGame)
 332
 333
 334 -- | This is our best guess at what occurs in the Odds_XML
 335 --   documents. It looks like each consecutive set of games can
 336 --   optionally have some notes appear before it. Each "note" comes as
 337 --   its own <Notes>...</Notes> element.
 338 --
 339 --   The notes are ignored completely in the database; we only bother
 340 --   with them to ensure that we're (un)pickling correctly.
 341 --
 342 --   We can't group the notes with a "set" of 'OddsGame's, because that
 343 --   leads to ambiguity in parsing. Since we're going to ignore the
 344 --   notes anyway, we just stick them with an arbitrary game. C'est la
 345 --   vie.
 346 --
 347 data OddsGameWithNotes =
 348   OddsGameWithNotes {
 349     notes :: [String],
 350     game :: OddsGameXml }
 351   deriving (Eq, Show)
 352
 353 -- | The XML representation of 'Odds'.
 354 data Message =
 355   Message {
 356     xml_xml_file_id :: Int,
 357     xml_heading :: String,
 358     xml_category :: String,
 359     xml_sport :: String,
 360     xml_title :: String,
 361     xml_line_time :: String,
 362     xml_games_with_notes :: [OddsGameWithNotes],
 363     xml_time_stamp :: String }
 364   deriving (Eq, Show)
 365
 366 -- | Pseudo-field that lets us get the 'OddsGame's out of
 367 --   'xml_games_with_notes'.
 368 --
 369 xml_games :: Message -> [OddsGameXml]
 370 xml_games m = map game (xml_games_with_notes m)
 371
 372
 373 instance FromXml Message where
 374   -- | The database representation of a 'Message' is 'Odds'.
 375   --
 376   type Db Message = Odds
 377
 378   -- | To convert from the XML representation to the database one, we
 379   --   just drop a bunch of fields.
 380   --
 381   from_xml Message{..} =
 382     Odds {
 383       db_sport = xml_sport,
 384       db_title = xml_title,
 385       db_line_time = xml_line_time }
 386
 387 -- | This lets us call 'insert_xml' on a Message directly, without
 388 --   having to convert it to its database representation explicitly.
 389 --
 390 instance XmlImport Message
 391
 392
 393
 394 -- Groundhog database schema. This must come before the DbImport
 395 -- instance definition.
 396 mkPersist tsn_codegen_config [groundhog|
 397 - entity: Odds
 398
 399 - entity: OddsCasino
 400   dbName: odds_casinos
 401   constructors:
 402     - name: OddsCasino
 403       uniques:
 404         - name: unique_odds_casino
 405           type: constraint
 406           fields: [casino_client_id]
 407
 408 - entity: OddsGameTeam
 409   dbName: odds_games_teams
 410   constructors:
 411     - name: OddsGameTeam
 412       uniques:
 413         - name: unique_odds_games_team
 414           type: constraint
 415           fields: [db_team_id]
 416
 417
 418 - entity: OddsGame
 419   dbName: odds_games
 420   constructors:
 421     - name: OddsGame
 422       uniques:
 423         - name: unique_odds_game
 424           type: constraint
 425           fields: [db_game_id]
 426
 427 - entity: OddsGameLine
 428   dbName: odds_games_lines
 429
 430 - entity: Odds_OddsGame
 431   dbName: odds__odds_games
 432   constructors:
 433     - name: Odds_OddsGame
 434       fields:
 435         - name: odds_OddsGame0 # Default created by mkNormalFieldName
 436           dbName: odds_id
 437         - name: odds_OddsGame1 # Default created by mkNormalFieldName
 438           dbName: odds_games_id
 439
 440 - entity: OddsGame_OddsGameTeam
 441   dbName: odds_games__odds_games_teams
 442 |]
 443
 444 instance DbImport Message where
 445   dbmigrate _=
 446     run_dbmigrate $ do
 447       migrate (undefined :: Odds)
 448       migrate (undefined :: OddsCasino)
 449       migrate (undefined :: OddsGameTeam)
 450       migrate (undefined :: OddsGame)
 451       migrate (undefined :: Odds_OddsGame)
 452       migrate (undefined :: OddsGame_OddsGameTeam)
 453       migrate (undefined :: OddsGameLine)
 454
 455   dbimport m = do
 456     -- Insert the root "odds" element and acquire its primary key (id).
 457     odds_id <- insert_xml m
 458
 459     -- Next, we insert the home and away teams. We do this before
 460     -- inserting the game itself because the game has two foreign keys
 461     -- pointing to odds_games_teams.
 462     forM_ (xml_games m) $ \g -> do
 463       game_id <- insert_xml_or_select g
 464       -- Insert a record into odds__odds_game mapping this game
 465       -- to its parent in the odds table.
 466       insert_ (Odds_OddsGame odds_id game_id)
 467
 468       -- Next to insert the home and away teams.
 469       away_team_id <- insert_xml_or_select (xml_game_away_team g)
 470       home_team_id <- insert_xml_or_select (xml_game_home_team g)
 471
 472       -- Insert a record into odds_games__odds_games_teams mapping the
 473       -- home/away teams to this game. Use the full record syntax
 474       -- because the types would let us mix up the home/away teams.
 475       insert_ OddsGame_OddsGameTeam {
 476                 ogogt_odds_games_id = game_id,
 477                 ogogt_away_team_id = away_team_id,
 478                 ogogt_home_team_id = home_team_id }
 479
 480       -- Finaly, we insert the lines. The over/under entries for this
 481       -- game and the lines for the casinos all wind up in the same
 482       -- table, odds_games_lines. We can insert the over/under entries
 483       -- freely with empty away/home lines:
 484       forM_ (xml_game_over_under_casinos g) $ \c -> do
 485         -- Start by inderting the casino.
 486         ou_casino_id <- insert_xml_or_select c
 487
 488         -- Now add the over/under entry with the casino's id.
 489         let ogl = OddsGameLine {
 490                     ogl_odds_games_id = game_id,
 491                     ogl_odds_casinos_id = ou_casino_id,
 492                     ogl_over_under = (xml_casino_line c),
 493                     ogl_away_line = Nothing,
 494                     ogl_home_line = Nothing }
 495
 496         insertByAll ogl
 497
 498       -- ...but then when we insert the home/away team lines, we
 499       -- prefer to update the existing entry rather than overwrite it
 500       -- or add a new record.
 501       forM_ (xml_away_casinos $ xml_game_away_team g) $ \c ->do
 502         -- insert, or more likely retrieve the existing, casino
 503         a_casino_id <- insert_xml_or_select c
 504
 505         -- Get a Maybe Double instead of the Maybe String that's in there.
 506         let away_line = home_away_line c
 507
 508         -- Unconditionally update that casino's away team line with ours.
 509         update [Ogl_Away_Line =. away_line] $ -- WHERE
 510           Ogl_Odds_Casinos_Id ==. a_casino_id
 511
 512       -- Repeat all that for the home team.
 513       forM_ (xml_home_casinos $ xml_game_home_team g) $ \c ->do
 514         h_casino_id <- insert_xml_or_select c
 515         let home_line = home_away_line c
 516         update [Ogl_Home_Line =. home_line] $ -- WHERE
 517           Ogl_Odds_Casinos_Id ==. h_casino_id
 518
 519       return game_id
 520
 521     return ImportSucceeded
 522
 523 -- | Pickler for an 'OddsGame' optionally preceded by some notes.
 524 --
 525 pickle_game_with_notes :: PU OddsGameWithNotes
 526 pickle_game_with_notes =
 527   xpWrap (from_pair, to_pair) $
 528     xpPair
 529       (xpList $ xpElem "Notes" xpText)
 530       pickle_game
 531   where
 532     from_pair = uncurry OddsGameWithNotes
 533     to_pair OddsGameWithNotes{..} = (notes, game)
 534
 535
 536 -- | Pickler for an 'OddsGameCasinoXml'.
 537 --
 538 pickle_casino :: PU OddsGameCasinoXml
 539 pickle_casino =
 540   xpElem "Casino" $
 541   xpWrap (from_tuple, to_tuple) $
 542   xpTriple
 543     (xpAttr "ClientID" xpInt)
 544     (xpAttr "Name" xpText)
 545     (xpOption xpText)
 546   where
 547     from_tuple = uncurryN OddsGameCasinoXml
 548     -- Use record wildcards to avoid unused field warnings.
 549     to_tuple OddsGameCasinoXml{..} = (xml_casino_client_id,
 550                                       xml_casino_name,
 551                                       xml_casino_line)
 552
 553
 554 -- | Pickler for an 'OddsGameHomeTeamXml'.
 555 --
 556 pickle_home_team :: PU OddsGameHomeTeamXml
 557 pickle_home_team =
 558   xpElem "HomeTeam" $
 559     xpWrap (from_tuple, to_tuple) $
 560       xp5Tuple
 561         (xpElem "HomeTeamID" xpText)
 562         (xpElem "HomeRotationNumber" xpInt)
 563         (xpElem "HomeAbbr" xpText)
 564         (xpElem "HomeTeamName" xpText)
 565         (xpList pickle_casino)
 566   where
 567     from_tuple = uncurryN OddsGameHomeTeamXml
 568     -- Use record wildcards to avoid unused field warnings.
 569     to_tuple OddsGameHomeTeamXml{..} = (xml_home_team_id,
 570                                         xml_home_rotation_number,
 571                                         xml_home_abbr,
 572                                         xml_home_team_name,
 573                                         xml_home_casinos)
 574
 575
 576 -- | Pickler for an 'OddsGameAwayTeamXml'.
 577 --
 578 pickle_away_team :: PU OddsGameAwayTeamXml
 579 pickle_away_team =
 580   xpElem "AwayTeam" $
 581     xpWrap (from_tuple, to_tuple) $
 582       xp5Tuple
 583         (xpElem "AwayTeamID" xpText)
 584         (xpElem "AwayRotationNumber" xpInt)
 585         (xpElem "AwayAbbr" xpText)
 586         (xpElem "AwayTeamName" xpText)
 587         (xpList pickle_casino)
 588   where
 589     from_tuple = uncurryN OddsGameAwayTeamXml
 590     -- Use record wildcards to avoid unused field warnings.
 591     to_tuple OddsGameAwayTeamXml{..} = (xml_away_team_id,
 592                                         xml_away_rotation_number,
 593                                         xml_away_abbr,
 594                                         xml_away_team_name,
 595                                         xml_away_casinos)
 596
 597
 598
 599 -- | Pickler for an 'OddsGameOverUnderXml'.
 600 --
 601 pickle_over_under :: PU OddsGameOverUnderXml
 602 pickle_over_under =
 603   xpElem "Over_Under" $
 604   xpWrap (to_newtype, from_newtype) $
 605     xpList pickle_casino
 606   where
 607     from_newtype (OddsGameOverUnderXml cs) = cs
 608     to_newtype = OddsGameOverUnderXml
 609
 610
 611 -- | Pickler for an 'OddsGameXml'.
 612 --
 613 pickle_game :: PU OddsGameXml
 614 pickle_game =
 615   xpElem "Game" $
 616   xpWrap (from_tuple, to_tuple) $
 617   xp6Tuple
 618     (xpElem "GameID" xpInt)
 619     (xpElem "Game_Date" xp_date)
 620     (xpElem "Game_Time" xp_time)
 621     pickle_away_team
 622     pickle_home_team
 623     pickle_over_under
 624   where
 625     from_tuple = uncurryN OddsGameXml
 626     -- Use record wildcards to avoid unused field warnings.
 627     to_tuple OddsGameXml{..} = (xml_game_id,
 628                                 xml_game_date,
 629                                 xml_game_time,
 630                                 xml_game_away_team,
 631                                 xml_game_home_team,
 632                                 xml_game_over_under)
 633
 634
 635 -- | Pickler for the top-level 'Message'.
 636 --
 637 pickle_message :: PU Message
 638 pickle_message =
 639   xpElem "message" $
 640     xpWrap (from_tuple, to_tuple) $
 641     xp8Tuple (xpElem "XML_File_ID" xpInt)
 642              (xpElem "heading" xpText)
 643              (xpElem "category" xpText)
 644              (xpElem "sport" xpText)
 645              (xpElem "Title" xpText)
 646              (xpElem "Line_Time" xpText)
 647              (xpList pickle_game_with_notes)
 648              (xpElem "time_stamp" xpText)
 649   where
 650     from_tuple = uncurryN Message
 651     to_tuple m = (xml_xml_file_id m,
 652                   xml_heading m,
 653                   xml_category m,
 654                   xml_sport m,
 655                   xml_title m,
 656                   xml_line_time m,
 657                   xml_games_with_notes m,
 658                   xml_time_stamp m)
 659
 660
 661 --
 662 -- Tasty Tests
 663 --
 664
 665 -- | A list of all tests for this module.
 666 --
 667 odds_tests :: TestTree
 668 odds_tests =
 669   testGroup
 670     "Odds tests"
 671     [ test_pickle_of_unpickle_is_identity,
 672       test_unpickle_succeeds ]
 673
 674
 675 -- | If we unpickle something and then pickle it, we should wind up
 676 --   with the same thing we started with. WARNING: succeess of this
 677 --   test does not mean that unpickling succeeded.
 678 --
 679 test_pickle_of_unpickle_is_identity :: TestTree
 680 test_pickle_of_unpickle_is_identity = testGroup "pickle-unpickle tests"
 681   [ check "pickle composed with unpickle is the identity"
 682          "test/xml/Odds_XML.xml",
 683
 684     check "pickle composed with unpickle is the identity (non-int team_id)"
 685           "test/xml/Odds_XML-noninteger-team-id.xml",
 686
 687     check "pickle composed with unpickle is the identity (positive(+) line)"
 688           "test/xml/Odds_XML-positive-line.xml",
 689
 690     check "pickle composed with unpickle is the identity (large file)"
 691           "test/xml/Odds_XML-largefile.xml" ]
 692   where
 693     check desc path = testCase desc $ do
 694       (expected, actual) <- pickle_unpickle pickle_message path
 695       actual @?= expected
 696
 697
 698 -- | Make sure we can actually unpickle these things.
 699 --
 700 test_unpickle_succeeds :: TestTree
 701 test_unpickle_succeeds = testGroup "unpickle tests"
 702   [ check "unpickling succeeds"
 703           "test/xml/Odds_XML.xml",
 704
 705     check "unpickling succeeds (non-int team_id)"
 706           "test/xml/Odds_XML-noninteger-team-id.xml",
 707
 708     check "unpickling succeeds (positive(+) line)"
 709           "test/xml/Odds_XML-positive-line.xml",
 710
 711     check "unpickling succeeds (large file)"
 712           "test/xml/Odds_XML-largefile.xml" ]
 713   where
 714     check desc path = testCase desc $ do
 715       actual <- unpickleable path pickle_message
 716       let expected = True
 717       actual @?= expected