src/Linear/QR.hs

   1 {-# LANGUAGE NoImplicitPrelude #-}
   2 {-# LANGUAGE ScopedTypeVariables #-}
   3
   4 -- | QR factorization via Givens rotations.
   5 --
   6 module Linear.QR (
   7   givens_rotator,
   8   qr )
   9 where
  10
  11 import qualified Algebra.Ring as Ring ( C )
  12 import qualified Algebra.Algebraic as Algebraic ( C )
  13 import Data.Vector.Fixed ( ifoldl )
  14 import Data.Vector.Fixed.Cont ( Arity )
  15 import NumericPrelude hiding ( (*) )
  16
  17 import Linear.Matrix (
  18   Mat(..),
  19   (*),
  20   (!!!),
  21   construct,
  22   identity_matrix,
  23   transpose )
  24
  25
  26 -- | Construct a givens rotation matrix that will operate on row @i@
  27 --   and column @j@. This is done to create zeros in some column of
  28 --   the target matrix. You must also supply that column's @i@th and
  29 --   @j@th entries as arguments.
  30 --
  31 --   Examples (Watkins, p. 193):
  32 --
  33 --   >>> import Normed ( Normed(..) )
  34 --   >>> import Linear.Vector ( Vec2, Vec3 )
  35 --   >>> import Linear.Matrix ( Mat2, Mat3, fromList, frobenius_norm )
  36 --   >>> import qualified Data.Vector.Fixed as V ( map )
  37 --
  38 --   >>> let m  = givens_rotator 0 1 1 1 :: Mat2 Double
  39 --   >>> let m2 = fromList [[1, -1],[1, 1]] :: Mat2 Double
  40 --   >>> m == (1 / (sqrt 2) :: Double) *> m2
  41 --   True
  42 --
  43 --   >>> let m = fromList [[2,3],[5,7]] :: Mat2 Double
  44 --   >>> let rot =  givens_rotator 0 1 2.0 5.0 :: Mat2 Double
  45 --   >>> ((transpose rot) * m) !!! (1,0) < 1e-12
  46 --   True
  47 --   >>> let (Mat rows) = rot
  48 --   >>> let (Mat cols) = transpose rot
  49 --   >>> V.map norm rows :: Vec2 Double
  50 --   fromList [1.0,1.0]
  51 --   >>> V.map norm cols :: Vec2 Double
  52 --   fromList [1.0,1.0]
  53 --
  54 --   >>> let m = fromList [[12,-51,4],[6,167,-68],[-4,24,-41]] :: Mat3 Double
  55 --   >>> let rot = givens_rotator 1 2 6 (-4) :: Mat3 Double
  56 --   >>> let ex_rot_r1 = [1,0,0] :: [Double]
  57 --   >>> let ex_rot_r2 = [0,0.83205,-0.55470] :: [Double]
  58 --   >>> let ex_rot_r3 = [0, 0.55470, 0.83205] :: [Double]
  59 --   >>> let ex_rot = fromList [ex_rot_r1, ex_rot_r2, ex_rot_r3] :: Mat3 Double
  60 --   >>> frobenius_norm ((transpose rot) - ex_rot) < 1e-4
  61 --   True
  62 --   >>> ((transpose rot) * m) !!! (2,0) == 0
  63 --   True
  64 --   >>> let (Mat rows) = rot
  65 --   >>> let (Mat cols) = transpose rot
  66 --   >>> V.map norm rows :: Vec3 Double
  67 --   fromList [1.0,1.0,1.0]
  68 --   >>> V.map norm cols :: Vec3 Double
  69 --   fromList [1.0,1.0,1.0]
  70 --
  71 givens_rotator :: forall m a. (Eq a, Ring.C a, Algebraic.C a, Arity m)
  72                => Int -> Int -> a -> a -> Mat m m a
  73 givens_rotator i j xi xj =
  74   construct f
  75   where
  76     xnorm = sqrt $ xi^2 + xj^2
  77     c = if xnorm == (fromInteger 0) then (fromInteger 1) else xi / xnorm
  78     s = if xnorm == (fromInteger 0) then (fromInteger 0) else xj / xnorm
  79
  80     f :: Int -> Int -> a
  81     f y z
  82       | y == i && z == i = c
  83       | y == j && z == j = c
  84       | y == i && z == j = negate s
  85       | y == j && z == i = s
  86       | y == z = fromInteger 1
  87       | otherwise = fromInteger 0
  88
  89
  90 -- | Compute the QR factorization of a matrix (using Givens
  91 --   rotations). This is accomplished with two folds: the first one
  92 --   traverses the columns of the matrix from left to right, and the
  93 --   second traverses the entries of the column from top to
  94 --   bottom.
  95 --
  96 --   The state that is passed through the fold is the current (q,r)
  97 --   factorization. We keep the pair updated by multiplying @q@ and
  98 --   @r@ by the new rotator (or its transpose).
  99 --
 100 --   We do not require that the diagonal elements of R are positive,
 101 --   so our factorization is a little less unique than usual.
 102 --
 103 --   Examples:
 104 --
 105 --   >>> import Linear.Matrix
 106 --
 107 --   >>> let m = fromList [[1,2],[1,3]] :: Mat2 Double
 108 --   >>> let (q,r) = qr m
 109 --   >>> let c = (1 / (sqrt 2 :: Double))
 110 --   >>> let ex_q = c *> (fromList [[1,-1],[1,1]] :: Mat2 Double)
 111 --   >>> let ex_r = c *> (fromList [[2,5],[0,1]] :: Mat2 Double)
 112 --   >>> frobenius_norm (q - ex_q) == 0
 113 --   True
 114 --   >>> frobenius_norm (r - ex_r) == 0
 115 --   True
 116 --   >>> let m' = q*r
 117 --   >>> frobenius_norm (m - m') < 1e-10
 118 --   True
 119 --   >>> is_upper_triangular' 1e-10 r
 120 --   True
 121 --
 122 --   >>> let m = fromList [[2,3],[5,7]] :: Mat2 Double
 123 --   >>> let (q,r) = qr m
 124 --   >>> frobenius_norm (m - (q*r)) < 1e-12
 125 --   True
 126 --   >>> is_upper_triangular' 1e-10 r
 127 --   True
 128 --
 129 --   >>> let m = fromList [[12,-51,4],[6,167,-68],[-4,24,-41]] :: Mat3 Double
 130 --   >>> let (q,r) = qr m
 131 --   >>> frobenius_norm (m - (q*r)) < 1e-12
 132 --   True
 133 --   >>> is_upper_triangular' 1e-10 r
 134 --   True
 135 --
 136 qr :: forall m n a. (Arity m, Arity n, Eq a, Algebraic.C a, Ring.C a, Show a)
 137    => Mat m n a -> (Mat m m a, Mat m n a)
 138 qr matrix =
 139   ifoldl col_function initial_qr columns
 140   where
 141     Mat columns = transpose matrix
 142     initial_qr = (identity_matrix, matrix)
 143
 144     -- | Process the column and spit out the current QR
 145     --   factorization. In the first column, we want to get rotators
 146     --   Q12, Q13, Q14,... In the second column, we want rotators Q23,
 147     --   Q24, Q25,...
 148     col_function (q,r) col_idx col =
 149       ifoldl (f col_idx) (q,r) col
 150
 151     -- | Process the entries in a column, doing basically the same
 152     --   thing as col_dunction does. It updates the QR factorization,
 153     --   maybe, and returns the current one.
 154     f col_idx (q,r) idx _ -- ignore the current element
 155       | idx <= col_idx = (q,r)
 156 --          trace ("---------------\nidx: " ++ (show idx) ++ ";\ncol_idx: " ++ (show col_idx) ++ "; leaving it alone") (q,r) -- leave it alone.
 157       | otherwise = (q*rotator, (transpose rotator)*r)
 158 --          trace ("---------------\nidx: " ++ (show idx) ++ ";\ncol_idx: " ++ (show col_idx) ++ ";\nupdating Q and R;\nq: " ++ (show q) ++ ";\nr " ++ (show r) ++ ";\nnew q: " ++ (show $ q*rotator) ++ ";\nnew r: " ++ (show $ (transpose rotator)*r) ++ ";\ny: " ++ (show y) ++ ";\nr[i,j]: " ++ (show (r !!! (col_idx, col_idx))))
 159 --          (q*rotator, (transpose rotator)*r)
 160           where
 161             y = r !!! (idx, col_idx)
 162             rotator :: Mat m m a
 163             rotator = givens_rotator col_idx idx (r !!! (col_idx, col_idx)) y