src/Linear/Matrix.hs

   1 {-# LANGUAGE ExistentialQuantification #-}
   2 {-# LANGUAGE FlexibleContexts #-}
   3 {-# LANGUAGE FlexibleInstances #-}
   4 {-# LANGUAGE MultiParamTypeClasses #-}
   5 {-# LANGUAGE NoMonomorphismRestriction #-}
   6 {-# LANGUAGE ScopedTypeVariables #-}
   7 {-# LANGUAGE TypeFamilies #-}
   8 {-# LANGUAGE RebindableSyntax #-}
   9
  10 -- | Boxed matrices; that is, boxed m-vectors of boxed n-vectors. We
  11 --   assume that the underlying representation is
  12 --   Data.Vector.Fixed.Boxed.Vec for simplicity. It was tried in
  13 --   generality and failed.
  14 --
  15 module Linear.Matrix
  16 where
  17
  18 import Data.List (intercalate)
  19
  20 import Data.Vector.Fixed (
  21   (!),
  22   generate,
  23   mk1,
  24   mk2,
  25   mk3,
  26   mk4,
  27   mk5 )
  28 import qualified Data.Vector.Fixed as V (
  29   and,
  30   fromList,
  31   head,
  32   ifoldl,
  33   ifoldr,
  34   imap,
  35   map,
  36   maximum,
  37   replicate,
  38   reverse,
  39   toList,
  40   zipWith )
  41 import Data.Vector.Fixed.Cont ( Arity, arity )
  42 import Linear.Vector ( Vec, delete )
  43 import Naturals
  44 import Normed ( Normed(..) )
  45
  46 import NumericPrelude hiding ( (*), abs )
  47 import qualified NumericPrelude as NP ( (*) )
  48 import qualified Algebra.Absolute as Absolute ( C )
  49 import Algebra.Absolute ( abs )
  50 import qualified Algebra.Additive as Additive ( C )
  51 import qualified Algebra.Algebraic as Algebraic ( C )
  52 import Algebra.Algebraic ( root )
  53 import qualified Algebra.Field as Field ( C )
  54 import qualified Algebra.Ring as Ring ( C )
  55 import qualified Algebra.Module as Module ( C )
  56 import qualified Algebra.RealRing as RealRing ( C )
  57 import qualified Algebra.ToRational as ToRational ( C )
  58 import qualified Algebra.Transcendental as Transcendental ( C )
  59 import qualified Prelude as P ( map )
  60
  61 -- | Our main matrix type.
  62 data Mat m n a = (Arity m, Arity n) => Mat (Vec m (Vec n a))
  63
  64 -- Type synonyms for n-by-n matrices.
  65 type Mat1 a = Mat N1 N1 a
  66 type Mat2 a = Mat N2 N2 a
  67 type Mat3 a = Mat N3 N3 a
  68 type Mat4 a = Mat N4 N4 a
  69 type Mat5 a = Mat N5 N5 a
  70 type Mat6 a = Mat N6 N6 a
  71 type Mat7 a = Mat N7 N7 a
  72
  73 -- * Type synonyms for 1-by-n row "vectors".
  74
  75 -- | Type synonym for row vectors expressed as 1-by-n matrices.
  76 type Row n a = Mat N1 n a
  77
  78 type Row1 a = Row N1 a
  79 type Row2 a = Row N2 a
  80 type Row3 a = Row N3 a
  81 type Row4 a = Row N4 a
  82 type Row5 a = Row N5 a
  83
  84 -- * Type synonyms for n-by-1 column "vectors".
  85
  86 -- | Type synonym for column vectors expressed as n-by-1 matrices.
  87 type Col n a = Mat n N1 a
  88
  89 type Col1 a = Col N1 a
  90 type Col2 a = Col N2 a
  91 type Col3 a = Col N3 a
  92 type Col4 a = Col N4 a
  93 type Col5 a = Col N5 a
  94 type Col6 a = Col N6 a
  95 type Col7 a = Col N7 a
  96 type Col8 a = Col N8 a
  97 type Col9 a = Col N9 a
  98 type Col10 a = Col N10 a
  99 type Col11 a = Col N11 a
 100 type Col12 a = Col N12 a
 101 type Col13 a = Col N13 a
 102 type Col14 a = Col N14 a
 103 type Col15 a = Col N15 a
 104 type Col16 a = Col N16 a
 105 type Col17 a = Col N17 a
 106 type Col18 a = Col N18 a
 107 type Col19 a = Col N19 a
 108 type Col20 a = Col N20 a
 109 type Col21 a = Col N21 a
 110 type Col22 a = Col N22 a
 111 type Col23 a = Col N23 a
 112 type Col24 a = Col N24 a
 113 type Col25 a = Col N25 a
 114 type Col26 a = Col N26 a
 115 type Col27 a = Col N27 a
 116 type Col28 a = Col N28 a
 117 type Col29 a = Col N29 a
 118 type Col30 a = Col N30 a
 119 type Col31 a = Col N31 a
 120 type Col32 a = Col N32 a
 121
 122
 123 instance (Eq a) => Eq (Mat m n a) where
 124   -- | Compare a row at a time.
 125   --
 126   --   Examples:
 127   --
 128   --   >>> let m1 = fromList [[1,2],[3,4]] :: Mat2 Int
 129   --   >>> let m2 = fromList [[1,2],[3,4]] :: Mat2 Int
 130   --   >>> let m3 = fromList [[5,6],[7,8]] :: Mat2 Int
 131   --   >>> m1 == m2
 132   --   True
 133   --   >>> m1 == m3
 134   --   False
 135   --
 136   (Mat rows_one) == (Mat rows_two) =
 137     V.and $ V.zipWith comp rows_one rows_two
 138     where
 139       -- Compare a row, one column at a time.
 140       comp row1 row2 = V.and (V.zipWith (==) row1 row2)
 141
 142
 143 instance (Show a) => Show (Mat m n a) where
 144   -- | Display matrices and vectors as ordinary tuples. This is poor
 145   --   practice, but these results are primarily displayed
 146   --   interactively and convenience trumps correctness (said the guy
 147   --   who insists his vector lengths be statically checked at
 148   --   compile-time).
 149   --
 150   --   Examples:
 151   --
 152   --   >>> let m = fromList [[1,2],[3,4]] :: Mat2 Int
 153   --   >>> show m
 154   --   ((1,2),(3,4))
 155   --
 156   show (Mat rows) =
 157     "(" ++ (intercalate "," (V.toList row_strings)) ++ ")"
 158     where
 159       row_strings = V.map show_vector rows
 160       show_vector v1 =
 161         "(" ++ (intercalate "," element_strings) ++ ")"
 162         where
 163           v1l = V.toList v1
 164           element_strings = P.map show v1l
 165
 166
 167 -- | Convert a matrix to a nested list.
 168 toList :: Mat m n a -> [[a]]
 169 toList (Mat rows) = map V.toList (V.toList rows)
 170
 171
 172 -- | Create a matrix from a nested list.
 173 fromList :: (Arity m, Arity n) => [[a]] -> Mat m n a
 174 fromList vs = Mat (V.fromList $ map V.fromList vs)
 175
 176
 177 -- | Unsafe indexing. Much faster than the safe indexing.
 178 (!!!) :: (Arity m, Arity n) => Mat m n a -> (Int, Int) -> a
 179 (!!!) (Mat rows) (i, j) = (rows ! i) ! j
 180
 181
 182 -- | Safe indexing.
 183 --
 184 --   Examples:
 185 --
 186 --   >>> let m = fromList [[1,2],[3,4]] :: Mat2 Int
 187 --   >>> m !!? (-1,-1)
 188 --   Nothing
 189 --   >>>  m !!? (-1,0)
 190 --   Nothing
 191 --   >>>  m !!? (-1,1)
 192 --   Nothing
 193 --   >>>  m !!? (0,-1)
 194 --   Nothing
 195 --   >>>  m !!? (0,0)
 196 --   Just 1
 197 --   >>>  m !!? (0,1)
 198 --   Just 2
 199 --   >>>  m !!? (1,-1)
 200 --   Nothing
 201 --   >>>  m !!? (1,0)
 202 --   Just 3
 203 --   >>>  m !!? (1,1)
 204 --   Just 4
 205 --   >>>  m !!? (2,-1)
 206 --   Nothing
 207 --   >>>  m !!? (2,0)
 208 --   Nothing
 209 --   >>>  m !!? (2,1)
 210 --   Nothing
 211 --   >>>  m !!? (2,2)
 212 --   Nothing
 213 --
 214 (!!?) :: (Arity m, Arity n) => Mat m n a -> (Int, Int) -> Maybe a
 215 (!!?) matrix idx =
 216   ifoldl2 f Nothing matrix
 217   where
 218     f k l found cur = if (k,l) == idx then (Just cur) else found
 219
 220
 221 -- | The number of rows in the matrix.
 222 nrows :: forall m n a. (Arity m) => Mat m n a -> Int
 223 nrows _ = arity (undefined :: m)
 224
 225
 226 -- | The number of columns in the first row of the
 227 --   matrix. Implementation stolen from Data.Vector.Fixed.length.
 228 ncols :: forall m n a. (Arity n) => Mat m n a -> Int
 229 ncols _ = arity (undefined :: n)
 230
 231
 232 -- | Return the @i@th row of @m@ as a matrix. Unsafe.
 233 row :: (Arity m, Arity n) => Mat m n a -> Int -> Row n a
 234 row m i =
 235   construct lambda
 236   where
 237     lambda _ j = m !!! (i, j)
 238
 239
 240 -- | Return the @j@th column of @m@ as a matrix. Unsafe.
 241 column :: (Arity m, Arity n) => Mat m n a -> Int -> Col m a
 242 column m j =
 243   construct lambda
 244   where
 245     lambda i _ = m !!! (i, j)
 246
 247
 248 -- | Transpose @m@; switch it's columns and its rows. This is a dirty
 249 --   implementation, but I don't see a better way.
 250 --
 251 --   TODO: Don't cheat with fromList.
 252 --
 253 --   Examples:
 254 --
 255 --   >>> let m = fromList [[1,2], [3,4]] :: Mat2 Int
 256 --   >>> transpose m
 257 --   ((1,3),(2,4))
 258 --
 259 transpose :: (Arity m, Arity n) => Mat m n a -> Mat n m a
 260 transpose matrix =
 261   construct lambda
 262   where
 263     lambda i j = matrix !!! (j,i)
 264
 265
 266 -- | Is @m@ symmetric?
 267 --
 268 --   Examples:
 269 --
 270 --   >>> let m1 = fromList [[1,2], [2,1]] :: Mat2 Int
 271 --   >>> symmetric m1
 272 --   True
 273 --
 274 --   >>> let m2 = fromList [[1,2], [3,1]] :: Mat2 Int
 275 --   >>> symmetric m2
 276 --   False
 277 --
 278 symmetric :: (Eq a, Arity m) => Mat m m a -> Bool
 279 symmetric m =
 280   m == (transpose m)
 281
 282
 283 -- | Construct a new matrix from a function @lambda@. The function
 284 --   @lambda@ should take two parameters i,j corresponding to the
 285 --   entries in the matrix. The i,j entry of the resulting matrix will
 286 --   have the value returned by lambda i j.
 287 --
 288 --   Examples:
 289 --
 290 --   >>> let lambda i j = i + j
 291 --   >>> construct lambda :: Mat3 Int
 292 --   ((0,1,2),(1,2,3),(2,3,4))
 293 --
 294 construct :: forall m n a. (Arity m, Arity n)
 295           => (Int -> Int -> a) -> Mat m n a
 296 construct lambda = Mat $ generate make_row
 297   where
 298     make_row :: Int -> Vec n a
 299     make_row i = generate (lambda i)
 300
 301
 302 -- | Create an identity matrix with the right dimensions.
 303 --
 304 --   Examples:
 305 --
 306 --   >>> identity_matrix :: Mat3 Int
 307 --   ((1,0,0),(0,1,0),(0,0,1))
 308 --   >>> identity_matrix :: Mat3 Double
 309 --   ((1.0,0.0,0.0),(0.0,1.0,0.0),(0.0,0.0,1.0))
 310 --
 311 identity_matrix :: (Arity m, Ring.C a) => Mat m m a
 312 identity_matrix =
 313   construct (\i j -> if i == j then (fromInteger 1) else (fromInteger 0))
 314
 315
 316 -- | Given a positive-definite matrix @m@, computes the
 317 --   upper-triangular matrix @r@ with (transpose r)*r == m and all
 318 --   values on the diagonal of @r@ positive.
 319 --
 320 --   Examples:
 321 --
 322 --   >>> let m1 = fromList [[20,-1], [-1,20]] :: Mat2 Double
 323 --   >>> let r = cholesky m1
 324 --   >>> frobenius_norm ((transpose r)*r - m1) < 1e-10
 325 --   True
 326 --   >>> is_upper_triangular r
 327 --   True
 328 --
 329 --   >>> let k1 = [6, -3, 0, 0, 0, 0, 0] :: [Double]
 330 --   >>> let k2 = [-3, 10.5, -7.5, 0, 0, 0, 0] :: [Double]
 331 --   >>> let k3 = [0, -7.5, 12.5, 0, 0, 0, 0] :: [Double]
 332 --   >>> let k4 = [0, 0, 0, 6, 0, 0, 0] :: [Double]
 333 --   >>> let k5 = [0, 0, 0, 0, 6, 0, 0] :: [Double]
 334 --   >>> let k6 = [0, 0, 0, 0, 0, 6, 0] :: [Double]
 335 --   >>> let k7 = [0, 0, 0, 0, 0, 0, 15] :: [Double]
 336 --   >>> let big_K = fromList [k1,k2,k3,k4,k5,k6,k7] :: Mat N7 N7 Double
 337 --
 338 --   >>> let e1 = [2.449489742783178,0,0,0,0,0,0] :: [Double]
 339 --   >>> let e2 = [-1.224744871391589,3,0,0,0,0,0] :: [Double]
 340 --   >>> let e3 = [0,-5/2,5/2,0,0,0,0] :: [Double]
 341 --   >>> let e4 = [0,0,0,2.449489742783178,0,0,0] :: [Double]
 342 --   >>> let e5 = [0,0,0,0,2.449489742783178,0,0] :: [Double]
 343 --   >>> let e6 = [0,0,0,0,0,2.449489742783178,0] :: [Double]
 344 --   >>> let e7 = [0,0,0,0,0,0,3.872983346207417] :: [Double]
 345 --   >>> let expected = fromList [e1,e2,e3,e4,e5,e6,e7] :: Mat N7 N7 Double
 346 --
 347 --   >>> let r = cholesky big_K
 348 --   >>> frobenius_norm (r - (transpose expected)) < 1e-12
 349 --   True
 350 --
 351 cholesky :: forall m n a. (Algebraic.C a, Arity m, Arity n)
 352          => (Mat m n a) -> (Mat m n a)
 353 cholesky m = construct r
 354   where
 355     r :: Int -> Int -> a
 356     r i j | i == j = sqrt(m !!! (i,j) - sum [(r k i)^2 | k <- [0..i-1]])
 357           | i < j =
 358               (((m !!! (i,j)) - sum [(r k i) NP.* (r k j) | k <- [0..i-1]]))/(r i i)
 359           | otherwise = 0
 360
 361
 362 -- | Returns True if the given matrix is upper-triangular, and False
 363 --   otherwise. The parameter @epsilon@ lets the caller choose a
 364 --   tolerance.
 365 --
 366 --   Examples:
 367 --
 368 --   >>> let m = fromList [[1,1],[1e-12,1]] :: Mat2 Double
 369 --   >>> is_upper_triangular m
 370 --   False
 371 --   >>> is_upper_triangular' 1e-10 m
 372 --   True
 373 --
 374 is_upper_triangular' :: forall m n a.
 375                         (Ord a, Ring.C a, Absolute.C a, Arity m, Arity n)
 376                     => a -- ^ The tolerance @epsilon@.
 377                     -> Mat m n a
 378                     -> Bool
 379 is_upper_triangular' epsilon matrix =
 380   ifoldl2 f True matrix
 381   where
 382     f :: Int -> Int -> Bool -> a -> Bool
 383     f _ _ False _ = False
 384     f i j True x
 385       | i <= j = True
 386       -- use "less than or equal to" so zero is a valid epsilon
 387       | otherwise = abs x <= epsilon
 388
 389
 390 -- | Returns True if the given matrix is upper-triangular, and False
 391 --   otherwise. We don't delegate to the general
 392 --   'is_upper_triangular'' here because it imposes additional
 393 --   typeclass constraints throughout the library.
 394 --
 395 --   Examples:
 396 --
 397 --   >>> let m = fromList [[1,0],[1,1]] :: Mat2 Int
 398 --   >>> is_upper_triangular m
 399 --   False
 400 --
 401 --   >>> let m = fromList [[1,2],[0,3]] :: Mat2 Int
 402 --   >>> is_upper_triangular m
 403 --   True
 404 --
 405 is_upper_triangular :: forall m n a.
 406                        (Eq a, Ring.C a, Arity m, Arity n)
 407                     => Mat m n a -> Bool
 408 is_upper_triangular matrix =
 409   ifoldl2 f True matrix
 410   where
 411     f :: Int -> Int -> Bool -> a -> Bool
 412     f _ _ False _ = False
 413     f i j True x
 414       | i <= j = True
 415       | otherwise = x == 0
 416
 417
 418
 419 -- | Returns True if the given matrix is lower-triangular, and False
 420 --   otherwise.
 421 --
 422 --   Examples:
 423 --
 424 --   >>> let m = fromList [[1,0],[1,1]] :: Mat2 Int
 425 --   >>> is_lower_triangular m
 426 --   True
 427 --
 428 --   >>> let m = fromList [[1,2],[0,3]] :: Mat2 Int
 429 --   >>> is_lower_triangular m
 430 --   False
 431 --
 432 is_lower_triangular :: (Eq a,
 433                         Ring.C a,
 434                         Arity m,
 435                         Arity n)
 436                     => Mat m n a
 437                     -> Bool
 438 is_lower_triangular = is_upper_triangular . transpose
 439
 440
 441 -- | Returns True if the given matrix is lower-triangular, and False
 442 --   otherwise. The parameter @epsilon@ lets the caller choose a
 443 --   tolerance.
 444 --
 445 --   Examples:
 446 --
 447 --   >>> let m = fromList [[1,1e-12],[1,1]] :: Mat2 Double
 448 --   >>> is_lower_triangular m
 449 --   False
 450 --   >>> is_lower_triangular' 1e-12 m
 451 --   True
 452 --
 453 is_lower_triangular' :: (Ord a,
 454                          Ring.C a,
 455                          Absolute.C a,
 456                          Arity m,
 457                          Arity n)
 458                     => a -- ^ The tolerance @epsilon@.
 459                     -> Mat m n a
 460                     -> Bool
 461 is_lower_triangular' epsilon = (is_upper_triangular' epsilon) . transpose
 462
 463
 464 -- | Returns True if the given matrix is triangular, and False
 465 --   otherwise.
 466 --
 467 --   Examples:
 468 --
 469 --   >>> let m = fromList [[1,0],[1,1]] :: Mat2 Int
 470 --   >>> is_triangular m
 471 --   True
 472 --
 473 --   >>> let m = fromList [[1,2],[0,3]] :: Mat2 Int
 474 --   >>> is_triangular m
 475 --   True
 476 --
 477 --   >>> let m = fromList [[1,2],[3,4]] :: Mat2 Int
 478 --   >>> is_triangular m
 479 --   False
 480 --
 481 is_triangular :: (Ord a,
 482                   Ring.C a,
 483                   Absolute.C a,
 484                   Arity m,
 485                   Arity n)
 486               => Mat m n a
 487               -> Bool
 488 is_triangular m = is_upper_triangular m || is_lower_triangular m
 489
 490
 491 -- | Delete the @i@th row and @j@th column from the matrix. The name
 492 --   \"preminor\" is made up, but is meant to signify that this is
 493 --   usually used in the computationof a minor. A minor is simply the
 494 --   determinant of a preminor in that case.
 495 --
 496 --   Examples:
 497 --
 498 --   >>> let m = fromList [[1,2,3],[4,5,6],[7,8,9]] :: Mat3 Int
 499 --   >>> preminor m 0 0 :: Mat2 Int
 500 --   ((5,6),(8,9))
 501 --   >>> preminor m 1 1 :: Mat2 Int
 502 --   ((1,3),(7,9))
 503 --
 504 preminor :: (Arity m, Arity n)
 505       => Mat (S m) (S n) a
 506       -> Int
 507       -> Int
 508       -> Mat m n a
 509 preminor (Mat rows) i j = m
 510   where
 511     rows' = delete rows i
 512     m = Mat $ V.map ((flip delete) j) rows'
 513
 514
 515 -- | Compute the i,jth minor of a @matrix@.
 516 --
 517 --   Examples:
 518 --
 519 --   >>> let m1 = fromList [[1,2,3],[4,5,6],[7,8,9]] :: Mat3 Double
 520 --   >>> minor m1 1 1
 521 --   -12.0
 522 --
 523 minor :: (Arity m, Determined (Mat m m) a)
 524       => Mat (S m) (S m) a
 525       -> Int
 526       -> Int
 527       -> a
 528 minor matrix i j = determinant (preminor matrix i j)
 529
 530 class (Eq a, Ring.C a) => Determined p a where
 531   determinant :: (p a) -> a
 532
 533 instance (Eq a, Ring.C a) => Determined (Mat (S Z) (S Z)) a where
 534   determinant = unscalar
 535
 536 instance (Ord a,
 537           Ring.C a,
 538           Absolute.C a,
 539           Arity n,
 540           Determined (Mat (S n) (S n)) a)
 541          => Determined (Mat (S (S n)) (S (S n))) a where
 542   -- | The recursive definition with a special-case for triangular matrices.
 543   --
 544   --   Examples:
 545   --
 546   --   >>> let m = fromList [[1,2],[3,4]] :: Mat2 Int
 547   --   >>> determinant m
 548   --   -1
 549   --
 550   determinant m
 551     | is_triangular m = product [ m !!! (i,i) | i <- [0..(nrows m)-1] ]
 552     | otherwise = determinant_recursive
 553         where
 554           m' i j = m !!! (i,j)
 555
 556           determinant_recursive =
 557             sum [ (-1)^(toInteger j) NP.* (m' 0 j) NP.* (minor m 0 j)
 558               | j <- [0..(ncols m)-1] ]
 559
 560
 561
 562 -- | Matrix multiplication.
 563 --
 564 --   Examples:
 565 --
 566 --   >>> let m1 = fromList [[1,2,3], [4,5,6]]  :: Mat N2 N3 Int
 567 --   >>> let m2 = fromList [[1,2],[3,4],[5,6]] :: Mat N3 N2 Int
 568 --   >>> m1 * m2
 569 --   ((22,28),(49,64))
 570 --
 571 infixl 7 *
 572 (*) :: (Ring.C a, Arity m, Arity n, Arity p)
 573         => Mat (S m) (S n) a
 574         -> Mat (S n) (S p) a
 575         -> Mat (S m) (S p) a
 576 (*) m1 m2 = construct lambda
 577   where
 578     lambda i j = (transpose $ row m1 i) `dot` (column m2 j)
 579
 580
 581
 582 instance (Ring.C a, Arity m, Arity n) => Additive.C (Mat m n a) where
 583
 584   (Mat rows_one) + (Mat rows_two) =
 585     Mat $ V.zipWith (V.zipWith (+)) rows_one rows_two
 586
 587   (Mat rows_one) - (Mat rows_two) =
 588     Mat $ V.zipWith (V.zipWith (-)) rows_one rows_two
 589
 590   zero = Mat (V.replicate $ V.replicate (fromInteger 0))
 591
 592
 593 instance (Ring.C a, Arity m, Arity n, m ~ n) => Ring.C (Mat (S m) (S n) a) where
 594   -- The first * is ring multiplication, the second is matrix
 595   -- multiplication.
 596   m1 * m2 = m1 * m2
 597
 598
 599 instance (Ring.C a, Arity m, Arity n) => Module.C a (Mat m n a) where
 600   -- We can multiply a matrix by a scalar of the same type as its
 601   -- elements.
 602   x *> (Mat rows) = Mat $ V.map (V.map (NP.* x)) rows
 603
 604
 605 instance (Absolute.C a,
 606           Algebraic.C a,
 607           ToRational.C a,
 608           Arity m)
 609          => Normed (Col (S m) a) where
 610   -- | Generic p-norms for vectors in R^n that are represented as n-by-1
 611   --   matrices.
 612   --
 613   --   Examples:
 614   --
 615   --   >>> let v1 = vec2d (3,4)
 616   --   >>> norm_p 1 v1
 617   --   7.0
 618   --   >>> norm_p 2 v1
 619   --   5.0
 620   --
 621   --   >>> let v1 = vec2d (-1,1) :: Col2 Double
 622   --   >>> norm_p 1 v1 :: Double
 623   --   2.0
 624   --
 625   norm_p p (Mat rows) =
 626     (root p') $ sum [fromRational' (toRational $ abs x)^p' | x <- xs]
 627     where
 628       p' = toInteger p
 629       xs = concat $ V.toList $ V.map V.toList rows
 630
 631   -- | The infinity norm.
 632   --
 633   --   Examples:
 634   --
 635   --   >>> let v1 = vec3d (1,5,2)
 636   --   >>> norm_infty v1
 637   --   5
 638   --
 639   norm_infty (Mat rows) =
 640     fromRational' $ toRational $ V.maximum $ V.map V.maximum rows
 641
 642
 643 -- | Compute the Frobenius norm of a matrix. This essentially treats
 644 --   the matrix as one long vector containing all of its entries (in
 645 --   any order, it doesn't matter).
 646 --
 647 --   Examples:
 648 --
 649 --   >>> let m = fromList [[1, 2, 3],[4,5,6],[7,8,9]] :: Mat3 Double
 650 --   >>> frobenius_norm m == sqrt 285
 651 --   True
 652 --
 653 --   >>> let m = fromList [[1, -1, 1],[-1,1,-1],[1,-1,1]] :: Mat3 Double
 654 --   >>> frobenius_norm m == 3
 655 --   True
 656 --
 657 frobenius_norm :: (Arity m, Arity n, Algebraic.C a, Ring.C a)
 658                => Mat m n a
 659                -> a
 660 frobenius_norm matrix =
 661   sqrt $ element_sum2 $ squares
 662   where
 663     squares = map2 (^2) matrix
 664
 665
 666 -- Vector helpers. We want it to be easy to create low-dimension
 667 -- column vectors, which are nx1 matrices.
 668
 669 -- | Convenient constructor for 2D vectors.
 670 --
 671 --   Examples:
 672 --
 673 --   >>> import Roots.Simple
 674 --   >>> let fst m = m !!! (0,0)
 675 --   >>> let snd m = m !!! (1,0)
 676 --   >>> let h = 0.5 :: Double
 677 --   >>> let g1 m = 1.0 + h NP.* exp(-((fst m)^2))/(1.0 + (snd m)^2)
 678 --   >>> let g2 m = 0.5 + h NP.* atan((fst m)^2 + (snd m)^2)
 679 --   >>> let g u = vec2d ((g1 u), (g2 u))
 680 --   >>> let u0 = vec2d (1.0, 1.0)
 681 --   >>> let eps = 1/(10^9)
 682 --   >>> fixed_point g eps u0
 683 --   ((1.0728549599342185),(1.0820591495686167))
 684 --
 685 vec1d :: (a) -> Col1 a
 686 vec1d (x) = Mat (mk1 (mk1 x))
 687
 688 vec2d :: (a,a) -> Col2 a
 689 vec2d (x,y) = Mat (mk2 (mk1 x) (mk1 y))
 690
 691 vec3d :: (a,a,a) -> Col3 a
 692 vec3d (x,y,z) = Mat (mk3 (mk1 x) (mk1 y) (mk1 z))
 693
 694 vec4d :: (a,a,a,a) -> Col4 a
 695 vec4d (w,x,y,z) = Mat (mk4 (mk1 w) (mk1 x) (mk1 y) (mk1 z))
 696
 697 vec5d :: (a,a,a,a,a) -> Col5 a
 698 vec5d (v,w,x,y,z) = Mat (mk5 (mk1 v) (mk1 w) (mk1 x) (mk1 y) (mk1 z))
 699
 700
 701 -- Since we commandeered multiplication, we need to create 1x1
 702 -- matrices in order to multiply things.
 703 scalar :: a -> Mat1 a
 704 scalar x = Mat (mk1 (mk1 x))
 705
 706 -- Get the scalar value out of a 1x1 matrix.
 707 unscalar :: Mat1 a -> a
 708 unscalar (Mat rows) = V.head $ V.head rows
 709
 710
 711 dot :: (Ring.C a, Arity m)
 712        => Col (S m) a
 713        -> Col (S m) a
 714        -> a
 715 v1 `dot` v2 = element_sum2 $ zipwith2 (NP.*) v1 v2
 716
 717
 718 -- | The angle between @v1@ and @v2@ in Euclidean space.
 719 --
 720 --   Examples:
 721 --
 722 --   >>> let v1 = vec2d (1.0, 0.0)
 723 --   >>> let v2 = vec2d (0.0, 1.0)
 724 --   >>> angle v1 v2 == pi/2.0
 725 --   True
 726 --
 727 angle :: (Transcendental.C a,
 728           RealRing.C a,
 729           m ~ S t,
 730           Arity t,
 731           ToRational.C a)
 732           => Col m a
 733           -> Col m a
 734           -> a
 735 angle v1 v2 =
 736   acos theta
 737   where
 738    theta = (recip norms) NP.* (v1 `dot` v2)
 739    norms = (norm v1) NP.* (norm v2)
 740
 741
 742 -- | Retrieve the diagonal elements of the given matrix as a \"column
 743 --   vector,\" i.e. a m-by-1 matrix. We require the matrix to be
 744 --   square to avoid ambiguity in the return type which would ideally
 745 --   have dimension min(m,n) supposing an m-by-n matrix.
 746 --
 747 --   Examples:
 748 --
 749 --   >>> let m = fromList [[1,2,3],[4,5,6],[7,8,9]] :: Mat3 Int
 750 --   >>> diagonal m
 751 --   ((1),(5),(9))
 752 --
 753 diagonal :: (Arity m) => Mat m m a -> Col m a
 754 diagonal matrix =
 755   construct lambda
 756   where
 757     lambda i _ = matrix !!! (i,i)
 758
 759
 760 -- | Given a square @matrix@, return a new matrix of the same size
 761 --   containing only the on-diagonal entries of @matrix@. The
 762 --   off-diagonal entries are set to zero.
 763 --
 764 --   Examples:
 765 --
 766 --   >>> let m = fromList [[1,2,3],[4,5,6],[7,8,9]] :: Mat3 Int
 767 --   >>> diagonal_part m
 768 --   ((1,0,0),(0,5,0),(0,0,9))
 769 --
 770 diagonal_part :: (Arity m, Ring.C a)
 771          => Mat m m a
 772          -> Mat m m a
 773 diagonal_part matrix =
 774   construct lambda
 775   where
 776     lambda i j = if i == j then matrix !!! (i,j) else 0
 777
 778
 779 -- | Given a square @matrix@, return a new matrix of the same size
 780 --   containing only the on-diagonal and below-diagonal entries of
 781 --   @matrix@. The above-diagonal entries are set to zero.
 782 --
 783 --   Examples:
 784 --
 785 --   >>> let m = fromList [[1,2,3],[4,5,6],[7,8,9]] :: Mat3 Int
 786 --   >>> lt_part m
 787 --   ((1,0,0),(4,5,0),(7,8,9))
 788 --
 789 lt_part :: (Arity m, Ring.C a)
 790         => Mat m m a
 791         -> Mat m m a
 792 lt_part matrix =
 793   construct lambda
 794   where
 795     lambda i j = if i >= j then matrix !!! (i,j) else 0
 796
 797
 798 -- | Given a square @matrix@, return a new matrix of the same size
 799 --   containing only the below-diagonal entries of @matrix@. The on-
 800 --   and above-diagonal entries are set to zero.
 801 --
 802 --   Examples:
 803 --
 804 --   >>> let m = fromList [[1,2,3],[4,5,6],[7,8,9]] :: Mat3 Int
 805 --   >>> lt_part_strict m
 806 --   ((0,0,0),(4,0,0),(7,8,0))
 807 --
 808 lt_part_strict :: (Arity m, Ring.C a)
 809         => Mat m m a
 810         -> Mat m m a
 811 lt_part_strict matrix =
 812   construct lambda
 813   where
 814     lambda i j = if i > j then matrix !!! (i,j) else 0
 815
 816
 817 -- | Given a square @matrix@, return a new matrix of the same size
 818 --   containing only the on-diagonal and above-diagonal entries of
 819 --   @matrix@. The below-diagonal entries are set to zero.
 820 --
 821 --   Examples:
 822 --
 823 --   >>> let m = fromList [[1,2,3],[4,5,6],[7,8,9]] :: Mat3 Int
 824 --   >>> ut_part m
 825 --   ((1,2,3),(0,5,6),(0,0,9))
 826 --
 827 ut_part :: (Arity m, Ring.C a)
 828         => Mat m m a
 829         -> Mat m m a
 830 ut_part = transpose . lt_part . transpose
 831
 832
 833 -- | Given a square @matrix@, return a new matrix of the same size
 834 --   containing only the above-diagonal entries of @matrix@. The on-
 835 --   and below-diagonal entries are set to zero.
 836 --
 837 --   Examples:
 838 --
 839 --   >>> let m = fromList [[1,2,3],[4,5,6],[7,8,9]] :: Mat3 Int
 840 --   >>> ut_part_strict m
 841 --   ((0,2,3),(0,0,6),(0,0,0))
 842 --
 843 ut_part_strict :: (Arity m, Ring.C a)
 844         => Mat m m a
 845         -> Mat m m a
 846 ut_part_strict = transpose . lt_part_strict . transpose
 847
 848
 849 -- | Compute the trace of a square matrix, the sum of the elements
 850 --   which lie on its diagonal. We require the matrix to be
 851 --   square to avoid ambiguity in the return type which would ideally
 852 --   have dimension min(m,n) supposing an m-by-n matrix.
 853 --
 854 --   Examples:
 855 --
 856 --   >>> let m = fromList [[1,2,3],[4,5,6],[7,8,9]] :: Mat3 Int
 857 --   >>> trace m
 858 --   15
 859 --
 860 trace :: (Arity m, Ring.C a) => Mat m m a -> a
 861 trace = element_sum2 . diagonal
 862
 863
 864
 865 -- | Zip together two matrices.
 866 --
 867 --   TODO: don't cheat with construct (map V.zips instead).
 868 --
 869 --   Examples:
 870 --
 871 --   >>> let m1 = fromList [[1],[1],[1]] :: Col3 Int
 872 --   >>> let m2 = fromList [[1],[2],[3]] :: Col3 Int
 873 --   >>> zip2 m1 m2
 874 --   (((1,1)),((1,2)),((1,3)))
 875 --
 876 --   >>> let m1 = fromList [[1,2],[3,4]] :: Mat2 Int
 877 --   >>> let m2 = fromList [[1,1],[1,1]] :: Mat2 Int
 878 --   >>> zip2 m1 m2
 879 --   (((1,1),(2,1)),((3,1),(4,1)))
 880 --
 881 zip2 :: (Arity m, Arity n) => Mat m n a -> Mat m n b -> Mat m n (a,b)
 882 zip2 m1 m2 =
 883   construct lambda
 884   where
 885     lambda i j = (m1 !!! (i,j), m2 !!! (i,j))
 886
 887
 888 -- | Zip together three matrices.
 889 --
 890 --   TODO: don't cheat with construct (map V.zips instead).
 891 --
 892 --   Examples:
 893 --
 894 --   >>> let m1 = fromList [[1],[1],[1]] :: Col3 Int
 895 --   >>> let m2 = fromList [[1],[2],[3]] :: Col3 Int
 896 --   >>> let m3 = fromList [[4],[5],[6]] :: Col3 Int
 897 --   >>> zip2three m1 m2 m3
 898 --   (((1,1,4)),((1,2,5)),((1,3,6)))
 899 --
 900 --   >>> let m1 = fromList [[1,2],[3,4]] :: Mat2 Int
 901 --   >>> let m2 = fromList [[1,1],[1,1]] :: Mat2 Int
 902 --   >>> let m3 = fromList [[8,2],[6,3]] :: Mat2 Int
 903 --   >>> zip2three m1 m2 m3
 904 --   (((1,1,8),(2,1,2)),((3,1,6),(4,1,3)))
 905 --
 906 zip2three :: (Arity m, Arity n)
 907           => Mat m n a
 908           -> Mat m n a
 909           -> Mat m n a
 910           -> Mat m n (a,a,a)
 911 zip2three m1 m2 m3 =
 912   construct lambda
 913   where
 914     lambda i j = (m1 !!! (i,j), m2 !!! (i,j), m3 !!! (i,j))
 915
 916
 917 -- | Zip together two matrices using the supplied function.
 918 --
 919 --   Examples:
 920 --
 921 --   >>> let c1 = fromList [[1],[2],[3]] :: Col3 Integer
 922 --   >>> let c2 = fromList [[4],[5],[6]] :: Col3 Integer
 923 --   >>> zipwith2 (^) c1 c2
 924 --   ((1),(32),(729))
 925 --
 926 zipwith2 :: (Arity m, Arity n)
 927            => (a -> b -> c)
 928            -> Mat m n a
 929            -> Mat m n b
 930            -> Mat m n c
 931 zipwith2 f c1 c2 =
 932   construct lambda
 933   where
 934     lambda i j = f (c1 !!! (i,j)) (c2 !!! (i,j))
 935
 936
 937 -- | Map a function over a matrix of any dimensions.
 938 --
 939 --   Examples:
 940 --
 941 --   >>> let m = fromList [[1,2],[3,4]] :: Mat2 Int
 942 --   >>> map2 (^2) m
 943 --   ((1,4),(9,16))
 944 --
 945 map2 :: (a -> b) -> Mat m n a -> Mat m n b
 946 map2 f (Mat rows) =
 947   Mat $ V.map g rows
 948   where
 949     g = V.map f
 950
 951
 952 -- | Fold over the entire matrix passing the coordinates @i@ and @j@
 953 --   (of the row/column) to the accumulation function. The fold occurs
 954 --   from top-left to bottom-right.
 955 --
 956 --   Examples:
 957 --
 958 --   >>> let m = fromList [[1,2,3],[4,5,6],[7,8,9]] :: Mat3 Int
 959 --   >>> ifoldl2 (\i j cur _ -> cur + i + j) 0 m
 960 --   18
 961 --
 962 ifoldl2 :: forall a b m n.
 963            (Int -> Int -> b -> a -> b)
 964         -> b
 965         -> Mat m n a
 966         -> b
 967 ifoldl2 f initial (Mat rows) =
 968   V.ifoldl row_function initial rows
 969   where
 970     -- | The order that we need this in (so that @g idx@ makes sense)
 971     --   is a little funny. So that we don't need to pass weird
 972     --   functions into ifoldl2, we swap the second and third
 973     --   arguments of @f@ calling the result @g@.
 974     g :: Int -> b -> Int -> a -> b
 975     g w x y = f w y x
 976
 977     row_function :: b -> Int -> Vec n a -> b
 978     row_function rowinit idx r = V.ifoldl (g idx) rowinit r
 979
 980
 981 -- | Left fold over the entries of a matrix (top-left to bottom-right).
 982 --
 983 foldl2 :: forall a b m n.
 984           (b -> a -> b)
 985         -> b
 986         -> Mat m n a
 987         -> b
 988 foldl2 f initial matrix =
 989   -- Use the index fold but ignore the index arguments.
 990   let g _ _ = f in ifoldl2 g initial matrix
 991
 992
 993 -- | Fold over the entire matrix passing the coordinates @i@ and @j@
 994 --   (of the row/column) to the accumulation function. The fold occurs
 995 --   from bottom-right to top-left.
 996 --
 997 --   The order of the arguments in the supplied function are different
 998 --   from those in V.ifoldr; we keep them similar to ifoldl2.
 999 --
1000 --   Examples:
1001 --
1002 --   >>> let m = fromList [[1,2,3],[4,5,6],[7,8,9]] :: Mat3 Int
1003 --   >>> ifoldr2 (\i j cur _ -> cur + i + j) 0 m
1004 --   18
1005 --
1006 ifoldr2 :: forall a b m n.
1007            (Int -> Int -> b -> a -> b)
1008         -> b
1009         -> Mat m n a
1010         -> b
1011 ifoldr2 f initial (Mat rows) =
1012   V.ifoldr row_function initial rows
1013   where
1014     -- | Swap the order of arguments in @f@ so that it agrees with the
1015     --   @f@ passed to ifoldl2.
1016     g :: Int -> Int -> a -> b -> b
1017     g w x y z = f w x z y
1018
1019     row_function :: Int -> Vec n a -> b -> b
1020     row_function idx r rowinit = V.ifoldr (g idx) rowinit r
1021
1022
1023 -- | Map a function over a matrix of any dimensions, passing the
1024 --   coordinates @i@ and @j@ to the function @f@.
1025 --
1026 --   Examples:
1027 --
1028 --   >>> let m = fromList [[1,2],[3,4]] :: Mat2 Int
1029 --   >>> imap2 (\i j _ -> i+j) m
1030 --   ((0,1),(1,2))
1031 --
1032 imap2 :: (Int -> Int -> a -> b) -> Mat m n a -> Mat m n b
1033 imap2 f (Mat rows) =
1034   Mat $ V.imap g rows
1035   where
1036     g i = V.imap (f i)
1037
1038
1039 -- | Reverse the order of elements in a matrix.
1040 --
1041 --   Examples:
1042 --
1043 --   >>> let m1 = fromList [[1,2,3]] :: Row3 Int
1044 --   >>> reverse2 m1
1045 --   ((3,2,1))
1046 --
1047 --   >>> let m1 = vec3d (1,2,3 :: Int)
1048 --   >>> reverse2 m1
1049 --   ((3),(2),(1))
1050 --
1051 --   >>> let m = fromList [[1,2,3],[4,5,6],[7,8,9]] :: Mat3 Int
1052 --   >>> reverse2 m
1053 --   ((9,8,7),(6,5,4),(3,2,1))
1054 --
1055 reverse2 :: (Arity m, Arity n) => Mat m n a -> Mat m n a
1056 reverse2 (Mat rows) = Mat $ V.reverse $ V.map V.reverse rows
1057
1058
1059 -- | Unsafely set the (i,j) element of the given matrix.
1060 --
1061 --   Examples:
1062 --
1063 --   >>> let m = fromList [[1,2,3],[4,5,6],[7,8,9]] :: Mat3 Int
1064 --   >>> set_idx m (1,1) 17
1065 --   ((1,2,3),(4,17,6),(7,8,9))
1066 --
1067 set_idx :: forall m n a.
1068            (Arity m, Arity n)
1069         => Mat m n a
1070         -> (Int, Int)
1071         -> a
1072         -> Mat m n a
1073 set_idx matrix (i,j) newval =
1074   imap2 updater matrix
1075   where
1076     updater :: Int -> Int -> a -> a
1077     updater k l existing =
1078       if k == i && l == j
1079       then newval
1080       else existing
1081
1082
1083 -- | Compute the i,jth cofactor of the given @matrix@. This simply
1084 --   premultiplues the i,jth minor by (-1)^(i+j).
1085 cofactor :: (Arity m, Determined (Mat m m) a)
1086          => Mat (S m) (S m) a
1087          -> Int
1088          -> Int
1089          -> a
1090 cofactor matrix i j =
1091   (-1)^(toInteger i + toInteger j) NP.* (minor matrix i j)
1092
1093
1094 -- | Compute the inverse of a matrix using cofactor expansion
1095 --   (generalized Cramer's rule).
1096 --
1097 --   Examples:
1098 --
1099 --   >>> let m1 = fromList [[37,22],[17,54]] :: Mat2 Double
1100 --   >>> let e1 = [54/1624, -22/1624] :: [Double]
1101 --   >>> let e2 = [-17/1624, 37/1624] :: [Double]
1102 --   >>> let expected = fromList [e1, e2] :: Mat2 Double
1103 --   >>> let actual = inverse m1
1104 --   >>> frobenius_norm (actual - expected) < 1e-12
1105 --   True
1106 --
1107 inverse :: (Arity m,
1108             Determined (Mat (S m) (S m)) a,
1109             Determined (Mat m m) a,
1110             Field.C a)
1111         => Mat (S m) (S m) a
1112         -> Mat (S m) (S m) a
1113 inverse matrix =
1114   (1 / (determinant matrix)) *> (transpose $ construct lambda)
1115   where
1116     lambda i j = cofactor matrix i j
1117
1118
1119
1120 -- | Retrieve the rows of a matrix as a column matrix. If the given
1121 --   matrix is m-by-n, the result would be an m-by-1 column whose
1122 --   entries are 1-by-n row matrices.
1123 --
1124 --   Examples:
1125 --
1126 --   >>> let m = fromList [[1,2],[3,4]] :: Mat2 Int
1127 --   >>> (rows2 m) !!! (0,0)
1128 --   ((1,2))
1129 --   >>> (rows2 m) !!! (1,0)
1130 --   ((3,4))
1131 --
1132 rows2 :: (Arity m, Arity n)
1133       => Mat m n a
1134       -> Col m (Row n a)
1135 rows2 (Mat rows) =
1136   Mat $ V.map (mk1. Mat . mk1) rows
1137
1138
1139
1140 -- | Sum the elements of a matrix.
1141 --
1142 --   Examples:
1143 --
1144 --   >>> let m = fromList [[1,-1],[3,4]] :: Mat2 Int
1145 --   >>> element_sum2 m
1146 --   7
1147 --
1148 element_sum2 :: (Arity m, Arity n, Additive.C a) => Mat m n a -> a
1149 element_sum2 = foldl2 (+) zero