+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+inherit eutils toolchain-funcs user
+
+DESCRIPTION="A DNS server designed to serve blacklist zones"
+HOMEPAGE="http://www.corpit.ru/mjt/rbldnsd.html"
+SRC_URI="http://www.corpit.ru/mjt/rbldnsd/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~sparc ~x86 ~x86-fbsd"
+IUSE="ipv6 zlib"
+
+DEPEND="zlib? ( sys-libs/zlib )"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+ # The ./configure file is handwritten and doesn't support a `make
+ # install` target, so there are no --prefix options. The econf
+ # function appends those automatically, so we can't use it.
+ ./configure \
+ $(use_enable ipv6) \
+ $(use_enable zlib) \
+ || die "./configure failed"
+}
+
+src_compile() {
+ # We can also pass AWK and PYTHON environment variables to emake,
+ # but those should be available via the default 'awk' and 'python'
+ # symlinks.
+ emake \
+ AR="$(tc-getAR)" \
+ CC="$(tc-getCC)" \
+ RANLIB="$(tc-getRANLIB)" \
+ || die "emake failed"
+}
+
+src_install() {
+ dosbin rbldnsd
+ doman rbldnsd.8
+ keepdir /var/db/rbldnsd
+ dodoc CHANGES* TODO NEWS README*
+ newinitd "${FILESDIR}"/initd-${PV} rbldnsd
+ newconfd "${FILESDIR}"/confd-${PV} rbldnsd
+}
+
+pkg_postinst() {
+ enewgroup rbldns
+ enewuser rbldns -1 -1 /var/db/rbldnsd rbldns
+ chown rbldns:rbldns /var/db/rbldnsd
+}