net-dns/rbldnsd/rbldnsd-0.997.ebuild

   1 # Copyright 1999-2012 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI=5
   6
   7 inherit eutils toolchain-funcs user
   8
   9 DESCRIPTION="A DNS server designed to serve blacklist zones"
  10 HOMEPAGE="http://www.corpit.ru/mjt/rbldnsd.html"
  11 SRC_URI="http://www.corpit.ru/mjt/rbldnsd/${P}.tar.gz"
  12
  13 LICENSE="GPL-2"
  14 SLOT="0"
  15 KEYWORDS="~amd64 ~hppa ~sparc ~x86 ~x86-fbsd"
  16 IUSE="ipv6 zlib"
  17
  18 DEPEND="zlib? ( sys-libs/zlib )"
  19 RDEPEND="${DEPEND}"
  20
  21 src_configure() {
  22         # The ./configure file is handwritten and doesn't support a `make
  23         # install` target, so there are no --prefix options. The econf
  24         # function appends those automatically, so we can't use it.
  25         ./configure \
  26                 $(use_enable ipv6) \
  27                 $(use_enable zlib) \
  28                 || die "./configure failed"
  29 }
  30
  31 src_compile() {
  32         # We can also pass AWK and PYTHON environment variables to emake,
  33         # but those should be available via the default 'awk' and 'python'
  34         # symlinks.
  35         emake \
  36                 AR="$(tc-getAR)" \
  37                 CC="$(tc-getCC)" \
  38                 RANLIB="$(tc-getRANLIB)" \
  39                 || die "emake failed"
  40 }
  41
  42 src_install() {
  43         dosbin rbldnsd
  44         doman rbldnsd.8
  45         keepdir /var/db/rbldnsd
  46         dodoc CHANGES* TODO NEWS README*
  47         newinitd "${FILESDIR}"/initd-${PV} rbldnsd
  48         newconfd "${FILESDIR}"/confd-${PV} rbldnsd
  49 }
  50
  51 pkg_postinst() {
  52         enewgroup rbldns
  53         enewuser rbldns -1 -1 /var/db/rbldnsd rbldns
  54         chown rbldns:rbldns /var/db/rbldnsd
  55 }