net-dns/djbdns/djbdns-1.05-r25.ebuild

   1 # Copyright 1999-2012 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: /var/cvsroot/gentoo-x86/net-dns/djbdns/djbdns-1.05-r25.ebuild,v 1.2 2012/03/24 09:26:17 hwoarang Exp $
   4
   5 EAPI="2"
   6 inherit eutils flag-o-matic toolchain-funcs
   7
   8 DESCRIPTION="Excellent high-performance DNS services"
   9 HOMEPAGE="http://cr.yp.to/djbdns.html"
  10 IPV6_PATCH="test23"
  11
  12 SRC_URI="http://cr.yp.to/djbdns/${P}.tar.gz
  13         ipv6? ( http://www.fefe.de/dns/${P}-${IPV6_PATCH}.diff.bz2 )"
  14
  15 SLOT="0"
  16 LICENSE="public-domain"
  17 KEYWORDS="~alpha ~amd64 ~hppa ~mips ~ppc ~ppc64 ~sparc ~x86"
  18 IUSE="doc ipv6 selinux static"
  19
  20 DEPEND=""
  21 RDEPEND="${DEPEND}
  22         virtual/daemontools
  23         sys-apps/ucspi-tcp
  24         doc? ( app-doc/djbdns-man )
  25         selinux? ( sec-policy/selinux-djbdns )
  26 "
  27
  28 src_prepare() {
  29         echo
  30         elog 'Several patches have been dropped from this ebuild.'
  31         elog 'Please place custom patches in,'
  32         elog
  33         elog '  /etc/portage/patches/net-dns/djbdns'
  34         elog
  35         elog 'Some of them can be found at http://tinydns.org/ or'
  36         elog 'http://homepage.ntlworld.com/jonathan.deboynepollard/Softwares/djbdns/'
  37         elog
  38
  39         epatch \
  40                 "${FILESDIR}/headtail.patch" \
  41                 "${FILESDIR}/dnsroots.patch" \
  42                 "${FILESDIR}/dnstracesort.patch" \
  43                 "${FILESDIR}/string_length_255.patch"
  44
  45         # Fix CVE2009-0858
  46         epatch "${FILESDIR}/CVE2009-0858_0001-check-response-domain-name-length.patch"
  47
  48         if use ipv6; then
  49                 elog "At present dnstrace does NOT support IPv6. It will"\
  50                          "be compiled without IPv6 support."
  51                 cp -pR "${S}" "${S}-noipv6"
  52                 # Careful -- >=test21 of the IPv6 patch includes the errno patch
  53                 epatch "${DISTDIR}/${P}-${IPV6_PATCH}.diff.bz2"
  54
  55                 # Fix CVE2008-4392
  56                 epatch \
  57                         "${FILESDIR}/CVE2008-4392_0001-dnscache-merge-similar-outgoing-queries-ipv6.patch" \
  58                         "${FILESDIR}/CVE2008-4392_0002-dnscache-cache-soa-records-ipv6.patch" \
  59                         "${FILESDIR}/makefile-parallel.patch"
  60
  61                 cd "${S}-noipv6"
  62         fi
  63
  64         # Fix CVE2008-4392
  65         epatch \
  66                 "${FILESDIR}/CVE2008-4392_0001-dnscache-merge-similar-outgoing-queries.patch" \
  67                 "${FILESDIR}/CVE2008-4392_0002-dnscache-cache-soa-records.patch"
  68
  69         epatch "${FILESDIR}/${PV}-errno.patch"
  70
  71         cd "${S}"
  72         epatch_user
  73 }
  74
  75 src_compile() {
  76         use static && append-ldflags -static
  77         echo "$(tc-getCC) ${CFLAGS}" > conf-cc
  78         echo "$(tc-getCC) ${LDFLAGS}" > conf-ld
  79         echo "/usr" > conf-home
  80         #emake -j1 || die "emake failed"
  81         emake || die "emake failed"
  82
  83         # If djbdns is compiled with IPv6 support, it breaks dnstrace.
  84         # Therefore we must compile dnstrace separately without IPv6
  85         # support.
  86         if use ipv6; then
  87                 elog "Compiling dnstrace without ipv6 support"
  88                 cd "${S}-noipv6"
  89                 echo "$(tc-getCC) ${CFLAGS}" > conf-cc
  90                 echo "$(tc-getCC) ${LDFLAGS}" > conf-ld
  91                 echo "/usr" > conf-home
  92                 #emake -j1 dnstrace || die "emake failed"
  93                 emake dnstrace || die "emake failed"
  94         fi
  95 }
  96
  97 src_install() {
  98         insinto /etc
  99         doins dnsroots.global || die
 100
 101         into /usr
 102         dobin *-conf dnscache tinydns walldns rbldns pickdns axfrdns \
 103                 *-get *-data *-edit dnsip dnsipq dnsname dnstxt dnsmx \
 104                 dnsfilter random-ip dnsqr dnsq dnstrace dnstracesort || die
 105
 106         if use ipv6; then
 107                 dobin dnsip6 dnsip6q "${S}-noipv6/dnstrace" || die
 108         fi
 109
 110         dodoc CHANGES FILES README SYSDEPS TARGETS TODO VERSION || die
 111
 112         dobin "${FILESDIR}/dnscache-setup" || die
 113         dobin "${FILESDIR}/tinydns-setup" || die
 114         dobin "${FILESDIR}/djbdns-setup" || die
 115 }
 116
 117 pkg_preinst() {
 118         # The nofiles group is no longer provided by baselayout.
 119         # Share it with qmail if possible.
 120         enewgroup nofiles 200
 121
 122         enewuser dnscache -1 -1 -1 nofiles
 123         enewuser dnslog -1 -1 -1 nofiles
 124         enewuser tinydns -1 -1 -1 nofiles
 125 }
 126
 127 pkg_postinst() {
 128         elog "Use dnscache-setup & tinydns-setup or djbdns-setup to configure djbdns."
 129 }