+ from_date = formatTime defaultTimeLocale date_format_padded
+
+
+
+-- | Format a number as a string using a comma as the thousands
+-- separator.
+--
+-- Examples:
+--
+-- >>> format_commas 0
+-- "0"
+-- >>> format_commas 10
+-- "10"
+-- >>> format_commas 100
+-- "100"
+-- >>> format_commas 1000
+-- "1,000"
+-- >>> format_commas 10000
+-- "10,000"
+-- >>> format_commas 100000
+-- "100,000"
+-- >>> format_commas 1000000
+-- "1,000,000"
+--
+format_commas :: Int -> String
+format_commas x =
+ reverse (intercalate "," $ chunksOf 3 $ reverse $ show x)
+
+
+
+-- | Parse \<Earnings\> from an 'AutoRaceResultsListing'. These are
+-- essentially 'Int's, but they look like,
+--
+-- * \<Earnings\>336,826\</Earnings\>
+--
+-- * \<Earnings\>1,000,191\</Earnings\>
+--
+-- * \<Earnings\>TBA\</Earnings\>
+--
+-- Examples:
+--
+-- >>> let tn = text_node "1,000,191"
+-- >>> unpickleDoc xp_earnings tn
+-- Just (Just 1000191)
+--
+-- >>> let tn = text_node "TBA"
+-- >>> unpickleDoc xp_earnings tn
+-- Just Nothing
+--
+xp_earnings :: PU (Maybe Int)
+xp_earnings =
+ (to_earnings, from_earnings) `xpWrap` xpText
+ where
+ strip_commas :: String -> String
+ strip_commas = replace "," ""
+
+ to_earnings :: String -> Maybe Int
+ to_earnings s
+ | s == "TBA" = Nothing
+ | otherwise = Just $ (read . strip_commas) s
+
+ from_earnings :: Maybe Int -> String
+ from_earnings Nothing = "TBA"
+ from_earnings (Just i) = format_commas i
+
+
+
+-- | Pickle a 'Double' that can be missing its leading zero (for
+-- values less than one). For example, we've seen,
+--
+-- <TrackLength KPH=".805">0.5</TrackLength>
+--
+-- Which 'xpPrim' can't handle without the leading
+-- zero. Unfortunately there's no way pickle/unpickle can be
+-- inverses of each other here, since \"0.5\" and \".5\" should
+-- unpickle to the same 'Double'.
+--
+-- Examples:
+--
+-- >>> let tn = text_node "0.5"
+-- >>> unpickleDoc xp_fracpart_only_double tn
+-- Just 0.5
+--
+-- >>> let tn = text_node ".5"
+-- >>> unpickleDoc xp_fracpart_only_double tn
+-- Just 0.5
+--
+-- >>> let tn = text_node "foo"
+-- >>> unpickleDoc xp_fracpart_only_double tn
+-- Nothing
+--
+xp_fracpart_only_double :: PU Double
+xp_fracpart_only_double =
+ (to_double, from_double) `xpWrapMaybe` xpText
+ where
+ -- | Convert a 'String' to a 'Double', maybe. We always prepend a
+ -- zero, since it will fix the fraction-only values, and not hurt
+ -- the ones that already have a leading integer.
+ to_double :: String -> Maybe Double
+ to_double s = readMaybe ("0" ++ s)
+
+ from_double :: Double -> String
+ from_double = show
+
+
+
+-- | (Un)pickle an unpadded 'UTCTime'. Used for example on the
+-- \<RaceDate\> elements in an 'AutoRaceResults' message.
+--
+-- Examples:
+--
+-- >>> let tn = text_node "6/1/2014 1:00:00 PM"
+-- >>> unpickleDoc xp_datetime tn
+-- Just 2014-06-01 13:00:00 UTC
+--
+-- >>> let tn = text_node "5/24/2014 2:45:00 PM"
+-- >>> unpickleDoc xp_datetime tn
+-- Just 2014-05-24 14:45:00 UTC
+--
+-- Padded! For some reason it works with only one zero in front. I
+-- dunno man. NOT required (or even desired?) behavior.
+--
+-- >>> let tn = text_node "05/24/2014 2:45:00 PM"
+-- >>> unpickleDoc xp_datetime tn
+-- Just 2014-05-24 14:45:00 UTC
+--
+xp_datetime :: PU UTCTime
+xp_datetime =
+ (to_datetime, from_datetime) `xpWrapMaybe` xpText
+ where
+ format = date_format ++ " " ++ "%-I:%M:%S %p"
+
+ to_datetime :: String -> Maybe UTCTime
+ to_datetime = parseTime defaultTimeLocale format
+
+ from_datetime :: UTCTime -> String
+ from_datetime = formatTime defaultTimeLocale format
+
+
+
+-- | Takes a 'UTCTime', and returns the English suffix that would be
+-- appropriate after the day of the month. For example, if we have a
+-- UTCTime representing Christmas, this would return \"th\" because
+-- \"th\" is the right suffix of \"December 25th\".
+--
+-- Examples:
+--
+-- >>> import Data.Maybe ( fromJust )
+-- >>> :{
+-- let parse_date :: String -> Maybe UTCTime
+-- parse_date = parseTime defaultTimeLocale date_format
+-- :}
+--
+-- >>> let dates = [ "1/" ++ (d : "/1970") | d <- ['1'..'9'] ]
+-- >>> let suffixes = map (date_suffix . fromJust . parse_date) dates
+-- >>> suffixes
+-- ["st","nd","rd","th","th","th","th","th","th"]
+--
+date_suffix :: UTCTime -> String
+date_suffix t =
+ case (reverse daystr) of
+ [] -> []
+ ('1':_) -> "st"
+ ('2':_) -> "nd"
+ ('3':_) -> "rd"
+ _ -> "th"
+ where
+ daystr = formatTime defaultTimeLocale "%d" t