+
+
+
+
+-- | (Un)pickle a UTCTime without the date portion. Doesn't work if
+-- the fields aren't zero-padded to two characters.
+--
+-- /Examples/:
+--
+-- Padded, should work:
+--
+-- >>> let tn = text_node "04:35 PM"
+-- >>> unpickleDoc xp_time tn
+-- Just 1970-01-01 16:35:00 UTC
+--
+-- Unpadded, should fail:
+--
+-- >>> let tn = text_node "4:35 PM"
+-- >>> unpickleDoc xp_time tn
+-- Nothing
+--
+xp_time :: PU UTCTime
+xp_time =
+ (to_time, from_time) `xpWrapMaybe` xpText
+ where
+ to_time :: String -> Maybe UTCTime
+ to_time = parseTime defaultTimeLocale time_format
+
+ from_time :: UTCTime -> String
+ from_time = formatTime defaultTimeLocale time_format
+
+
+-- | (Un)pickle a UTCTime without the date portion. This differs from
+-- 'xp_time' in that it uses periods in the AM/PM part, i.e. \"A.M.\"
+-- and \"P.M.\" It also doesn't use padding for the \"hours\" part.
+--
+-- /Examples/:
+--
+-- A standard example of the correct form:
+--
+-- >>> let tn = text_node "11:30 A.M."
+-- >>> let (Just result) = unpickleDoc xp_time_dots tn
+-- >>> result
+-- 1970-01-01 11:30:00 UTC
+-- >>> pickleDoc xp_time_dots result
+-- NTree (XTag "/" []) [NTree (XText "11:30 A.M.") []]
+--
+-- Another miracle, it still parses with a leading zero!
+--
+-- >>> let tn = text_node "01:30 A.M."
+-- >>> unpickleDoc xp_time_dots tn
+-- Just 1970-01-01 01:30:00 UTC
+--
+xp_time_dots :: PU UTCTime
+xp_time_dots =
+ (to_time, from_time) `xpWrapMaybe` xpText
+ where
+ -- | The hours arent padded with zeros.
+ nopad_time_format :: String
+ nopad_time_format = "%-I:%M %p"
+
+ to_time :: String -> Maybe UTCTime
+ to_time = (parseTime defaultTimeLocale nopad_time_format) . (replace "." "")
+
+ from_time :: UTCTime -> String
+ from_time t =
+ replace "AM" "A.M." (replace "PM" "P.M." s)
+ where
+ s = formatTime defaultTimeLocale nopad_time_format t
+
+
+-- | (Un)pickle a UTCTime without the date portion, allowing for a
+-- value of \"TBA\" (which gets translated to 'Nothing').
+--
+-- /Examples/:
+--
+-- A failed parse will return 'Nothing':
+--
+-- >>> let tn = text_node "YO"
+-- >>> unpickleDoc xp_tba_time tn
+-- Just Nothing
+--
+-- And so will parsing a \"TBA\":
+--
+-- >>> let tn = text_node "TBA"
+-- >>> unpickleDoc xp_tba_time tn
+-- Just Nothing
+--
+-- But re-pickling 'Nothing' gives only \"TBA\":
+--
+-- >>> pickleDoc xp_tba_time Nothing
+-- NTree (XTag "/" []) [NTree (XText "TBA") []]
+--
+-- A normal time is also parsed successfully, of course:
+--
+-- >>> let tn = text_node "08:10 PM"
+-- >>> unpickleDoc xp_tba_time tn
+-- Just (Just 1970-01-01 20:10:00 UTC)
+--
+xp_tba_time :: PU (Maybe UTCTime)
+xp_tba_time =
+ (to_time, from_time) `xpWrap` xpText
+ where
+ to_time :: String -> Maybe UTCTime
+ to_time s
+ | s == "TBA" = Nothing
+ | otherwise = parseTime defaultTimeLocale time_format s
+
+ from_time :: Maybe UTCTime -> String
+ from_time Nothing = "TBA"
+ from_time (Just t) = formatTime defaultTimeLocale time_format t
+
+
+
+-- | (Un)pickle the \<time_stamp\> element format to/from a 'UTCTime'.
+-- The time_stamp elements look something like,
+--
+-- \<time_stamp\> January 6, 2014, at 10:11 PM ET \</time_stamp\>
+--
+-- TSN doesn't provide a proper time zone name, only \"ET\" for
+-- \"Eastern Time\". But \"Eastern Time\" changes throughout the
+-- year, depending on one's location, for daylight-savings
+-- time. It's really not any more useful to be off by one hour than
+-- it is to be off by 5 hours, so rather than guess at EDT/EST, we
+-- just store the timestamp as UTC.
+--
+-- Examples:
+--
+-- >>> let tn = text_node " January 6, 2014, at 10:11 PM ET "
+-- >>> let (Just tstamp) = unpickleDoc xp_time_stamp tn
+-- >>> tstamp
+-- 2014-01-06 22:11:00 UTC
+-- >>> pickleDoc xp_time_stamp tstamp
+-- NTree (XTag "/" []) [NTree (XText " January 6, 2014, at 10:11 PM ET ") []]
+--
+xp_time_stamp :: PU UTCTime
+xp_time_stamp =
+ (parse_time_stamp, from_time_stamp) `xpWrapMaybe` xpText
+ where
+ -- | We have to re-pad the time_stamp_format with a leading and
+ -- trailing space; see the documentation of 'time_stamp_format'
+ -- for more information.
+ from_time_stamp :: UTCTime -> String
+ from_time_stamp =
+ formatTime defaultTimeLocale (" " ++ time_stamp_format ++ " ")
+
+
+
+-- | (Un)pickle an ambiguous 12-hour AM/PM time, which is ambiguous
+-- because it's missing the AM/PM part.
+--
+-- Examples:
+--
+-- >>> let tn = text_node "8:00"
+-- >>> unpickleDoc xp_ambiguous_time tn
+-- Just 1970-01-01 08:00:00 UTC
+--
+xp_ambiguous_time :: PU UTCTime
+xp_ambiguous_time =
+ (to_time, from_time) `xpWrapMaybe` xpText
+ where
+ ambiguous_time_format :: String
+ ambiguous_time_format = "%-I:%M"
+
+ to_time :: String -> Maybe UTCTime
+ to_time = parseTime defaultTimeLocale ambiguous_time_format
+
+ from_time :: UTCTime -> String
+ from_time =
+ formatTime defaultTimeLocale ambiguous_time_format
+
+
+-- | Pickle a date value from a \<date\> element as they appear in the
+-- early lines. This is a particularly wacky format, but then so is
+-- the associated time (see 'xp_ambiguous_time').
+--
+-- Examples:
+--
+-- >>> let tn = text_node "SUNDAY, MAY 25TH (05/25/2014)"
+-- >>> let (Just result) = unpickleDoc xp_early_line_date tn
+-- >>> result
+-- 2014-05-25 00:00:00 UTC
+-- >>> pickleDoc xp_early_line_date result
+-- NTree (XTag "/" []) [NTree (XText "SUNDAY, MAY 25TH (05/25/2014)") []]
+--
+-- >>> let tn = text_node "SATURDAY, JUNE 7TH (06/07/2014)"
+-- >>> let (Just result) = unpickleDoc xp_early_line_date tn
+-- >>> result
+-- 2014-06-07 00:00:00 UTC
+-- >>> pickleDoc xp_early_line_date result
+-- NTree (XTag "/" []) [NTree (XText "SATURDAY, JUNE 7TH (06/07/2014)") []]
+--
+xp_early_line_date :: PU UTCTime
+xp_early_line_date =
+ (to_time, from_time) `xpWrapMaybe` xpText
+ where
+ -- | We need to create our own time locale that talks IN ALL CAPS.
+ -- Actually, 'parseTime' doesn't seem to care about the
+ -- case. But when we spit it back out again ('formatTime'),
+ -- we'll want it to be in all caps.
+ --
+ caps_time_locale :: TimeLocale
+ caps_time_locale =
+ defaultTimeLocale { wDays = caps_days, months = caps_months }
+
+ caps_days :: [(String,String)]
+ caps_days = map both_to_upper (wDays defaultTimeLocale)
+
+ caps_months :: [(String,String)]
+ caps_months = map both_to_upper (months defaultTimeLocale)
+
+ both_to_upper :: (String,String) -> (String,String)
+ both_to_upper (s1,s2) = (map toUpper s1, map toUpper s2)
+
+ wacko_date_formats :: [String]
+ wacko_date_formats =
+ ["%A, %B %-d" ++ suffix ++ " (" ++ date_format_padded ++ ")" |
+ suffix <- ["ST", "ND", "RD","TH"] ]
+
+ to_time :: String -> Maybe UTCTime
+ to_time s =
+ listToMaybe $ catMaybes possible_parses
+ where
+ possible_parses = [ parseTime caps_time_locale fmt s |
+ fmt <- wacko_date_formats ]
+
+ from_time :: UTCTime -> String
+ from_time t =
+ formatTime caps_time_locale fmt t
+ where
+ upper_suffix = map toUpper (date_suffix t)
+ fmt = "%A, %B %-d" ++ upper_suffix ++ " (" ++ date_format_padded ++ ")"
+
+
+
+-- | Create an 'XmlTree' containing only the given text. This is
+-- useful for testing (un)picklers, where we don't want to have to
+-- bother to create a dummy XML document.
+--
+-- Examples:
+--
+-- >>> text_node "8:00"
+-- NTree (XText "8:00") []
+--
+text_node :: String -> XmlTree
+text_node s = NTree (XText s) []
+
+
+
+--
+-- * Tasty Tests
+--
+
+-- | A list of all tests for this module. This primary exists to
+-- eliminate the unused import/export warnings for 'unpickleDoc' and
+-- 'text_node' which are otherwise only used in the doctests.
+--
+pickler_tests :: TestTree
+pickler_tests =
+ testGroup
+ "Pickler tests"
+ [ test_pickle_of_unpickle_is_identity ]
+
+
+-- | If we unpickle something and then pickle it, we should wind up
+-- with the same thing we started with (plus an additional root
+-- element).
+--
+test_pickle_of_unpickle_is_identity :: TestTree
+test_pickle_of_unpickle_is_identity =
+ testCase "pickle composed with unpickle is (almost) the identity" $ do
+ let tn = text_node "8:00"
+ let (Just utctime) = unpickleDoc xp_ambiguous_time tn
+ let actual = pickleDoc xp_ambiguous_time utctime
+ let expected = NTree (XTag (mkName "/") []) [tn]
+ actual @?= expected