configure.ac

   1 AC_INIT([libsvgtiny-pixbuf],[0.0.2],[michael@orlitzky.com])
   2 AC_CONFIG_AUX_DIR([build-aux])
   3 AM_INIT_AUTOMAKE([-Wall foreign no-dist-gzip dist-xz tar-ustar])
   4 AC_CONFIG_MACRO_DIRS([m4])
   5
   6 AC_PROG_CC
   7 AM_PROG_AR
   8
   9 PKG_CHECK_MODULES([CAIRO], [cairo])
  10 PKG_CHECK_MODULES([GDKPIXBUF], [gdk-pixbuf-2.0])
  11 PKG_CHECK_MODULES([LIBSVGTINY], [libsvgtiny])
  12 PKG_CHECK_MODULES([LIBXML2], [libxml-2.0])
  13
  14 AC_MSG_CHECKING([for gdk-pixbuf module location])
  15 # Hack alert: we need to install our module into this specific
  16 # location... BUT, we also want to respect --prefix, at least to the
  17 # extent that we won't try to install something to, say, /usr when
  18 # we've passed --prefix=/tmp. This little libdir trick prevents
  19 # pkg-config from substituting for ${libdir} where it appears in the
  20 # *.pc file. When we go to actually use gdk_pixbuf_moduledir, the
  21 # variable ${libdir} will be valid in our own build system, and will
  22 # respect the prefix. This means that if you configure this package
  23 # with a different prefix than gdk-pixbuf was, it won't install
  24 # correctly. But hey, make distcheck works?
  25 gdk_pixbuf_moduledir=$($PKG_CONFIG --define-variable=libdir="\${libdir}" --variable gdk_pixbuf_moduledir gdk-pixbuf-2.0)
  26 AC_MSG_RESULT([$gdk_pixbuf_moduledir])
  27 AC_SUBST([gdk_pixbuf_moduledir])
  28
  29 AC_MSG_CHECKING([for gdk-pixbuf-thumbnailer location])
  30 gdk_pixbuf_bindir=$($PKG_CONFIG --variable bindir gdk-pixbuf-2.0)
  31 gdk_pixbuf_thumbnailer="${gdk_pixbuf_bindir}/gdk-pixbuf-thumbnailer"
  32
  33 AS_IF([test -x "${gdk_pixbuf_thumbnailer}"], [
  34   AC_MSG_RESULT([$gdk_pixbuf_thumbnailer])
  35   AC_SUBST([gdk_pixbuf_thumbnailer])
  36 ],[
  37   AC_MSG_RESULT([no])
  38 ])
  39
  40
  41 AC_CONFIG_FILES([
  42   Makefile
  43   libsvgtiny.thumbnailer
  44 ])
  45
  46 LT_INIT([disable-static])
  47 AC_OUTPUT