src/Main.hs

   1 {-# LANGUAGE DoAndIfThenElse #-}
   2 {-# LANGUAGE RecordWildCards #-}
   3
   4 module Main
   5 where
   6
   7 import Control.Concurrent.ParallelIO.Global (parallel, stopGlobalPool)
   8 import Control.Monad (unless)
   9 import qualified Data.ByteString as BS
  10 import qualified Data.ByteString.UTF8 as BSU
  11 import Network.DNS (
  12   Domain,
  13   Resolver,
  14   ResolvConf(..),
  15   defaultResolvConf,
  16   makeResolvSeed,
  17   withResolver)
  18 import Network.DNS.Lookup (lookupMX)
  19 import System.Directory (doesFileExist)
  20 import System.Exit (exitWith, ExitCode(..))
  21 import System.IO (
  22   Handle,
  23   IOMode( WriteMode ),
  24   hClose,
  25   hFlush,
  26   openFile,
  27   stdin,
  28   stdout)
  29
  30
  31 import CommandLine (Args(..), apply_args)
  32 import EmailAddress
  33 import ExitCodes (exit_input_file_doesnt_exist)
  34
  35
  36 -- | Resolver parameters. We increase the default timeout from 3 to 5
  37 --   seconds.
  38 resolv_conf ::  ResolvConf
  39 resolv_conf = defaultResolvConf { resolvTimeout = 5 * 1000 * 1000 }
  40
  41 -- | A list of common domains, there's no need to waste MX lookups
  42 --   on these.
  43 common_domains :: [Domain]
  44 common_domains = map BSU.fromString [ "aol.com",
  45                                       "comcast.net",
  46                                       "gmail.com",
  47                                       "msn.com",
  48                                       "yahoo.com",
  49                                       "verizon.net" ]
  50
  51
  52 -- | Check whether the given domain has a valid MX record.
  53 validate_mx :: Resolver -> Domain -> IO Bool
  54 validate_mx resolver domain
  55   | domain `elem` common_domains = return True
  56   | otherwise = do
  57       result <- lookupMX resolver domain
  58       case result of
  59         Nothing -> return False
  60         _       -> return True
  61
  62
  63 -- | Validate the syntax of an email address by checking its length
  64 --   and validating it against a simple regex.
  65 validate_syntax :: Address -> Bool
  66 validate_syntax address =
  67   (validate_length address) && (validate_regex address)
  68
  69
  70 -- | Validate an email address by doing some simple syntax checks and
  71 --   (if those fail) an MX lookup. We don't count an A record as a mail
  72 --   exchanger.
  73 validate :: Resolver -> Address -> IO (Address, Bool)
  74 validate resolver address = do
  75   let valid_syntax = validate_syntax address
  76   if valid_syntax then do
  77     let (_,domain) = parts address
  78     mx_result <- validate_mx resolver domain
  79     return (address, mx_result)
  80   else
  81     return (address, False)
  82
  83
  84 -- | Append a ByteString to a file Handle, followed by a newline.
  85 append_handle_with_newline :: Handle -> BS.ByteString -> IO ()
  86 append_handle_with_newline h bs = do
  87   BS.hPutStr h bs
  88   BS.hPutStr h newline
  89   where
  90     newline = BSU.fromString "\n"
  91
  92
  93 main :: IO ()
  94 main = do
  95   Args{..} <- apply_args
  96
  97   -- Get the input from either stdin, or the file given on the command
  98   -- line.
  99   input <- case input_file of
 100              Nothing   -> BS.hGetContents stdin
 101              Just path -> do
 102                is_file <- doesFileExist path
 103                unless is_file $
 104                  exitWith (ExitFailure exit_input_file_doesnt_exist)
 105                BS.readFile path
 106
 107   -- Do the same for the output handle and stdout.
 108   output_handle <- case output_file of
 109                      Nothing -> return stdout
 110                      Just path -> openFile path WriteMode
 111
 112   -- Split the input into lines.
 113   let addresses = BSU.lines input
 114
 115   -- And remove the empty ones.
 116   let nonempty_addresses = filter (not . BS.null) addresses
 117
 118   rs <- makeResolvSeed resolv_conf
 119   withResolver rs $ \resolver -> do
 120     -- Construst a list of [IO (Address, Bool)]
 121     let actions = map (validate resolver) nonempty_addresses
 122     -- And compute them in parallel.
 123     results <- parallel actions
 124     stopGlobalPool
 125     -- Find the pairs with a True in the second position.
 126     let good_pairs = filter snd results
 127     -- And output the results.
 128     mapM_ ((append_handle_with_newline output_handle) . fst) good_pairs
 129
 130   -- Clean up. It's safe to try to close stdout.
 131   hFlush output_handle
 132   hClose output_handle