module Tests.Tetrahedron
where

import Test.Framework (Test, testGroup)
import Test.Framework.Providers.HUnit (testCase)
import Test.HUnit
import Test.QuickCheck (Property, (==>))

import Cardinal
import Comparisons
import FunctionValues
import Tests.FunctionValues()
import Tetrahedron
import ThreeDimensional

-- HUnit Tests


-- | Check the volume of a particular tetrahedron against the value
--   computed by hand. Its vertices are in clockwise order, so the
--   volume should be negative.
test_volume1 :: Assertion
test_volume1 =
    assertEqual "volume is correct" True (vol ~= (-1/3))
    where
      p0 = (0, -0.5, 0)
      p1 = (0, 0.5, 0)
      p2 = (2, 0, 0)
      p3 = (1, 0, 1)
      t = Tetrahedron { v0 = p0,
                        v1 = p1,
                        v2 = p2,
                        v3 = p3,
                        fv = empty_values }
      vol = volume t


-- | Check the volume of a particular tetrahedron (computed by hand)
--   and whether or not it contains a specific point chosen to be
--   inside of it. Its vertices are in counter-clockwise order, so the
--   volume should be positive.
tetrahedron2_geometry_tests :: Test.Framework.Test
tetrahedron2_geometry_tests =
  testGroup "tetrahedron2 geometry"
              [ testCase "volume1" volume1,
                testCase "contains point1" contains_point1]
  where
    p0 = (0, -0.5, 0)
    p1 = (2, 0, 0)
    p2 = (0, 0.5, 0)
    p3 = (1, 0, 1)
    t = Tetrahedron { v0 = p0,
                      v1 = p1,
                      v2 = p2,
                      v3 = p3,
                      fv = empty_values }

    volume1 :: Assertion
    volume1 = assertEqual "volume1 is correct" True (vol ~= (1/3))
      where
        vol = volume t

    contains_point1 :: Assertion
    contains_point1 = assertEqual "contains an inner point" True contained
        where
          inner_point = (1, 0, 0.5)
          contained = contains_point t inner_point


-- | Ensure that a tetrahedron does not contain a particular point chosen to
--   be outside of it (first test).
test_doesnt_contain_point1 :: Assertion
test_doesnt_contain_point1 =
    assertEqual "doesn't contain an exterior point" False contained
    where
      p0 = (0, -0.5, 0)
      p1 = (0, 0.5, 0)
      p2 = (2, 0, 0)
      p3 = (1, 0, 1)
      exterior_point = (5, 2, -9.0212)
      t = Tetrahedron { v0 = p0,
                        v1 = p1,
                        v2 = p2,
                        v3 = p3,
                        fv = empty_values }
      contained = contains_point t exterior_point


-- | Ensure that a tetrahedron does not contain a particular point chosen to
--   be outside of it (second test).
test_doesnt_contain_point2 :: Assertion
test_doesnt_contain_point2 =
    assertEqual "doesn't contain an exterior point" False contained
    where
      p0 = (0, 1, 1)
      p1 = (1, 1, 1)
      p2 = (0.5, 0.5, 1)
      p3 = (0.5, 0.5, 0.5)
      exterior_point = (0, 0, 0)
      t = Tetrahedron { v0 = p0,
                        v1 = p1,
                        v2 = p2,
                        v3 = p3,
                        fv = empty_values }
      contained = contains_point t exterior_point


-- | Ensure that a tetrahedron does not contain a particular point chosen to
--   be outside of it (third test).
test_doesnt_contain_point3 :: Assertion
test_doesnt_contain_point3 =
    assertEqual "doesn't contain an exterior point" False contained
    where
      p0 = (1, 1, 1)
      p1 = (1, 0, 1)
      p2 = (0.5, 0.5, 1)
      p3 = (0.5, 0.5, 0.5)
      exterior_point = (0, 0, 0)
      t = Tetrahedron { v0 = p0,
                        v1 = p1,
                        v2 = p2,
                        v3 = p3,
                        fv = empty_values }
      contained = contains_point t exterior_point


-- | Ensure that a tetrahedron does not contain a particular point chosen to
--   be outside of it (fourth test).
test_doesnt_contain_point4 :: Assertion
test_doesnt_contain_point4 =
    assertEqual "doesn't contain an exterior point" False contained
    where
      p0 = (1, 0, 1)
      p1 = (0, 0, 1)
      p2 = (0.5, 0.5, 1)
      p3 = (0.5, 0.5, 0.5)
      exterior_point = (0, 0, 0)
      t = Tetrahedron { v0 = p0,
                        v1 = p1,
                        v2 = p2,
                        v3 = p3,
                        fv = empty_values }
      contained = contains_point t exterior_point


-- | Ensure that a tetrahedron does not contain a particular point chosen to
--   be outside of it (fifth test).
test_doesnt_contain_point5 :: Assertion
test_doesnt_contain_point5 =
    assertEqual "doesn't contain an exterior point" False contained
    where
      p0 = (0, 0, 1)
      p1 = (0, 1, 1)
      p2 = (0.5, 0.5, 1)
      p3 = (0.5, 0.5, 0.5)
      exterior_point = (0, 0, 0)
      t = Tetrahedron { v0 = p0,
                        v1 = p1,
                        v2 = p2,
                        v3 = p3,
                        fv = empty_values }
      contained = contains_point t exterior_point


-- | The barycentric coordinate of v0 with respect to itself should
--   be one.
prop_b0_v0_always_unity :: Tetrahedron -> Property
prop_b0_v0_always_unity t =
    (volume t) > 0 ==> (b0 t) (v0 t) ~= 1.0

-- | The barycentric coordinate of v1 with respect to v0 should
--   be zero.
prop_b0_v1_always_zero :: Tetrahedron -> Property
prop_b0_v1_always_zero t =
    (volume t) > 0 ==> (b0 t) (v1 t) ~= 0

-- | The barycentric coordinate of v2 with respect to v0 should
--   be zero.
prop_b0_v2_always_zero :: Tetrahedron -> Property
prop_b0_v2_always_zero t =
    (volume t) > 0 ==> (b0 t) (v2 t) ~= 0

-- | The barycentric coordinate of v3 with respect to v0 should
--   be zero.
prop_b0_v3_always_zero :: Tetrahedron -> Property
prop_b0_v3_always_zero t =
    (volume t) > 0 ==> (b0 t) (v3 t) ~= 0

-- | The barycentric coordinate of v1 with respect to itself should
--   be one.
prop_b1_v1_always_unity :: Tetrahedron -> Property
prop_b1_v1_always_unity t =
    (volume t) > 0 ==> (b1 t) (v1 t) ~= 1.0

-- | The barycentric coordinate of v0 with respect to v1 should
--   be zero.
prop_b1_v0_always_zero :: Tetrahedron -> Property
prop_b1_v0_always_zero t =
    (volume t) > 0 ==> (b1 t) (v0 t) ~= 0

-- | The barycentric coordinate of v2 with respect to v1 should
--   be zero.
prop_b1_v2_always_zero :: Tetrahedron -> Property
prop_b1_v2_always_zero t =
    (volume t) > 0 ==> (b1 t) (v2 t) ~= 0

-- | The barycentric coordinate of v3 with respect to v1 should
--   be zero.
prop_b1_v3_always_zero :: Tetrahedron -> Property
prop_b1_v3_always_zero t =
    (volume t) > 0 ==> (b1 t) (v3 t) ~= 0

-- | The barycentric coordinate of v2 with respect to itself should
--   be one.
prop_b2_v2_always_unity :: Tetrahedron -> Property
prop_b2_v2_always_unity t =
    (volume t) > 0 ==> (b2 t) (v2 t) ~= 1.0

-- | The barycentric coordinate of v0 with respect to v2 should
--   be zero.
prop_b2_v0_always_zero :: Tetrahedron -> Property
prop_b2_v0_always_zero t =
    (volume t) > 0 ==> (b2 t) (v0 t) ~= 0

-- | The barycentric coordinate of v1 with respect to v2 should
--   be zero.
prop_b2_v1_always_zero :: Tetrahedron -> Property
prop_b2_v1_always_zero t =
    (volume t) > 0 ==> (b2 t) (v1 t) ~= 0

-- | The barycentric coordinate of v3 with respect to v2 should
--   be zero.
prop_b2_v3_always_zero :: Tetrahedron -> Property
prop_b2_v3_always_zero t =
    (volume t) > 0 ==> (b2 t) (v3 t) ~= 0

-- | The barycentric coordinate of v3 with respect to itself should
--   be one.
prop_b3_v3_always_unity :: Tetrahedron -> Property
prop_b3_v3_always_unity t =
    (volume t) > 0 ==> (b3 t) (v3 t) ~= 1.0

-- | The barycentric coordinate of v0 with respect to v3 should
--   be zero.
prop_b3_v0_always_zero :: Tetrahedron -> Property
prop_b3_v0_always_zero t =
    (volume t) > 0 ==> (b3 t) (v0 t) ~= 0

-- | The barycentric coordinate of v1 with respect to v3 should
--   be zero.
prop_b3_v1_always_zero :: Tetrahedron -> Property
prop_b3_v1_always_zero t =
    (volume t) > 0 ==> (b3 t) (v1 t) ~= 0

-- | The barycentric coordinate of v2 with respect to v3 should
--   be zero.
prop_b3_v2_always_zero :: Tetrahedron -> Property
prop_b3_v2_always_zero t =
    (volume t) > 0 ==> (b3 t) (v2 t) ~= 0


-- | Used for convenience in the next few tests; not a test itself.
p :: Tetrahedron -> Int -> Int -> Int -> Int -> Double
p t i j k l = (polynomial t) (xi t i j k l)

-- | Given in Sorokina and Zeilfelder, p. 78.
prop_c3000_identity :: Tetrahedron -> Property
prop_c3000_identity t =
    (volume t) > 0 ==>
               c t 3 0 0 0 ~= p t 3 0 0 0

-- | Given in Sorokina and Zeilfelder, p. 78.
prop_c2100_identity :: Tetrahedron -> Property
prop_c2100_identity t =
    (volume t) > 0 ==>
      c t 2 1 0 0 ~= (term1 - term2 + term3 - term4)
        where
          term1 = (1/3)*(p t 0 3 0 0)
          term2 = (5/6)*(p t 3 0 0 0)
          term3 = 3*(p t 2 1 0 0)
          term4 = (3/2)*(p t 1 2 0 0)

-- | Given in Sorokina and Zeilfelder, p. 78.
prop_c1110_identity :: Tetrahedron -> Property
prop_c1110_identity t =
    (volume t) > 0 ==>
       c t 1 1 1 0 ~= (term1 + term2 - term3 - term4)
        where
          term1 = (1/3)*((p t 3 0 0 0) + (p t 0 3 0 0) + (p t 0 0 3 0))
          term2 = (9/2)*(p t 1 1 1 0)
          term3 = (3/4)*((p t 2 1 0 0) + (p t 1 2 0 0) + (p t 2 0 1 0))
          term4 = (3/4)*((p t 1 0 2 0) + (p t 0 2 1 0) + (p t 0 1 2 0))

prop_x_rotation_doesnt_affect_front :: Tetrahedron -> Bool
prop_x_rotation_doesnt_affect_front t =
    expr1 == expr2
    where
      fv0 = Tetrahedron.fv t
      fv1 = rotate cwx (Tetrahedron.fv t)
      expr1 = front fv0
      expr2 = front fv1

prop_x_rotation_doesnt_affect_back :: Tetrahedron -> Bool
prop_x_rotation_doesnt_affect_back t =
    expr1 == expr2
    where
      fv0 = Tetrahedron.fv t
      fv1 = rotate cwx (Tetrahedron.fv t)
      expr1 = back fv0
      expr2 = back fv1


prop_y_rotation_doesnt_affect_left :: Tetrahedron -> Bool
prop_y_rotation_doesnt_affect_left t =
    expr1 == expr2
    where
      fv0 = Tetrahedron.fv t
      fv1 = rotate cwy (Tetrahedron.fv t)
      expr1 = left fv0
      expr2 = left fv1

prop_y_rotation_doesnt_affect_right :: Tetrahedron -> Bool
prop_y_rotation_doesnt_affect_right t =
    expr1 == expr2
    where
      fv0 = Tetrahedron.fv t
      fv1 = rotate cwy (Tetrahedron.fv t)
      expr1 = right fv0
      expr2 = right fv1


prop_z_rotation_doesnt_affect_down :: Tetrahedron -> Bool
prop_z_rotation_doesnt_affect_down t =
    expr1 == expr2
    where
      fv0 = Tetrahedron.fv t
      fv1 = rotate cwz (Tetrahedron.fv t)
      expr1 = down fv0
      expr2 = down fv1


prop_z_rotation_doesnt_affect_top :: Tetrahedron -> Bool
prop_z_rotation_doesnt_affect_top t =
    expr1 == expr2
    where
      fv0 = Tetrahedron.fv t
      fv1 = rotate cwz (Tetrahedron.fv t)
      expr1 = top fv0
      expr2 = top fv1

prop_swapping_vertices_doesnt_affect_coefficients1 :: Tetrahedron -> Bool
prop_swapping_vertices_doesnt_affect_coefficients1 t =
      c t 0 0 1 2 == c t' 0 0 1 2
        where
          t' = t { v0 = (v1 t), v1 = (v0 t) }

prop_swapping_vertices_doesnt_affect_coefficients2 :: Tetrahedron -> Bool
prop_swapping_vertices_doesnt_affect_coefficients2 t =
      c t 0 1 1 1 == c t' 0 1 1 1
        where
          t' = t { v2 = (v3 t), v3 = (v2 t) }

prop_swapping_vertices_doesnt_affect_coefficients3 :: Tetrahedron -> Bool
prop_swapping_vertices_doesnt_affect_coefficients3 t =
      c t 2 1 0 0 == c t' 2 1 0 0
        where
          t' = t { v2 = (v3 t), v3 = (v2 t) }

prop_swapping_vertices_doesnt_affect_coefficients4 :: Tetrahedron -> Bool
prop_swapping_vertices_doesnt_affect_coefficients4 t =
      c t 2 0 0 1 == c t' 2 0 0 1
        where
          t' = t { v0 = (v3 t), v3 = (v0 t) }