-- | The Grid module just contains the Grid type and two constructors
--   for it. We hide the main Grid constructor because we don't want
--   to allow instantiation of a grid with h <= 0.
module Grid
where

import Test.QuickCheck (Arbitrary(..), Gen, Positive(..))

import Cube (Cube(Cube), find_containing_tetrahedra)
import FunctionValues
import Misc (flatten)
import Point (Point)
import Tetrahedron (polynomial)
import ThreeDimensional (contains_point)


-- | Our problem is defined on a Grid. The grid size is given by the
--   positive number h. The function values are the values of the
--   function at the grid points, which are distance h from one
--   another in each direction (x,y,z).
data Grid = Grid { h :: Double, -- MUST BE GREATER THAN ZERO!
                   function_values :: [[[Double]]] }
          deriving (Eq, Show)


instance Arbitrary Grid where
    arbitrary = do
      (Positive h') <- arbitrary :: Gen (Positive Double)
      fvs <- arbitrary :: Gen [[[Double]]]
      return (make_grid h' fvs)


-- | The constructor that we want people to use. If we're passed a
--   non-positive grid size, we throw an error.
make_grid :: Double -> [[[Double]]] -> Grid
make_grid grid_size values
    | grid_size <= 0 = error "grid size must be positive"
    | otherwise = Grid grid_size values


-- | Creates an empty grid with grid size 1.
empty_grid :: Grid
empty_grid = Grid 1 [[[]]]


-- | Returns a three-dimensional list of cubes centered on the grid
--   points of g with the appropriate 'FunctionValues'.
cubes :: Grid -> [[[Cube]]]
cubes g
    | fvs == [[[]]] = [[[]]]
    | head fvs == [[]] = [[[]]]
    | otherwise =
        [[[ Cube (h g) i j k (make_values fvs i j k) | i <- [0..xsize]]
              | j <- [0..ysize]]
              | k <- [0..zsize]]
    where
      fvs = function_values g
      zsize = (length fvs) - 1
      ysize = length (head fvs) - 1
      xsize = length (head $ head fvs) - 1


-- | Takes a grid and a position as an argument and returns the cube
--   centered on that position. If there is no cube there (i.e. the
--   position is outside of the grid), it will return 'Nothing'.
cube_at :: Grid -> Int -> Int -> Int -> Maybe Cube
cube_at g i j k
    | i < 0 = Nothing
    | j < 0 = Nothing
    | k < 0 = Nothing
    | i >= length (cubes g) = Nothing
    | j >= length ((cubes g) !! i) = Nothing
    | k >= length (((cubes g) !! i) !! j) = Nothing
    | otherwise = Just $ (((cubes g) !! i) !! j) !! k


-- | Takes a 'Grid', and returns all 'Cube's belonging to it that
--   contain the given 'Point'.
find_containing_cubes :: Grid -> Point -> [Cube]
find_containing_cubes g p =
    filter contains_our_point all_cubes
    where
      all_cubes = flatten $ cubes g
      contains_our_point = flip contains_point p



zoom :: Grid -> Int -> [[[Double]]]
zoom g scale_factor
    | fvs == [[[]]] = []
    | head fvs == [[]] = []
    | otherwise =
        [[[f p | i <- [0..scaled_zsize],
                 let i' = scale_dimension i,
                 let j' = scale_dimension j,
                 let k' = scale_dimension k,
                 let p = (i', j', k') :: Point,
                 let c = (find_containing_cubes g p) !! 0,
                 let t = (find_containing_tetrahedra c p) !! 0,
                 let f = polynomial t]
                 | j <- [0..scaled_ysize]]
                   | k <- [0..scaled_xsize]]
  where
    scale_dimension :: Int -> Double
    scale_dimension x = (fromIntegral x) / (fromIntegral scale_factor)

    fvs = function_values g
    scaled_zsize = ((length fvs) - 1) * scale_factor
    scaled_ysize = (length (head fvs) - 1) * scale_factor
    scaled_xsize = (length (head $ head fvs) - 1) * scale_factor