{-# LANGUAGE RebindableSyntax #-}

-- | Stuff for which I'm too lazy to come up with a decent name.
module Misc
where

import NumericPrelude
import Algebra.Field
import Algebra.ToInteger

-- | Partition the interval [@a@, @b@] into @n@ subintervals, which we
--   then return as a list of pairs.
--
--   Examples:
--
--   >>> partition 1 (-1) 1
--   [(-1.0,1.0)]
--
--   >>> partition 4 (-1) 1
--   [(-1.0,-0.5),(-0.5,0.0),(0.0,0.5),(0.5,1.0)]
--
partition :: (Algebra.Field.C a, Algebra.ToInteger.C b, Enum b)
          => b -- ^ The number of subintervals to use, @n@
          -> a -- ^ The \"left\" endpoint of the interval, @a@
          -> a -- ^ The \"right\" endpoint of the interval, @b@
          -> [(a,a)]
 -- Somebody asked for zero subintervals? Ok.
partition 0 _ _ = []
partition n a b
  | n < 0 = error "partition: asked for a negative number of subintervals"
  | otherwise =
    [ (xi, xj) | k <- [0..n-1],
                 let k' = fromIntegral k,
                 let xi = a + k'*h,
                 let xj = a + (k'+1)*h ]
    where
      h = (b-a)/(fromIntegral $ toInteger n)