dev-lang/php/php-5.6.4-r1.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI=5
   6
   7 inherit eutils autotools flag-o-matic versionator depend.apache apache-module db-use libtool systemd
   8
   9 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
  10
  11 function php_get_uri ()
  12 {
  13         case "${1}" in
  14                 "php-pre")
  15                         echo "http://downloads.php.net/dsp/${2}"
  16                 ;;
  17                 "php")
  18                         echo "http://www.php.net/distributions/${2}"
  19                 ;;
  20                 "olemarkus")
  21                         echo "http://dev.gentoo.org/~olemarkus/php/${2}"
  22                 ;;
  23                 "gentoo")
  24                         echo "mirror://gentoo/${2}"
  25                 ;;
  26                 *)
  27                         die "unhandled case in php_get_uri"
  28                 ;;
  29         esac
  30 }
  31
  32 PHP_MV="$(get_major_version)"
  33 SLOT="$(get_version_component_range 1-2)"
  34
  35 # alias, so we can handle different types of releases (finals, rcs, alphas,
  36 # betas, ...) w/o changing the whole ebuild
  37 PHP_PV="${PV/_rc/RC}"
  38 PHP_PV="${PHP_PV/_alpha/alpha}"
  39 PHP_PV="${PHP_PV/_beta/beta}"
  40 PHP_RELEASE="php"
  41 [[ ${PV} == ${PV/_alpha/} ]] || PHP_RELEASE="php-pre"
  42 [[ ${PV} == ${PV/_beta/} ]] || PHP_RELEASE="php-pre"
  43 [[ ${PV} == ${PV/_rc/} ]] || PHP_RELEASE="php-pre"
  44 PHP_P="${PN}-${PHP_PV}"
  45
  46 PHP_SRC_URI="$(php_get_uri "${PHP_RELEASE}" "${PHP_P}.tar.bz2")"
  47
  48 PHP_FPM_CONF_VER="1"
  49
  50 SRC_URI="${PHP_SRC_URI}"
  51
  52 DESCRIPTION="The PHP language runtime engine: CLI, CGI, FPM/FastCGI, Apache2 and embed SAPIs"
  53 HOMEPAGE="http://php.net/"
  54 LICENSE="PHP-3"
  55
  56 S="${WORKDIR}/${PHP_P}"
  57
  58 # We can build the following SAPIs in the given order
  59 SAPIS="embed cli cgi fpm apache2"
  60
  61 # SAPIs and SAPI-specific USE flags (cli SAPI is default on):
  62 IUSE="${IUSE}
  63         ${SAPIS/cli/+cli}
  64         threads"
  65
  66 IUSE="${IUSE} bcmath berkdb bzip2 calendar cdb cjk
  67         crypt +ctype curl debug
  68         enchant exif frontbase +fileinfo +filter firebird
  69         flatfile ftp gd gdbm gmp +hash +iconv imap inifile
  70         intl iodbc ipv6 +json kerberos ldap ldap-sasl libedit mhash
  71         mssql mysql libmysqlclient mysqli nls
  72         oci8-instant-client odbc +opcache pcntl pdo pdo-dblib pdo-mysql pdo-oci
  73         pdo-odbc pdo-pgsql pdo-sqlite+phar +posix postgres qdbm readline recode
  74         selinux +session sharedmem +simplexml snmp soap sockets spell sqlite ssl
  75         sybase-ct sysvipc systemd tidy +tokenizer truetype unicode vpx wddx
  76         +xml xmlreader xmlwriter xmlrpc xpm xslt zip zlib"
  77
  78 DEPEND="
  79         >=app-admin/eselect-php-0.7.1-r3[apache2?,fpm?]
  80         >=dev-libs/libpcre-8.32[unicode]
  81         apache2? ( || ( >=www-servers/apache-2.4[apache2_modules_unixd,threads=]
  82                 <www-servers/apache-2.4[threads=] ) )
  83         berkdb? ( =sys-libs/db-4* )
  84         bzip2? ( app-arch/bzip2 )
  85         cdb? ( || ( dev-db/cdb dev-db/tinycdb ) )
  86         cjk? ( !gd? (
  87                 virtual/jpeg:0
  88                 media-libs/libpng:0=
  89                 sys-libs/zlib
  90         ) )
  91         crypt? ( >=dev-libs/libmcrypt-2.4 )
  92         curl? ( >=net-misc/curl-7.10.5 )
  93         enchant? ( app-text/enchant )
  94         exif? ( !gd? (
  95                 virtual/jpeg:0
  96                 media-libs/libpng:0=
  97                 sys-libs/zlib
  98         ) )
  99         firebird? ( dev-db/firebird )
 100         gd? ( virtual/jpeg:0 media-libs/libpng:0= sys-libs/zlib )
 101         gdbm? ( >=sys-libs/gdbm-1.8.0 )
 102         gmp? ( >=dev-libs/gmp-4.1.2 )
 103         iconv? ( virtual/libiconv )
 104         imap? ( virtual/imap-c-client[ssl=] )
 105         intl? ( dev-libs/icu:= )
 106         iodbc? ( dev-db/libiodbc )
 107         kerberos? ( virtual/krb5 )
 108         ldap? ( >=net-nds/openldap-1.2.11 )
 109         ldap-sasl? ( dev-libs/cyrus-sasl >=net-nds/openldap-1.2.11 )
 110         libedit? ( || ( sys-freebsd/freebsd-lib dev-libs/libedit ) )
 111         mssql? ( dev-db/freetds[mssql] )
 112         libmysqlclient? (
 113                 mysql? ( virtual/mysql )
 114                 mysqli? ( >=virtual/mysql-4.1 )
 115         )
 116         nls? ( sys-devel/gettext )
 117         oci8-instant-client? ( dev-db/oracle-instantclient-basic )
 118         odbc? ( >=dev-db/unixODBC-1.8.13 )
 119         postgres? ( dev-db/postgresql )
 120         qdbm? ( dev-db/qdbm )
 121         readline? ( sys-libs/readline )
 122         recode? ( app-text/recode )
 123         sharedmem? ( dev-libs/mm )
 124         simplexml? ( >=dev-libs/libxml2-2.6.8 )
 125         snmp? ( >=net-analyzer/net-snmp-5.2 )
 126         soap? ( >=dev-libs/libxml2-2.6.8 )
 127         spell? ( >=app-text/aspell-0.50 )
 128         sqlite? ( >=dev-db/sqlite-3.7.6.3 )
 129         ssl? ( >=dev-libs/openssl-0.9.7 )
 130         sybase-ct? ( dev-db/freetds )
 131         tidy? ( app-text/htmltidy )
 132         truetype? (
 133                 =media-libs/freetype-2*
 134                 >=media-libs/t1lib-5.0.0
 135                 !gd? (
 136                         virtual/jpeg:0 media-libs/libpng:0= sys-libs/zlib )
 137         )
 138         unicode? ( dev-libs/oniguruma )
 139         vpx? ( media-libs/libvpx )
 140         wddx? ( >=dev-libs/libxml2-2.6.8 )
 141         xml? ( >=dev-libs/libxml2-2.6.8 )
 142         xmlrpc? ( >=dev-libs/libxml2-2.6.8 virtual/libiconv )
 143         xmlreader? ( >=dev-libs/libxml2-2.6.8 )
 144         xmlwriter? ( >=dev-libs/libxml2-2.6.8 )
 145         xpm? (
 146                 x11-libs/libXpm
 147                 virtual/jpeg:0
 148                 media-libs/libpng:0= sys-libs/zlib
 149         )
 150         xslt? ( dev-libs/libxslt >=dev-libs/libxml2-2.6.8 )
 151         zip? ( sys-libs/zlib )
 152         zlib? ( sys-libs/zlib )
 153         virtual/mta
 154 "
 155
 156 php="=${CATEGORY}/${PF}"
 157
 158 REQUIRED_USE="
 159         truetype? ( gd )
 160         vpx? ( gd )
 161         cjk? ( gd )
 162         exif? ( gd )
 163
 164         xpm? ( gd )
 165         gd? ( zlib )
 166         simplexml? ( xml )
 167         soap? ( xml )
 168         wddx? ( xml )
 169         xmlrpc? ( || ( xml iconv ) )
 170         xmlreader? ( xml )
 171         xslt? ( xml )
 172         ldap-sasl? ( ldap )
 173         mhash? ( hash )
 174         phar? ( hash )
 175         libmysqlclient? ( || (
 176                 mysql
 177                 mysqli
 178                 pdo-mysql
 179         ) )
 180
 181         pdo-dblib? ( mssql )
 182         pdo-oci? ( oci8-instant-client )
 183         pdo-odbc? ( odbc )
 184         pdo-mysql? ( mysql )
 185         pdo-pgsql? ( postgres )
 186         pdo-sqlite? ( sqlite )
 187         qdbm? ( !gdbm )
 188         readline? ( !libedit )
 189         recode? ( !imap !mysql !mysqli )
 190         sharedmem? ( !threads )
 191
 192         !cli? ( !cgi? ( !fpm? ( !apache2? ( !embed? ( cli ) ) ) ) )"
 193
 194 RDEPEND="${DEPEND}"
 195
 196 RDEPEND="${RDEPEND}
 197         fpm? (
 198                 selinux? ( sec-policy/selinux-phpfpm )
 199                 systemd? ( sys-apps/systemd ) )"
 200
 201 DEPEND="${DEPEND}
 202         sys-devel/flex
 203         >=sys-devel/m4-1.4.3
 204         >=sys-devel/libtool-1.5.18"
 205
 206 # Allow users to install production version if they want to
 207
 208 case "${PHP_INI_VERSION}" in
 209         production|development)
 210                 ;;
 211         *)
 212                 PHP_INI_VERSION="development"
 213                 ;;
 214 esac
 215
 216 PHP_INI_UPSTREAM="php.ini-${PHP_INI_VERSION}"
 217 PHP_INI_FILE="php.ini"
 218
 219 want_apache
 220
 221 pkg_setup() {
 222         depend.apache_pkg_setup
 223 }
 224
 225 php_install_ini() {
 226         local phpsapi="${1}"
 227
 228         # work out where we are installing the ini file
 229         php_set_ini_dir "${phpsapi}"
 230
 231         local phpinisrc="${PHP_INI_UPSTREAM}-${phpsapi}"
 232         cp "${PHP_INI_UPSTREAM}" "${phpinisrc}"
 233
 234         # default to /tmp for save_path, bug #282768
 235         sed -e 's|^;session.save_path .*$|session.save_path = "'"${EPREFIX}"'/tmp"|g' -i "${phpinisrc}"
 236
 237         # Set the extension dir
 238         sed -e "s|^extension_dir .*$|extension_dir = ${extension_dir}|g" -i "${phpinisrc}"
 239
 240         # Set the include path to point to where we want to find PEAR packages
 241         sed -e 's|^;include_path = ".:/php/includes".*|include_path = ".:'"${EPREFIX}"'/usr/share/php'${PHP_MV}':'"${EPREFIX}"'/usr/share/php"|' -i "${phpinisrc}"
 242
 243         dodir "${PHP_INI_DIR#${EPREFIX}}"
 244         insinto "${PHP_INI_DIR#${EPREFIX}}"
 245         newins "${phpinisrc}" "${PHP_INI_FILE}"
 246
 247         elog "Installing php.ini for ${phpsapi} into ${PHP_INI_DIR#${EPREFIX}}"
 248         elog
 249
 250         dodir "${PHP_EXT_INI_DIR#${EPREFIX}}"
 251         dodir "${PHP_EXT_INI_DIR_ACTIVE#${EPREFIX}}"
 252
 253         if use_if_iuse opcache; then
 254                 elog "Adding opcache to $PHP_EXT_INI_DIR"
 255                 echo "zend_extension=${PHP_DESTDIR}/$(get_libdir)/opcache.so" >> "${D}/${PHP_EXT_INI_DIR}"/opcache.ini
 256                 dosym "${PHP_EXT_INI_DIR#${EPREFIX}}/opcache.ini" "${PHP_EXT_INI_DIR_ACTIVE#${EPREFIX}}/opcache.ini"
 257         fi
 258
 259         # SAPI-specific handling
 260
 261         if [[ "${sapi}" == "fpm" ]] ; then
 262                 [[ -z ${PHP_FPM_CONF_VER} ]] && PHP_FPM_CONF_VER=0
 263                 einfo "Installing FPM CGI config file php-fpm.conf"
 264                 insinto "${PHP_INI_DIR#${EPREFIX}}"
 265                 newins "${FILESDIR}/php-fpm-r${PHP_FPM_CONF_VER}.conf" php-fpm.conf
 266
 267                 # Remove bogus /etc/php-fpm.conf.default (bug 359906)
 268                 [[ -f "${ED}/etc/php-fpm.conf.default" ]] && rm "${ED}/etc/php-fpm.conf.default"
 269         fi
 270
 271         # Install PHP ini files into /usr/share/php
 272
 273         dodoc php.ini-development
 274         dodoc php.ini-production
 275
 276 }
 277
 278 php_set_ini_dir() {
 279         PHP_INI_DIR="${EPREFIX}/etc/php/${1}-php${SLOT}"
 280         PHP_EXT_INI_DIR="${PHP_INI_DIR}/ext"
 281         PHP_EXT_INI_DIR_ACTIVE="${PHP_INI_DIR}/ext-active"
 282 }
 283
 284 src_prepare() {
 285         # USE=sharedmem (session/mod_mm to be exact) tries to mmap() this path
 286         # ([empty session.save_path]/session_mm_[sapi][gid].sem)
 287         # there is no easy way to circumvent that, all php calls during
 288         # install use -n, so no php.ini file will be used.
 289         # As such, this is the easiest way to get around
 290         addpredict /session_mm_cli250.sem
 291         addpredict /session_mm_cli0.sem
 292
 293         # Change PHP branding
 294         # Get the alpha/beta/rc version
 295         sed -re "s|^(PHP_EXTRA_VERSION=\").*(\")|\1-pl${PR/r/}-gentoo\2|g" \
 296                 -i configure.in || die "Unable to change PHP branding"
 297
 298         # Patch PHP to show Gentoo as the server platform
 299         sed -e 's/PHP_UNAME=`uname -a | xargs`/PHP_UNAME=`uname -s -n -r -v | xargs`/g' \
 300                 -i configure.in || die "Failed to fix server platform name"
 301
 302         # Prevent PHP from activating the Apache config,
 303         # as we will do that ourselves
 304         sed -i \
 305                 -e "s,-i -a -n php${PHP_MV},-i -n php${PHP_MV},g" \
 306                 -e "s,-i -A -n php${PHP_MV},-i -n php${PHP_MV},g" \
 307                 configure sapi/apache2filter/config.m4 sapi/apache2handler/config.m4
 308
 309         # Patch PHP to support heimdal instead of mit-krb5
 310         if has_version "app-crypt/heimdal" ; then
 311                 sed -e 's|gssapi_krb5|gssapi|g' -i acinclude.m4 \
 312                         || die "Failed to fix heimdal libname"
 313                 sed -e 's|PHP_ADD_LIBRARY(k5crypto, 1, $1)||g' -i acinclude.m4 \
 314                         || die "Failed to fix heimdal crypt library reference"
 315         fi
 316
 317         #Add user patches #357637
 318         epatch_user
 319
 320         #force rebuilding aclocal.m4
 321         rm aclocal.m4
 322         eautoreconf
 323
 324         if [[ ${CHOST} == *-darwin* ]] ; then
 325                 # http://bugs.php.net/bug.php?id=48795, bug #343481
 326                 sed -i -e '/BUILD_CGI="\\$(CC)/s/CC/CXX/' configure || die
 327         fi
 328 }
 329
 330 src_configure() {
 331         addpredict /usr/share/snmp/mibs/.index
 332         addpredict /var/lib/net-snmp/mib_indexes
 333
 334         PHP_DESTDIR="${EPREFIX}/usr/$(get_libdir)/php${SLOT}"
 335
 336         # This is a global variable and should be in caps. It isn't because the
 337         # phpconfutils eclass relies on exactly this name...
 338         # for --with-libdir see bug #327025
 339         my_conf="
 340                 --prefix="${PHP_DESTDIR}"
 341                 --mandir="${PHP_DESTDIR}"/man
 342                 --infodir="${PHP_DESTDIR}"/info
 343                 --libdir="${PHP_DESTDIR}"/lib
 344                 --with-libdir=$(get_libdir)
 345                 --without-pear
 346                 $(use_enable threads maintainer-zts)"
 347
 348         #                             extension           USE flag        shared
 349         my_conf+="
 350         $(use_enable bcmath bcmath )
 351         $(use_with   bzip2 bz2 "${EPREFIX}"/usr)
 352         $(use_enable calendar calendar )
 353         $(use_with   crypt mcrypt "${EPREFIX}"/usr)
 354         $(use_enable ctype ctype )
 355         $(use_with   curl curl "${EPREFIX}"/usr)
 356         $(use_enable debug debug )
 357         $(use_with   enchant enchant "${EPREFIX}"/usr)
 358         $(use_enable exif exif )
 359         $(use_enable fileinfo fileinfo )
 360         $(use_enable filter filter )
 361         $(use_with   firebird interbase "${EPREFIX}"/usr)
 362         $(use_enable ftp ftp )
 363         $(use_with   gmp gmp "${EPREFIX}"/usr)
 364         $(use_enable hash hash )
 365         $(use_with   iconv iconv $(use elibc_glibc || echo "${EPREFIX}"/usr))
 366         $(use_with   imap imap "${EPREFIX}"/usr)
 367         $(use_enable intl intl )
 368         $(use_with   iodbc iodbc "${EPREFIX}"/usr)
 369         $(use_enable ipv6 ipv6 )
 370         $(use_enable json json )
 371         $(use_with   kerberos kerberos "${EPREFIX}"/usr)
 372         $(use_with   ldap ldap "${EPREFIX}"/usr)
 373         $(use_with   ldap-sasl ldap-sasl "${EPREFIX}"/usr)
 374         $(use_with   libedit libedit "${EPREFIX}"/usr)
 375         $(use_with   mhash mhash "${EPREFIX}"/usr)
 376         $(use_with   mssql mssql "${EPREFIX}"/usr)
 377         $(use_with   nls gettext "${EPREFIX}"/usr)
 378         $(use_with   oci8-instant-client oci8)
 379         $(use_with   odbc unixODBC "${EPREFIX}"/usr)
 380         $(use_enable opcache opcache )
 381         $(use_enable pcntl pcntl )
 382         $(use_enable pdo pdo )
 383         $(use_with   pdo-dblib pdo-dblib )
 384         $(use_with   pdo-oci pdo-oci )
 385         $(use_with   pdo-odbc pdo-odbc unixODBC,"${EPREFIX}"/usr)
 386         $(use_with   pdo-pgsql pdo-pgsql )
 387         $(use_with   pdo-sqlite pdo-sqlite "${EPREFIX}"/usr)
 388         $(use_enable phar phar )
 389         $(use_enable posix posix )
 390         $(use_with   postgres pgsql "${EPREFIX}"/usr)
 391         $(use_with   spell pspell "${EPREFIX}"/usr)
 392         $(use_with   readline readline "${EPREFIX}"/usr)
 393         $(use_with   recode recode "${EPREFIX}"/usr)
 394         $(use_enable sharedmem shmop )
 395         $(use_enable simplexml simplexml )
 396         $(use_with   snmp snmp "${EPREFIX}"/usr)
 397         $(use_enable soap soap )
 398         $(use_enable sockets sockets )
 399         $(use_with   sqlite sqlite3 "${EPREFIX}"/usr)
 400         $(use_with   ssl openssl "${EPREFIX}"/usr)
 401         $(use_with   ssl openssl-dir "${EPREFIX}"/usr)
 402         $(use_with   sybase-ct sybase-ct "${EPREFIX}"/usr)
 403         $(use_with   systemd fpm-systemd)
 404         $(use_enable sysvipc sysvmsg )
 405         $(use_enable sysvipc sysvsem )
 406         $(use_enable sysvipc sysvshm )
 407         $(use_with   tidy tidy "${EPREFIX}"/usr)
 408         $(use_enable tokenizer tokenizer )
 409         $(use_enable unicode mbstring )
 410         $(use_with   unicode onig "${EPREFIX}"/usr)
 411         $(use_enable wddx wddx )
 412         $(use_enable xml dom )
 413         $(use_enable xml libxml )
 414         $(use_with   xml libxml-dir "${EPREFIX}"/usr)
 415         $(use_enable xml xml )
 416         $(use_enable xmlreader xmlreader )
 417         $(use_with   xmlrpc xmlrpc)
 418         $(use_enable xmlwriter xmlwriter )
 419         $(use_with   xslt xsl "${EPREFIX}"/usr)
 420         $(use_enable zip zip )
 421         $(use_with   zlib zlib "${EPREFIX}"/usr)"
 422
 423         # DBA support
 424         if use cdb || use berkdb || use flatfile || use gdbm || use inifile \
 425                 || use qdbm ; then
 426                 my_conf="${my_conf} --enable-dba${shared}"
 427         fi
 428
 429         # DBA drivers support
 430         my_conf+="
 431         $(use_with cdb cdb)
 432         $(use_with berkdb db4 ${EPREFIX}/usr)
 433         $(use_enable flatfile flatfile )
 434         $(use_with gdbm gdbm ${EPREFIX}/usr)
 435         $(use_enable inifile inifile )
 436         $(use_with qdbm qdbm ${EPREFIX}/usr)"
 437
 438         # Support for the GD graphics library
 439         my_conf+="
 440         $(use_with truetype freetype-dir ${EPREFIX}/usr)
 441         $(use_with truetype t1lib ${EPREFIX}/usr)
 442         $(use_enable cjk gd-jis-conv )
 443         $(use_with gd jpeg-dir ${EPREFIX}/usr)
 444         $(use_with gd png-dir ${EPREFIX}/usr)
 445         $(use_with xpm xpm-dir ${EPREFIX}/usr)
 446         $(use_with vpx vpx-dir ${EPREFIX}/usr)"
 447         # enable gd last, so configure can pick up the previous settings
 448         my_conf+="
 449         $(use_with gd gd)"
 450
 451         # IMAP SSL support
 452         if use imap ; then
 453                 my_conf+="$(use_with ssl imap-ssl ${EPREFIX}/usr)"
 454         fi
 455
 456         # MySQL support
 457         local mysqllib="mysqlnd"
 458         local mysqlilib="mysqlnd"
 459         use libmysqlclient && mysqllib="${EPREFIX}/usr"
 460         use libmysqlclient && mysqlilib="${EPREFIX}/usr/bin/mysql_config"
 461
 462         my_conf+=" $(use_with mysql mysql $mysqllib)"
 463         my_conf+=" $(use_with mysqli mysqli $mysqlilib)"
 464
 465         local mysqlsock=" $(use_with mysql mysql-sock ${EPREFIX}/var/run/mysqld/mysqld.sock)"
 466         if use mysql ; then
 467                 my_conf+="${mysqlsock}"
 468         elif use mysqli ; then
 469                 my_conf+="${mysqlsock}"
 470         fi
 471
 472         # MySQL PDO support
 473         my_conf+="$(use_with pdo-mysql pdo-mysql ${mysqllib})"
 474
 475         # Session support
 476         if use session ; then
 477                 my_conf+="
 478                 $(use_with sharedmem mm ${EPREFIX}/usr)"
 479         else
 480                 my_conf+="
 481                 $(use_enable session session )"
 482         fi
 483
 484         # Use pic for shared modules such as apache2's mod_php
 485         my_conf="${my_conf} --with-pic"
 486
 487         # we use the system copy of pcre
 488         # --with-pcre-regex affects ext/pcre
 489         # --with-pcre-dir affects ext/filter and ext/zip
 490         my_conf="${my_conf} --with-pcre-regex=${EPREFIX}/usr --with-pcre-dir=${EPREFIX}/usr"
 491
 492         # Catch CFLAGS problems
 493         # Fixes bug #14067.
 494         # Changed order to run it in reverse for bug #32022 and #12021.
 495         replace-cpu-flags "k6*" "i586"
 496
 497         # Support user-passed configuration parameters
 498         my_conf="${my_conf} ${EXTRA_ECONF:-}"
 499
 500         # Support the Apache2 extras, they must be set globally for all
 501         # SAPIs to work correctly, especially for external PHP extensions
 502
 503         mkdir -p "${WORKDIR}/sapis-build"
 504         for one_sapi in $SAPIS ; do
 505                 use "${one_sapi}" || continue
 506                 php_set_ini_dir "${one_sapi}"
 507
 508                 cp -r "${S}" "${WORKDIR}/sapis-build/${one_sapi}"
 509                 cd "${WORKDIR}/sapis-build/${one_sapi}"
 510
 511                 sapi_conf="${my_conf} --with-config-file-path=${PHP_INI_DIR}
 512                         --with-config-file-scan-dir=${PHP_EXT_INI_DIR_ACTIVE}"
 513
 514                 for sapi in $SAPIS ; do
 515                         case "$sapi" in
 516                                 cli|cgi|embed|fpm)
 517                                         if [[ "${one_sapi}" == "${sapi}" ]] ; then
 518                                                 sapi_conf="${sapi_conf} --enable-${sapi}"
 519                                         else
 520                                                 sapi_conf="${sapi_conf} --disable-${sapi}"
 521                                         fi
 522                                         ;;
 523
 524                                 apache2)
 525                                         if [[ "${one_sapi}" == "${sapi}" ]] ; then
 526                                                 sapi_conf="${sapi_conf} --with-apxs2=${EPREFIX}/usr/sbin/apxs"
 527                                         else
 528                                                 sapi_conf="${sapi_conf} --without-apxs2"
 529                                         fi
 530                                         ;;
 531                         esac
 532                 done
 533
 534                 econf ${sapi_conf}
 535         done
 536 }
 537
 538 src_compile() {
 539         # snmp seems to run during src_compile, too (bug #324739)
 540         addpredict /usr/share/snmp/mibs/.index
 541         addpredict /var/lib/net-snmp/mib_indexes
 542
 543         for sapi in ${SAPIS} ; do
 544                 if use "${sapi}"; then
 545                         cd "${WORKDIR}/sapis-build/$sapi" || "Failed to change dir to ${WORKDIR}/sapis-build/$1"
 546                         emake || die "emake failed"
 547                 fi
 548         done
 549 }
 550
 551 src_install() {
 552         # see bug #324739 for what happens when we don't have that
 553         addpredict /usr/share/snmp/mibs/.index
 554
 555         # grab the first SAPI that got built and install common files from there
 556         local first_sapi=""
 557         for sapi in $SAPIS ; do
 558                 if use $sapi ; then
 559                         first_sapi=$sapi
 560                         break
 561                 fi
 562         done
 563
 564         # Makefile forgets to create this before trying to write to it...
 565         dodir "${PHP_DESTDIR#${EPREFIX}}/bin"
 566
 567         # Install php environment (without any sapis)
 568         cd "${WORKDIR}/sapis-build/$first_sapi"
 569         emake INSTALL_ROOT="${D}" \
 570                 install-build install-headers install-programs \
 571                 || die "emake install failed"
 572
 573         local extension_dir="$("${ED}/${PHP_DESTDIR#${EPREFIX}}/bin/php-config" --extension-dir)"
 574
 575         # Create the directory where we'll put version-specific php scripts
 576         keepdir /usr/share/php${PHP_MV}
 577
 578         local sapi="", file=""
 579         local sapi_list=""
 580
 581         for sapi in ${SAPIS}; do
 582                 if use "${sapi}" ; then
 583                         einfo "Installing SAPI: ${sapi}"
 584                         cd "${WORKDIR}/sapis-build/${sapi}"
 585
 586                         if [[ "${sapi}" == "apache2" ]] ; then
 587                                 # We're specifically not using emake install-sapi as libtool
 588                                 # may cause unnecessary relink failures (see bug #351266)
 589                                 insinto "${PHP_DESTDIR#${EPREFIX}}/apache2/"
 590                                 newins ".libs/libphp5$(get_libname)" "libphp${PHP_MV}$(get_libname)"
 591                                 keepdir "/usr/$(get_libdir)/apache2/modules"
 592                         else
 593                                 # needed each time, php_install_ini would reset it
 594                                 local dest="${PHP_DESTDIR#${EPREFIX}}"
 595                                 into "${dest}"
 596                                 case "$sapi" in
 597                                         cli)
 598                                                 source="sapi/cli/php"
 599                                                 ;;
 600                                         cgi)
 601                                                 source="sapi/cgi/php-cgi"
 602                                                 ;;
 603                                         fpm)
 604                                                 source="sapi/fpm/php-fpm"
 605                                                 ;;
 606                                         embed)
 607                                                 source="libs/libphp${PHP_MV}$(get_libname)"
 608                                                 ;;
 609                                         *)
 610                                                 die "unhandled sapi in src_install"
 611                                                 ;;
 612                                 esac
 613
 614                                 if [[ "${source}" == *"$(get_libname)" ]]; then
 615                                         dolib.so "${source}" || die "Unable to install ${sapi} sapi"
 616                                 else
 617                                         dobin "${source}" || die "Unable to install ${sapi} sapi"
 618                                         local name="$(basename ${source})"
 619                                         dosym "${dest}/bin/${name}" "/usr/bin/${name}${SLOT}"
 620                                 fi
 621                         fi
 622
 623                         php_install_ini "${sapi}"
 624
 625                         # construct correct SAPI string for php-config
 626                         # thanks to ferringb for the bash voodoo
 627                         if [[ "${sapi}" == "apache2" ]]; then
 628                                 sapi_list="${sapi_list:+${sapi_list} }apache2handler"
 629                         else
 630                                 sapi_list="${sapi_list:+${sapi_list} }${sapi}"
 631                         fi
 632                 fi
 633         done
 634
 635         # Installing opcache module
 636         if use_if_iuse opcache ; then
 637                 dolib.so "modules/opcache$(get_libname)" || die "Unable to install opcache module"
 638         fi
 639
 640         # Install env.d files
 641         newenvd "${FILESDIR}/20php5-envd" \
 642                 "20php${SLOT}"
 643         sed -e "s|/lib/|/$(get_libdir)/|g" -i \
 644                 "${ED}/etc/env.d/20php${SLOT}"
 645         sed -e "s|php5|php${SLOT}|g" -i \
 646                 "${ED}/etc/env.d/20php${SLOT}"
 647
 648         # set php-config variable correctly (bug #278439)
 649         sed -e "s:^\(php_sapis=\)\".*\"$:\1\"${sapi_list}\":" -i \
 650                 "${ED}/usr/$(get_libdir)/php${SLOT}/bin/php-config"
 651
 652         if use fpm ; then
 653                 if use systemd; then
 654                         systemd_newunit "${FILESDIR}/php-fpm_at.service" "php-fpm@${SLOT}.service"
 655                 else
 656                         systemd_newunit "${FILESDIR}/php-fpm_at-simple.service" "php-fpm@${SLOT}.service"
 657                 fi
 658         fi
 659 }
 660
 661 src_test() {
 662         echo ">>> Test phase [test]: ${CATEGORY}/${PF}"
 663         PHP_BIN="${WORKDIR}/sapis-build/cli/sapi/cli/php"
 664         if [[ ! -x "${PHP_BIN}" ]] ; then
 665                 ewarn "Test phase requires USE=cli, skipping"
 666                 return
 667         else
 668                 export TEST_PHP_EXECUTABLE="${PHP_BIN}"
 669         fi
 670
 671         if [[ -x "${WORKDIR}/sapis/cgi/php-cgi" ]] ; then
 672                 export TEST_PHP_CGI_EXECUTABLE="${WORKDIR}/sapis/cgi/php-cgi"
 673         fi
 674
 675         REPORT_EXIT_STATUS=1 "${TEST_PHP_EXECUTABLE}" -n  -d "session.save_path=${T}" \
 676                 "${WORKDIR}/sapis-build/cli/run-tests.php" -n -q -d "session.save_path=${T}"
 677
 678         for name in ${EXPECTED_TEST_FAILURES}; do
 679                 mv "${name}.out" "${name}.out.orig" 2>/dev/null
 680         done
 681
 682         local failed="$(find -name '*.out')"
 683         if [[ ${failed} != "" ]] ; then
 684                 ewarn "The following test cases failed unexpectedly:"
 685                 for name in ${failed}; do
 686                         ewarn "  ${name/.out/}"
 687                 done
 688         else
 689                 einfo "No unexpected test failures, all fine"
 690         fi
 691
 692         if [[ ${PHP_SHOW_UNEXPECTED_TEST_PASS} == "1" ]] ; then
 693                 local passed=""
 694                 for name in ${EXPECTED_TEST_FAILURES}; do
 695                         [[ -f "${name}.diff" ]] && continue
 696                         passed="${passed} ${name}"
 697                 done
 698                 if [[ ${passed} != "" ]] ; then
 699                         einfo "The following test cases passed unexpectedly:"
 700                         for name in ${passed}; do
 701                                 ewarn "  ${passed}"
 702                         done
 703                 else
 704                         einfo "None of the known-to-fail tests passed, all fine"
 705                 fi
 706         fi
 707 }
 708
 709 pkg_postinst() {
 710         # Output some general info to the user
 711         if use apache2 ; then
 712                 APACHE2_MOD_DEFINE="PHP5"
 713                 APACHE2_MOD_CONF="70_mod_php5"
 714                 apache-module_pkg_postinst
 715         fi
 716
 717         # Create the symlinks for php
 718         for m in ${SAPIS}; do
 719                 [[ ${m} == 'embed' ]] && continue;
 720                 if use $m ; then
 721                         local ci=$(eselect php show $m)
 722                         if [[ -z $ci ]]; then
 723                                 eselect php set $m php${SLOT}
 724                                 einfo "Switched ${m} to use php:${SLOT}"
 725                                 einfo
 726                         elif [[ $ci != "php${SLOT}" ]] ; then
 727                                 elog "To switch $m to use php:${SLOT}, run"
 728                                 elog "    eselect php set $m php${SLOT}"
 729                                 elog
 730                         fi
 731                 fi
 732         done
 733
 734         elog "Make sure that PHP_TARGETS in ${EPREFIX}/etc/make.conf includes php${SLOT/./-} in order"
 735         elog "to compile extensions for the ${SLOT} ABI"
 736         elog
 737         if ! use readline && use cli ; then
 738                 ewarn "Note that in order to use php interactivly, you need to enable"
 739                 ewarn "the readline USE flag or php -a will hang"
 740         fi
 741         elog
 742         elog "This ebuild installed a version of php.ini based on php.ini-${PHP_INI_VERSION} version."
 743         elog "You can chose which version of php.ini to install by default by setting PHP_INI_VERSION to either"
 744         elog "'production' or 'development' in ${EPREFIX}/etc/make.conf"
 745         elog "Both versions of php.ini can be found in ${EPREFIX}/usr/share/doc/${PF}"
 746
 747         elog
 748         elog "For more details on how minor version slotting works (PHP_TARGETS) please read the upgrade guide:"
 749         elog "http://www.gentoo.org/proj/en/php/php-upgrading.xml"
 750         elog
 751 }
 752
 753 pkg_prerm() {
 754         eselect php cleanup
 755 }