dev-lang/php/php-5.6.4-r1.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI=5
   6
   7 inherit eutils autotools flag-o-matic versionator depend.apache apache-module db-use libtool systemd
   8
   9 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
  10
  11 function php_get_uri ()
  12 {
  13         case "${1}" in
  14                 "php-pre")
  15                         echo "http://downloads.php.net/dsp/${2}"
  16                 ;;
  17                 "php")
  18                         echo "http://www.php.net/distributions/${2}"
  19                 ;;
  20                 "olemarkus")
  21                         echo "http://dev.gentoo.org/~olemarkus/php/${2}"
  22                 ;;
  23                 "gentoo")
  24                         echo "mirror://gentoo/${2}"
  25                 ;;
  26                 *)
  27                         die "unhandled case in php_get_uri"
  28                 ;;
  29         esac
  30 }
  31
  32 PHP_MV="$(get_major_version)"
  33 SLOT="$(get_version_component_range 1-2)"
  34
  35 # alias, so we can handle different types of releases (finals, rcs, alphas,
  36 # betas, ...) w/o changing the whole ebuild
  37 PHP_PV="${PV/_rc/RC}"
  38 PHP_PV="${PHP_PV/_alpha/alpha}"
  39 PHP_PV="${PHP_PV/_beta/beta}"
  40 PHP_RELEASE="php"
  41 [[ ${PV} == ${PV/_alpha/} ]] || PHP_RELEASE="php-pre"
  42 [[ ${PV} == ${PV/_beta/} ]] || PHP_RELEASE="php-pre"
  43 [[ ${PV} == ${PV/_rc/} ]] || PHP_RELEASE="php-pre"
  44 PHP_P="${PN}-${PHP_PV}"
  45
  46 PHP_SRC_URI="$(php_get_uri "${PHP_RELEASE}" "${PHP_P}.tar.bz2")"
  47
  48 PHP_FPM_CONF_VER="1"
  49
  50 SRC_URI="${PHP_SRC_URI}"
  51
  52 DESCRIPTION="The PHP language runtime engine: CLI, CGI, FPM/FastCGI, Apache2 and embed SAPIs"
  53 HOMEPAGE="http://php.net/"
  54 LICENSE="PHP-3"
  55
  56 S="${WORKDIR}/${PHP_P}"
  57
  58 # We can build the following SAPIs in the given order
  59 SAPIS="embed cli cgi fpm apache2"
  60
  61 # SAPIs and SAPI-specific USE flags (cli SAPI is default on):
  62 IUSE="${IUSE}
  63         ${SAPIS/cli/+cli}
  64         threads"
  65
  66 IUSE="${IUSE} bcmath berkdb bzip2 calendar cdb cjk
  67         crypt +ctype curl debug
  68         enchant exif frontbase +fileinfo +filter firebird
  69         flatfile ftp gd gdbm gmp +hash +iconv imap inifile
  70         intl iodbc ipv6 +json kerberos ldap ldap-sasl libedit mhash
  71         mssql mysql libmysqlclient mysqli nls
  72         oci8-instant-client odbc +opcache pcntl pdo pdo-dblib pdo-odbc
  73         pdo-pgsql pdo-sqlite+phar +posix postgres qdbm readline recode selinux
  74         +session sharedmem +simplexml snmp soap sockets spell sqlite ssl
  75         sybase-ct sysvipc systemd tidy +tokenizer truetype unicode vpx wddx
  76         +xml xmlreader xmlwriter xmlrpc xpm xslt zip zlib"
  77
  78 DEPEND="
  79         >=app-admin/eselect-php-0.7.1-r3[apache2?,fpm?]
  80         >=dev-libs/libpcre-8.32[unicode]
  81         apache2? ( || ( >=www-servers/apache-2.4[apache2_modules_unixd,threads=]
  82                 <www-servers/apache-2.4[threads=] ) )
  83         berkdb? ( =sys-libs/db-4* )
  84         bzip2? ( app-arch/bzip2 )
  85         cdb? ( || ( dev-db/cdb dev-db/tinycdb ) )
  86         cjk? ( !gd? (
  87                 virtual/jpeg:0
  88                 media-libs/libpng:0=
  89                 sys-libs/zlib
  90         ) )
  91         crypt? ( >=dev-libs/libmcrypt-2.4 )
  92         curl? ( >=net-misc/curl-7.10.5 )
  93         enchant? ( app-text/enchant )
  94         exif? ( !gd? (
  95                 virtual/jpeg:0
  96                 media-libs/libpng:0=
  97                 sys-libs/zlib
  98         ) )
  99         firebird? ( dev-db/firebird )
 100         gd? ( virtual/jpeg:0 media-libs/libpng:0= sys-libs/zlib )
 101         gdbm? ( >=sys-libs/gdbm-1.8.0 )
 102         gmp? ( >=dev-libs/gmp-4.1.2 )
 103         iconv? ( virtual/libiconv )
 104         imap? ( virtual/imap-c-client[ssl=] )
 105         intl? ( dev-libs/icu:= )
 106         iodbc? ( dev-db/libiodbc )
 107         kerberos? ( virtual/krb5 )
 108         ldap? ( >=net-nds/openldap-1.2.11 )
 109         ldap-sasl? ( dev-libs/cyrus-sasl >=net-nds/openldap-1.2.11 )
 110         libedit? ( || ( sys-freebsd/freebsd-lib dev-libs/libedit ) )
 111         mssql? ( dev-db/freetds[mssql] )
 112         libmysqlclient? (
 113                 mysql? ( virtual/mysql )
 114                 mysqli? ( >=virtual/mysql-4.1 )
 115         )
 116         nls? ( sys-devel/gettext )
 117         oci8-instant-client? ( dev-db/oracle-instantclient-basic )
 118         odbc? ( >=dev-db/unixODBC-1.8.13 )
 119         postgres? ( dev-db/postgresql )
 120         qdbm? ( dev-db/qdbm )
 121         readline? ( sys-libs/readline )
 122         recode? ( app-text/recode )
 123         sharedmem? ( dev-libs/mm )
 124         simplexml? ( >=dev-libs/libxml2-2.6.8 )
 125         snmp? ( >=net-analyzer/net-snmp-5.2 )
 126         soap? ( >=dev-libs/libxml2-2.6.8 )
 127         spell? ( >=app-text/aspell-0.50 )
 128         sqlite? ( >=dev-db/sqlite-3.7.6.3 )
 129         ssl? ( >=dev-libs/openssl-0.9.7 )
 130         sybase-ct? ( dev-db/freetds )
 131         tidy? ( app-text/htmltidy )
 132         truetype? (
 133                 =media-libs/freetype-2*
 134                 >=media-libs/t1lib-5.0.0
 135                 !gd? (
 136                         virtual/jpeg:0 media-libs/libpng:0= sys-libs/zlib )
 137         )
 138         unicode? ( dev-libs/oniguruma )
 139         vpx? ( media-libs/libvpx )
 140         wddx? ( >=dev-libs/libxml2-2.6.8 )
 141         xml? ( >=dev-libs/libxml2-2.6.8 )
 142         xmlrpc? ( >=dev-libs/libxml2-2.6.8 virtual/libiconv )
 143         xmlreader? ( >=dev-libs/libxml2-2.6.8 )
 144         xmlwriter? ( >=dev-libs/libxml2-2.6.8 )
 145         xpm? (
 146                 x11-libs/libXpm
 147                 virtual/jpeg:0
 148                 media-libs/libpng:0= sys-libs/zlib
 149         )
 150         xslt? ( dev-libs/libxslt >=dev-libs/libxml2-2.6.8 )
 151         zip? ( sys-libs/zlib )
 152         zlib? ( sys-libs/zlib )
 153         virtual/mta
 154 "
 155
 156 php="=${CATEGORY}/${PF}"
 157
 158 REQUIRED_USE="
 159         truetype? ( gd )
 160         vpx? ( gd )
 161         cjk? ( gd )
 162         exif? ( gd )
 163
 164         xpm? ( gd )
 165         gd? ( zlib )
 166         simplexml? ( xml )
 167         soap? ( xml )
 168         wddx? ( xml )
 169         xmlrpc? ( || ( xml iconv ) )
 170         xmlreader? ( xml )
 171         xslt? ( xml )
 172         ldap-sasl? ( ldap )
 173         mhash? ( hash )
 174         phar? ( hash )
 175         libmysqlclient? ( || (
 176                 mysql
 177                 mysqli
 178                 pdo
 179         ) )
 180
 181         pdo-dblib? ( mssql )
 182         pdo-odbc? ( odbc )
 183         pdo-pgsql? ( postgres )
 184         pdo-sqlite? ( sqlite )
 185         qdbm? ( !gdbm )
 186         readline? ( !libedit )
 187         recode? ( !imap !mysql !mysqli )
 188         sharedmem? ( !threads )
 189
 190         !cli? ( !cgi? ( !fpm? ( !apache2? ( !embed? ( cli ) ) ) ) )"
 191
 192 RDEPEND="${DEPEND}"
 193
 194 RDEPEND="${RDEPEND}
 195         fpm? (
 196                 selinux? ( sec-policy/selinux-phpfpm )
 197                 systemd? ( sys-apps/systemd ) )"
 198
 199 DEPEND="${DEPEND}
 200         sys-devel/flex
 201         >=sys-devel/m4-1.4.3
 202         >=sys-devel/libtool-1.5.18"
 203
 204 # Allow users to install production version if they want to
 205
 206 case "${PHP_INI_VERSION}" in
 207         production|development)
 208                 ;;
 209         *)
 210                 PHP_INI_VERSION="development"
 211                 ;;
 212 esac
 213
 214 PHP_INI_UPSTREAM="php.ini-${PHP_INI_VERSION}"
 215 PHP_INI_FILE="php.ini"
 216
 217 want_apache
 218
 219 pkg_setup() {
 220         depend.apache_pkg_setup
 221 }
 222
 223 php_install_ini() {
 224         local phpsapi="${1}"
 225
 226         # work out where we are installing the ini file
 227         php_set_ini_dir "${phpsapi}"
 228
 229         local phpinisrc="${PHP_INI_UPSTREAM}-${phpsapi}"
 230         cp "${PHP_INI_UPSTREAM}" "${phpinisrc}"
 231
 232         # default to /tmp for save_path, bug #282768
 233         sed -e 's|^;session.save_path .*$|session.save_path = "'"${EPREFIX}"'/tmp"|g' -i "${phpinisrc}"
 234
 235         # Set the extension dir
 236         sed -e "s|^extension_dir .*$|extension_dir = ${extension_dir}|g" -i "${phpinisrc}"
 237
 238         # Set the include path to point to where we want to find PEAR packages
 239         sed -e 's|^;include_path = ".:/php/includes".*|include_path = ".:'"${EPREFIX}"'/usr/share/php'${PHP_MV}':'"${EPREFIX}"'/usr/share/php"|' -i "${phpinisrc}"
 240
 241         dodir "${PHP_INI_DIR#${EPREFIX}}"
 242         insinto "${PHP_INI_DIR#${EPREFIX}}"
 243         newins "${phpinisrc}" "${PHP_INI_FILE}"
 244
 245         elog "Installing php.ini for ${phpsapi} into ${PHP_INI_DIR#${EPREFIX}}"
 246         elog
 247
 248         dodir "${PHP_EXT_INI_DIR#${EPREFIX}}"
 249         dodir "${PHP_EXT_INI_DIR_ACTIVE#${EPREFIX}}"
 250
 251         if use_if_iuse opcache; then
 252                 elog "Adding opcache to $PHP_EXT_INI_DIR"
 253                 echo "zend_extension=${PHP_DESTDIR}/$(get_libdir)/opcache.so" >> "${D}/${PHP_EXT_INI_DIR}"/opcache.ini
 254                 dosym "${PHP_EXT_INI_DIR#${EPREFIX}}/opcache.ini" "${PHP_EXT_INI_DIR_ACTIVE#${EPREFIX}}/opcache.ini"
 255         fi
 256
 257         # SAPI-specific handling
 258
 259         if [[ "${sapi}" == "fpm" ]] ; then
 260                 [[ -z ${PHP_FPM_CONF_VER} ]] && PHP_FPM_CONF_VER=0
 261                 einfo "Installing FPM CGI config file php-fpm.conf"
 262                 insinto "${PHP_INI_DIR#${EPREFIX}}"
 263                 newins "${FILESDIR}/php-fpm-r${PHP_FPM_CONF_VER}.conf" php-fpm.conf
 264
 265                 # Remove bogus /etc/php-fpm.conf.default (bug 359906)
 266                 [[ -f "${ED}/etc/php-fpm.conf.default" ]] && rm "${ED}/etc/php-fpm.conf.default"
 267         fi
 268
 269         # Install PHP ini files into /usr/share/php
 270
 271         dodoc php.ini-development
 272         dodoc php.ini-production
 273
 274 }
 275
 276 php_set_ini_dir() {
 277         PHP_INI_DIR="${EPREFIX}/etc/php/${1}-php${SLOT}"
 278         PHP_EXT_INI_DIR="${PHP_INI_DIR}/ext"
 279         PHP_EXT_INI_DIR_ACTIVE="${PHP_INI_DIR}/ext-active"
 280 }
 281
 282 src_prepare() {
 283         # USE=sharedmem (session/mod_mm to be exact) tries to mmap() this path
 284         # ([empty session.save_path]/session_mm_[sapi][gid].sem)
 285         # there is no easy way to circumvent that, all php calls during
 286         # install use -n, so no php.ini file will be used.
 287         # As such, this is the easiest way to get around
 288         addpredict /session_mm_cli250.sem
 289         addpredict /session_mm_cli0.sem
 290
 291         # Change PHP branding
 292         # Get the alpha/beta/rc version
 293         sed -re "s|^(PHP_EXTRA_VERSION=\").*(\")|\1-pl${PR/r/}-gentoo\2|g" \
 294                 -i configure.in || die "Unable to change PHP branding"
 295
 296         # Patch PHP to show Gentoo as the server platform
 297         sed -e 's/PHP_UNAME=`uname -a | xargs`/PHP_UNAME=`uname -s -n -r -v | xargs`/g' \
 298                 -i configure.in || die "Failed to fix server platform name"
 299
 300         # Prevent PHP from activating the Apache config,
 301         # as we will do that ourselves
 302         sed -i \
 303                 -e "s,-i -a -n php${PHP_MV},-i -n php${PHP_MV},g" \
 304                 -e "s,-i -A -n php${PHP_MV},-i -n php${PHP_MV},g" \
 305                 configure sapi/apache2filter/config.m4 sapi/apache2handler/config.m4
 306
 307         # Patch PHP to support heimdal instead of mit-krb5
 308         if has_version "app-crypt/heimdal" ; then
 309                 sed -e 's|gssapi_krb5|gssapi|g' -i acinclude.m4 \
 310                         || die "Failed to fix heimdal libname"
 311                 sed -e 's|PHP_ADD_LIBRARY(k5crypto, 1, $1)||g' -i acinclude.m4 \
 312                         || die "Failed to fix heimdal crypt library reference"
 313         fi
 314
 315         #Add user patches #357637
 316         epatch_user
 317
 318         #force rebuilding aclocal.m4
 319         rm aclocal.m4
 320         eautoreconf
 321
 322         if [[ ${CHOST} == *-darwin* ]] ; then
 323                 # http://bugs.php.net/bug.php?id=48795, bug #343481
 324                 sed -i -e '/BUILD_CGI="\\$(CC)/s/CC/CXX/' configure || die
 325         fi
 326 }
 327
 328 src_configure() {
 329         addpredict /usr/share/snmp/mibs/.index
 330         addpredict /var/lib/net-snmp/mib_indexes
 331
 332         PHP_DESTDIR="${EPREFIX}/usr/$(get_libdir)/php${SLOT}"
 333
 334         # This is a global variable and should be in caps. It isn't because the
 335         # phpconfutils eclass relies on exactly this name...
 336         # for --with-libdir see bug #327025
 337         my_conf="
 338                 --prefix="${PHP_DESTDIR}"
 339                 --mandir="${PHP_DESTDIR}"/man
 340                 --infodir="${PHP_DESTDIR}"/info
 341                 --libdir="${PHP_DESTDIR}"/lib
 342                 --with-libdir=$(get_libdir)
 343                 --without-pear
 344                 $(use_enable threads maintainer-zts)"
 345
 346         #                             extension           USE flag        shared
 347         my_conf+="
 348         $(use_enable bcmath bcmath )
 349         $(use_with   bzip2 bz2 "${EPREFIX}"/usr)
 350         $(use_enable calendar calendar )
 351         $(use_with   crypt mcrypt "${EPREFIX}"/usr)
 352         $(use_enable ctype ctype )
 353         $(use_with   curl curl "${EPREFIX}"/usr)
 354         $(use_enable debug debug )
 355         $(use_with   enchant enchant "${EPREFIX}"/usr)
 356         $(use_enable exif exif )
 357         $(use_enable fileinfo fileinfo )
 358         $(use_enable filter filter )
 359         $(use_with   firebird interbase "${EPREFIX}"/usr)
 360         $(use_enable ftp ftp )
 361         $(use_with   gmp gmp "${EPREFIX}"/usr)
 362         $(use_enable hash hash )
 363         $(use_with   iconv iconv $(use elibc_glibc || echo "${EPREFIX}"/usr))
 364         $(use_with   imap imap "${EPREFIX}"/usr)
 365         $(use_enable intl intl )
 366         $(use_with   iodbc iodbc "${EPREFIX}"/usr)
 367         $(use_enable ipv6 ipv6 )
 368         $(use_enable json json )
 369         $(use_with   kerberos kerberos "${EPREFIX}"/usr)
 370         $(use_with   ldap ldap "${EPREFIX}"/usr)
 371         $(use_with   ldap-sasl ldap-sasl "${EPREFIX}"/usr)
 372         $(use_with   libedit libedit "${EPREFIX}"/usr)
 373         $(use_with   mhash mhash "${EPREFIX}"/usr)
 374         $(use_with   mssql mssql "${EPREFIX}"/usr)
 375         $(use_with   nls gettext "${EPREFIX}"/usr)
 376         $(use_with   oci8-instant-client oci8)
 377         $(use_with   odbc unixODBC "${EPREFIX}"/usr)
 378         $(use_enable opcache opcache )
 379         $(use_enable pcntl pcntl )
 380         $(use_enable pdo pdo )
 381         $(use_with   pdo-dblib pdo-dblib )
 382         $(use_with   pdo-odbc pdo-odbc unixODBC,"${EPREFIX}"/usr)
 383         $(use_with   pdo-pgsql pdo-pgsql )
 384         $(use_with   pdo-sqlite pdo-sqlite "${EPREFIX}"/usr)
 385         $(use_enable phar phar )
 386         $(use_enable posix posix )
 387         $(use_with   postgres pgsql "${EPREFIX}"/usr)
 388         $(use_with   spell pspell "${EPREFIX}"/usr)
 389         $(use_with   readline readline "${EPREFIX}"/usr)
 390         $(use_with   recode recode "${EPREFIX}"/usr)
 391         $(use_enable sharedmem shmop )
 392         $(use_enable simplexml simplexml )
 393         $(use_with   snmp snmp "${EPREFIX}"/usr)
 394         $(use_enable soap soap )
 395         $(use_enable sockets sockets )
 396         $(use_with   sqlite sqlite3 "${EPREFIX}"/usr)
 397         $(use_with   ssl openssl "${EPREFIX}"/usr)
 398         $(use_with   ssl openssl-dir "${EPREFIX}"/usr)
 399         $(use_with   sybase-ct sybase-ct "${EPREFIX}"/usr)
 400         $(use_with   systemd fpm-systemd)
 401         $(use_enable sysvipc sysvmsg )
 402         $(use_enable sysvipc sysvsem )
 403         $(use_enable sysvipc sysvshm )
 404         $(use_with   tidy tidy "${EPREFIX}"/usr)
 405         $(use_enable tokenizer tokenizer )
 406         $(use_enable unicode mbstring )
 407         $(use_with   unicode onig "${EPREFIX}"/usr)
 408         $(use_enable wddx wddx )
 409         $(use_enable xml dom )
 410         $(use_enable xml libxml )
 411         $(use_with   xml libxml-dir "${EPREFIX}"/usr)
 412         $(use_enable xml xml )
 413         $(use_enable xmlreader xmlreader )
 414         $(use_with   xmlrpc xmlrpc)
 415         $(use_enable xmlwriter xmlwriter )
 416         $(use_with   xslt xsl "${EPREFIX}"/usr)
 417         $(use_enable zip zip )
 418         $(use_with   zlib zlib "${EPREFIX}"/usr)"
 419
 420         # DBA support
 421         if use cdb || use berkdb || use flatfile || use gdbm || use inifile \
 422                 || use qdbm ; then
 423                 my_conf="${my_conf} --enable-dba${shared}"
 424         fi
 425
 426         # DBA drivers support
 427         my_conf+="
 428         $(use_with cdb cdb)
 429         $(use_with berkdb db4 ${EPREFIX}/usr)
 430         $(use_enable flatfile flatfile )
 431         $(use_with gdbm gdbm ${EPREFIX}/usr)
 432         $(use_enable inifile inifile )
 433         $(use_with qdbm qdbm ${EPREFIX}/usr)"
 434
 435         # Support for the GD graphics library
 436         my_conf+="
 437         $(use_with truetype freetype-dir ${EPREFIX}/usr)
 438         $(use_with truetype t1lib ${EPREFIX}/usr)
 439         $(use_enable cjk gd-jis-conv )
 440         $(use_with gd jpeg-dir ${EPREFIX}/usr)
 441         $(use_with gd png-dir ${EPREFIX}/usr)
 442         $(use_with xpm xpm-dir ${EPREFIX}/usr)
 443         $(use_with vpx vpx-dir ${EPREFIX}/usr)"
 444         # enable gd last, so configure can pick up the previous settings
 445         my_conf+="
 446         $(use_with gd gd)"
 447
 448         # IMAP SSL support
 449         if use imap ; then
 450                 my_conf+="$(use_with ssl imap-ssl ${EPREFIX}/usr)"
 451         fi
 452
 453         # MySQL support
 454         local mysqllib="mysqlnd"
 455         local mysqlilib="mysqlnd"
 456         use libmysqlclient && mysqllib="${EPREFIX}/usr"
 457         use libmysqlclient && mysqlilib="${EPREFIX}/usr/bin/mysql_config"
 458
 459         my_conf+=" $(use_with mysql mysql $mysqllib)"
 460         my_conf+=" $(use_with mysqli mysqli $mysqlilib)"
 461
 462         local mysqlsock=" $(use_with mysql mysql-sock ${EPREFIX}/var/run/mysqld/mysqld.sock)"
 463         if use mysql ; then
 464                 my_conf+="${mysqlsock}"
 465         elif use mysqli ; then
 466                 my_conf+="${mysqlsock}"
 467         fi
 468
 469         # PDO support
 470         if use pdo ; then
 471                 my_conf+="$(use_with mysql pdo-mysql ${mysqllib})"
 472                 if use oci8-instant-client ; then
 473                         my_conf+="
 474                         $(use_with oci8-instant-client pdo-oci)"
 475                 fi
 476         fi
 477
 478         # Session support
 479         if use session ; then
 480                 my_conf+="
 481                 $(use_with sharedmem mm ${EPREFIX}/usr)"
 482         else
 483                 my_conf+="
 484                 $(use_enable session session )"
 485         fi
 486
 487         # Use pic for shared modules such as apache2's mod_php
 488         my_conf="${my_conf} --with-pic"
 489
 490         # we use the system copy of pcre
 491         # --with-pcre-regex affects ext/pcre
 492         # --with-pcre-dir affects ext/filter and ext/zip
 493         my_conf="${my_conf} --with-pcre-regex=${EPREFIX}/usr --with-pcre-dir=${EPREFIX}/usr"
 494
 495         # Catch CFLAGS problems
 496         # Fixes bug #14067.
 497         # Changed order to run it in reverse for bug #32022 and #12021.
 498         replace-cpu-flags "k6*" "i586"
 499
 500         # Support user-passed configuration parameters
 501         my_conf="${my_conf} ${EXTRA_ECONF:-}"
 502
 503         # Support the Apache2 extras, they must be set globally for all
 504         # SAPIs to work correctly, especially for external PHP extensions
 505
 506         mkdir -p "${WORKDIR}/sapis-build"
 507         for one_sapi in $SAPIS ; do
 508                 use "${one_sapi}" || continue
 509                 php_set_ini_dir "${one_sapi}"
 510
 511                 cp -r "${S}" "${WORKDIR}/sapis-build/${one_sapi}"
 512                 cd "${WORKDIR}/sapis-build/${one_sapi}"
 513
 514                 sapi_conf="${my_conf} --with-config-file-path=${PHP_INI_DIR}
 515                         --with-config-file-scan-dir=${PHP_EXT_INI_DIR_ACTIVE}"
 516
 517                 for sapi in $SAPIS ; do
 518                         case "$sapi" in
 519                                 cli|cgi|embed|fpm)
 520                                         if [[ "${one_sapi}" == "${sapi}" ]] ; then
 521                                                 sapi_conf="${sapi_conf} --enable-${sapi}"
 522                                         else
 523                                                 sapi_conf="${sapi_conf} --disable-${sapi}"
 524                                         fi
 525                                         ;;
 526
 527                                 apache2)
 528                                         if [[ "${one_sapi}" == "${sapi}" ]] ; then
 529                                                 sapi_conf="${sapi_conf} --with-apxs2=${EPREFIX}/usr/sbin/apxs"
 530                                         else
 531                                                 sapi_conf="${sapi_conf} --without-apxs2"
 532                                         fi
 533                                         ;;
 534                         esac
 535                 done
 536
 537                 econf ${sapi_conf}
 538         done
 539 }
 540
 541 src_compile() {
 542         # snmp seems to run during src_compile, too (bug #324739)
 543         addpredict /usr/share/snmp/mibs/.index
 544         addpredict /var/lib/net-snmp/mib_indexes
 545
 546         for sapi in ${SAPIS} ; do
 547                 if use "${sapi}"; then
 548                         cd "${WORKDIR}/sapis-build/$sapi" || "Failed to change dir to ${WORKDIR}/sapis-build/$1"
 549                         emake || die "emake failed"
 550                 fi
 551         done
 552 }
 553
 554 src_install() {
 555         # see bug #324739 for what happens when we don't have that
 556         addpredict /usr/share/snmp/mibs/.index
 557
 558         # grab the first SAPI that got built and install common files from there
 559         local first_sapi=""
 560         for sapi in $SAPIS ; do
 561                 if use $sapi ; then
 562                         first_sapi=$sapi
 563                         break
 564                 fi
 565         done
 566
 567         # Makefile forgets to create this before trying to write to it...
 568         dodir "${PHP_DESTDIR#${EPREFIX}}/bin"
 569
 570         # Install php environment (without any sapis)
 571         cd "${WORKDIR}/sapis-build/$first_sapi"
 572         emake INSTALL_ROOT="${D}" \
 573                 install-build install-headers install-programs \
 574                 || die "emake install failed"
 575
 576         local extension_dir="$("${ED}/${PHP_DESTDIR#${EPREFIX}}/bin/php-config" --extension-dir)"
 577
 578         # Create the directory where we'll put version-specific php scripts
 579         keepdir /usr/share/php${PHP_MV}
 580
 581         local sapi="", file=""
 582         local sapi_list=""
 583
 584         for sapi in ${SAPIS}; do
 585                 if use "${sapi}" ; then
 586                         einfo "Installing SAPI: ${sapi}"
 587                         cd "${WORKDIR}/sapis-build/${sapi}"
 588
 589                         if [[ "${sapi}" == "apache2" ]] ; then
 590                                 # We're specifically not using emake install-sapi as libtool
 591                                 # may cause unnecessary relink failures (see bug #351266)
 592                                 insinto "${PHP_DESTDIR#${EPREFIX}}/apache2/"
 593                                 newins ".libs/libphp5$(get_libname)" "libphp${PHP_MV}$(get_libname)"
 594                                 keepdir "/usr/$(get_libdir)/apache2/modules"
 595                         else
 596                                 # needed each time, php_install_ini would reset it
 597                                 local dest="${PHP_DESTDIR#${EPREFIX}}"
 598                                 into "${dest}"
 599                                 case "$sapi" in
 600                                         cli)
 601                                                 source="sapi/cli/php"
 602                                                 ;;
 603                                         cgi)
 604                                                 source="sapi/cgi/php-cgi"
 605                                                 ;;
 606                                         fpm)
 607                                                 source="sapi/fpm/php-fpm"
 608                                                 ;;
 609                                         embed)
 610                                                 source="libs/libphp${PHP_MV}$(get_libname)"
 611                                                 ;;
 612                                         *)
 613                                                 die "unhandled sapi in src_install"
 614                                                 ;;
 615                                 esac
 616
 617                                 if [[ "${source}" == *"$(get_libname)" ]]; then
 618                                         dolib.so "${source}" || die "Unable to install ${sapi} sapi"
 619                                 else
 620                                         dobin "${source}" || die "Unable to install ${sapi} sapi"
 621                                         local name="$(basename ${source})"
 622                                         dosym "${dest}/bin/${name}" "/usr/bin/${name}${SLOT}"
 623                                 fi
 624                         fi
 625
 626                         php_install_ini "${sapi}"
 627
 628                         # construct correct SAPI string for php-config
 629                         # thanks to ferringb for the bash voodoo
 630                         if [[ "${sapi}" == "apache2" ]]; then
 631                                 sapi_list="${sapi_list:+${sapi_list} }apache2handler"
 632                         else
 633                                 sapi_list="${sapi_list:+${sapi_list} }${sapi}"
 634                         fi
 635                 fi
 636         done
 637
 638         # Installing opcache module
 639         if use_if_iuse opcache ; then
 640                 dolib.so "modules/opcache$(get_libname)" || die "Unable to install opcache module"
 641         fi
 642
 643         # Install env.d files
 644         newenvd "${FILESDIR}/20php5-envd" \
 645                 "20php${SLOT}"
 646         sed -e "s|/lib/|/$(get_libdir)/|g" -i \
 647                 "${ED}/etc/env.d/20php${SLOT}"
 648         sed -e "s|php5|php${SLOT}|g" -i \
 649                 "${ED}/etc/env.d/20php${SLOT}"
 650
 651         # set php-config variable correctly (bug #278439)
 652         sed -e "s:^\(php_sapis=\)\".*\"$:\1\"${sapi_list}\":" -i \
 653                 "${ED}/usr/$(get_libdir)/php${SLOT}/bin/php-config"
 654
 655         if use fpm ; then
 656                 if use systemd; then
 657                         systemd_newunit "${FILESDIR}/php-fpm_at.service" "php-fpm@${SLOT}.service"
 658                 else
 659                         systemd_newunit "${FILESDIR}/php-fpm_at-simple.service" "php-fpm@${SLOT}.service"
 660                 fi
 661         fi
 662 }
 663
 664 src_test() {
 665         echo ">>> Test phase [test]: ${CATEGORY}/${PF}"
 666         PHP_BIN="${WORKDIR}/sapis-build/cli/sapi/cli/php"
 667         if [[ ! -x "${PHP_BIN}" ]] ; then
 668                 ewarn "Test phase requires USE=cli, skipping"
 669                 return
 670         else
 671                 export TEST_PHP_EXECUTABLE="${PHP_BIN}"
 672         fi
 673
 674         if [[ -x "${WORKDIR}/sapis/cgi/php-cgi" ]] ; then
 675                 export TEST_PHP_CGI_EXECUTABLE="${WORKDIR}/sapis/cgi/php-cgi"
 676         fi
 677
 678         REPORT_EXIT_STATUS=1 "${TEST_PHP_EXECUTABLE}" -n  -d "session.save_path=${T}" \
 679                 "${WORKDIR}/sapis-build/cli/run-tests.php" -n -q -d "session.save_path=${T}"
 680
 681         for name in ${EXPECTED_TEST_FAILURES}; do
 682                 mv "${name}.out" "${name}.out.orig" 2>/dev/null
 683         done
 684
 685         local failed="$(find -name '*.out')"
 686         if [[ ${failed} != "" ]] ; then
 687                 ewarn "The following test cases failed unexpectedly:"
 688                 for name in ${failed}; do
 689                         ewarn "  ${name/.out/}"
 690                 done
 691         else
 692                 einfo "No unexpected test failures, all fine"
 693         fi
 694
 695         if [[ ${PHP_SHOW_UNEXPECTED_TEST_PASS} == "1" ]] ; then
 696                 local passed=""
 697                 for name in ${EXPECTED_TEST_FAILURES}; do
 698                         [[ -f "${name}.diff" ]] && continue
 699                         passed="${passed} ${name}"
 700                 done
 701                 if [[ ${passed} != "" ]] ; then
 702                         einfo "The following test cases passed unexpectedly:"
 703                         for name in ${passed}; do
 704                                 ewarn "  ${passed}"
 705                         done
 706                 else
 707                         einfo "None of the known-to-fail tests passed, all fine"
 708                 fi
 709         fi
 710 }
 711
 712 pkg_postinst() {
 713         # Output some general info to the user
 714         if use apache2 ; then
 715                 APACHE2_MOD_DEFINE="PHP5"
 716                 APACHE2_MOD_CONF="70_mod_php5"
 717                 apache-module_pkg_postinst
 718         fi
 719
 720         # Create the symlinks for php
 721         for m in ${SAPIS}; do
 722                 [[ ${m} == 'embed' ]] && continue;
 723                 if use $m ; then
 724                         local ci=$(eselect php show $m)
 725                         if [[ -z $ci ]]; then
 726                                 eselect php set $m php${SLOT}
 727                                 einfo "Switched ${m} to use php:${SLOT}"
 728                                 einfo
 729                         elif [[ $ci != "php${SLOT}" ]] ; then
 730                                 elog "To switch $m to use php:${SLOT}, run"
 731                                 elog "    eselect php set $m php${SLOT}"
 732                                 elog
 733                         fi
 734                 fi
 735         done
 736
 737         elog "Make sure that PHP_TARGETS in ${EPREFIX}/etc/make.conf includes php${SLOT/./-} in order"
 738         elog "to compile extensions for the ${SLOT} ABI"
 739         elog
 740         if ! use readline && use cli ; then
 741                 ewarn "Note that in order to use php interactivly, you need to enable"
 742                 ewarn "the readline USE flag or php -a will hang"
 743         fi
 744         elog
 745         elog "This ebuild installed a version of php.ini based on php.ini-${PHP_INI_VERSION} version."
 746         elog "You can chose which version of php.ini to install by default by setting PHP_INI_VERSION to either"
 747         elog "'production' or 'development' in ${EPREFIX}/etc/make.conf"
 748         elog "Both versions of php.ini can be found in ${EPREFIX}/usr/share/doc/${PF}"
 749
 750         elog
 751         elog "For more details on how minor version slotting works (PHP_TARGETS) please read the upgrade guide:"
 752         elog "http://www.gentoo.org/proj/en/php/php-upgrading.xml"
 753         elog
 754 }
 755
 756 pkg_prerm() {
 757         eselect php cleanup
 758 }