[list-remote-forwards.git] / src / Report.hs

module Report (
  report,
  report_tests )
where

import Data.Map ( mapKeys )
import qualified Data.Map as Map ( lookup )
import Data.Maybe ( catMaybes, listToMaybe )
import Data.Set ( fromList, isSubsetOf )
import qualified Data.Set as Set ( map )
import Data.String.Utils ( join )
import Database.HDBC (
  IConnection,
  Statement,
  execute,
  prepare,
  sFetchAllRows')
import Database.HDBC.Sqlite3 ( connectSqlite3 )
import System.Console.CmdArgs.Default ( Default(..) )
import Test.Tasty ( TestTree, testGroup )
import Test.Tasty.HUnit ( (@?=), testCase )

import Configuration ( Configuration(..) )
import DNS ( MxSetMap, mx_set_map, normalize_string_domain )
import Forward (
  Forward(..),
  address_domain,
  dropby_goto_domains,
  pretty_print,
  strings_to_forwards )
import MxList ( MxList(..) )

-- | Type synonym to make the signatures below a little more clear.
--   WARNING: Also defined in the "Forward" module.
type Domain = String


-- | We really want executeRaw here, but there's a bug: it will tell
--   us we can't fetch rows from the statement since it hasn't been
--   executed yet!
--
my_executeRaw :: Statement -> IO [[Maybe String]]
my_executeRaw stmt = do
  _ <- execute stmt []
  sFetchAllRows' stmt


-- | Given a connection @conn@ and a @query@, return a list of domains
--   found by executing @query@ on @conn. The @query@ is assumed to
--   return only one column, containing domains.
--
get_domain_list :: IConnection a
                => a -- ^ A database connection
                -> String -- ^ The @query@ to execute
                -> IO [Domain] -- ^ The list of domains returned from @query@
get_domain_list conn query = do
  stmt <- prepare conn query
  rows <- my_executeRaw stmt

  -- rows' :: [Maybe String]
  let rows' = map (listToMaybe . catMaybes) rows

  -- domains :: [String]
  let domains = catMaybes rows'

  return domains




-- | Given a connection @conn@ and a @query@, return a list of
--   forwards found by executing @query@ on @conn. The @query@ is
--   assumed to return two columns, the first containing addresses and
--   the second containing a comma-separated list of gotos (as a
--   string).
--
get_forward_list :: IConnection a
                 => a  -- ^ A database connection
                 -> String -- ^ The @query@ to execute
                 -> IO [Forward]  -- ^ A list of forwards returned from @query@
get_forward_list conn query = do
  stmt <- prepare conn query
  rows <- my_executeRaw stmt

  -- forwards :: [Forward]
  let forwards = concatMap (strings_to_forwards . catMaybes) rows

  return forwards



-- | A filter function to remove specific 'Forward's from a list (of
--   forwards).  Its intended usage is to ignore a 'Forward' if its
--   'Address' has MX records that are all contained in the given
--   list. This could be useful if, for example, one MX has strict
--   spam filtering and remote forwards are not a problem for domains
--   with that MX.
--
--   If the MX records for a domain are contained in the 'MxList',
--   then we exclude that domain from the report.
--
--   For performance reasons, we want to have precomputed the MX
--   records for all of the address domains in our list of
--   forwards. We do this so we don't look up the MX records twice for
--   two addresses within the same domain. We could just as well do
--   this within this function, but by taking the @domain_mxs@ as a
--   parameter, we allow ourselves to be a pure function.
--
--   If the domain of a forward address can't be determined, it won't
--   be dropped! This is intentional: the existence of a forward
--   address without a domain part probably indicates a configuration
--   error somewhere, and we should report it.
--
--   The empty @MxList []@ special case is necessary! Otherwise if we
--   have an empty exclude list and a domain that has no MX record, it
--   will be excluded.
--
--   ==== __Examples__
--
--   Our single forward should be dropped from the list, because its
--   MX record list, ["mx.example.com"], is contained in the list of
--   excluded MXs:
--
--   >>> import qualified Data.Map as Map ( fromList )
--   >>> import qualified Data.Set as Set ( fromList )
--   >>> import Forward ( fwd )
--   >>> let fwds = [fwd "user1@example.com" "user2@example.net"]
--   >>> let mx_set = Set.fromList ["mx.example.com"]
--   >>> let example_mx_pairs = [("example.com.", mx_set)]
--   >>> let mx_map = Map.fromList example_mx_pairs
--   >>> let droplist = MxList ["mx.example.com", "mx2.example.com"]
--   >>> map pretty_print (dropby_mxlist droplist mx_map fwds)
--   []
--
--   Repeat the previous test with the goto domain, to make sure we're
--   dropping based on the address and not the goto:
--
--   >>> import qualified Data.Map as Map ( fromList )
--   >>> import qualified Data.Set as Set ( fromList )
--   >>> let fwds = [fwd "user1@example.com" "user2@example.net"]
--   >>> let mx_set = Set.fromList ["mx.example.net"]
--   >>> let example_mx_pairs = [("example.net.", mx_set)]
--   >>> let mx_map = Map.fromList example_mx_pairs
--   >>> let droplist = MxList ["mx.example.net", "mx2.example.net"]
--   >>> map pretty_print (dropby_mxlist droplist mx_map fwds)
--   ["user1@example.com -> user2@example.net"]
--
--   Use weird caps, and optional trailing dot all over the place to
--   make sure everything is handled normalized:
--
--   >>> import qualified Data.Set as Set ( fromList )
--   >>> import Forward ( fwd )
--   >>> let fwds = [fwd "user1@exAmPle.com." "user2@examPle.net"]
--   >>> let mx_set = Set.fromList ["mx.EXAMPLE.com"]
--   >>> let example_mx_pairs = [("Example.com", mx_set)]
--   >>> let mx_map = Map.fromList example_mx_pairs
--   >>> let droplist = MxList ["mx.EXAMple.com", "mx2.example.COM"]
--   >>> map pretty_print (dropby_mxlist droplist mx_map fwds)
--   []
--
--   This time it shouldn't be dropped, because ["mx.example.com"] is
--   not contained in ["nope.example.com"]:
--
--   >>> import qualified Data.Map as Map ( fromList )
--   >>> import qualified Data.Set as Set ( fromList )
--   >>> let fwds = [fwd "user1@example.com" "user2@example.net"]
--   >>> let mx_set = Set.fromList ["mx.example.com"]
--   >>> let example_mx_pairs = [("example.com.", mx_set)]
--   >>> let mx_map = Map.fromList example_mx_pairs
--   >>> let droplist = MxList ["nope.example.com"]
--   >>> map pretty_print (dropby_mxlist droplist mx_map fwds)
--   ["user1@example.com -> user2@example.net"]
--
--   Now we check that if a forward has two MXes, one of which appears
--   in the list of excluded MXes, it doesn't get dropped:
--
--   >>> import qualified Data.Map as Map ( fromList )
--   >>> import qualified Data.Set as Set ( fromList )
--   >>> let fwds = [fwd "user1@example.com" "user2@example.net"]
--   >>> let mx_set = Set.fromList ["mx1.example.com", "mx2.example.com"]
--   >>> let example_mx_pairs = [("example.com.", mx_set)]
--   >>> let mx_map = Map.fromList example_mx_pairs
--   >>> let droplist = MxList ["mx1.example.com"]
--   >>> map pretty_print (dropby_mxlist droplist mx_map fwds)
--   ["user1@example.com -> user2@example.net"]
--
dropby_mxlist :: MxList -> MxSetMap -> [Forward] -> [Forward]
dropby_mxlist (MxList []) _ = id
dropby_mxlist (MxList mxs) domain_mx_map =
  filter (not . is_bad)
  where
    -- If we don't normalize these first, comparison (isSubsetOf)
    -- doesn't work so great.
    mx_set = fromList (map normalize_string_domain mxs)

    -- We perform a lookup using a normalized key, so we'd better
    -- normalize the keys in the map first!
    normal_mxmap = mapKeys normalize_string_domain domain_mx_map

    is_bad :: Forward -> Bool
    is_bad f =
      case (address_domain f) of
        Nothing -> False -- Do **NOT** drop these.
        Just d  -> case (Map.lookup (normalize_string_domain d) normal_mxmap) of
                     Nothing -> False -- No domain MX? Don't drop.

                     -- We need to normalize the set of MXes for the
                     -- domain, too.
                     Just dmxs ->
                       let ndmxs = (Set.map normalize_string_domain dmxs)
                       in
                         ndmxs `isSubsetOf` mx_set


-- | Given a connection and a 'Configuration', produces the report as
--   a 'String'.
--
report :: IConnection a => Configuration -> a -> IO String
report cfg conn = do
  domains <- get_domain_list conn (domain_query cfg)
  forwards <- get_forward_list conn (forward_query cfg)

  -- valid_forwards are those not excluded based on their address's MXes.
  --
  -- WARNING: Don't do MX lookups if the exclude list is empty! It
  -- wastes a ton of time!
  --
  -- Don't ask why, but this doesn't work if you factor out the
  -- "return" below.
  --
  let exclude_mx_list = exclude_mx cfg
  valid_forwards <- if null (get_mxs exclude_mx_list)
                    then return forwards
                    else do
                      domain_mxs <- mx_set_map domains
                      return $ dropby_mxlist exclude_mx_list domain_mxs forwards

  let remote_forwards = dropby_goto_domains domains valid_forwards
  let forward_strings = map pretty_print remote_forwards

  -- Don't append the final newline if there's nothing to report.
  return $ if (null forward_strings)
           then ""
           else (join "\n" forward_strings) ++ "\n"



-- * Tests

report_tests :: TestTree
report_tests =
  testGroup "Report Tests" [ test_example1 ]


test_example1 :: TestTree
test_example1 =
  testCase desc $ do
    conn <- connectSqlite3 "test/fixtures/postfixadmin.sqlite3"
    let cfg = def :: Configuration
    actual <- report cfg conn
    actual @?= expected
  where
    desc = "all remote forwards are found"
    expected = "user1@example.com -> user1@example.net\n" ++
               "user2@example.com -> user1@example.org\n" ++
               "user2@example.com -> user2@example.org\n" ++
               "user2@example.com -> user3@example.org\n" ++
               "user7@example.com -> user8@example.net\n"