src/Main.hs

   1 module Main
   2 where
   3
   4 import Control.Concurrent.ParallelIO.Global (
   5   parallelInterleaved,
   6   stopGlobalPool )
   7 import Control.Monad (unless)
   8 import qualified Data.ByteString.Char8 as BS (
   9   getContents,
  10   pack,
  11   words )
  12 import Data.List ( (\\) )
  13 import Data.String.Utils (join)
  14 import Network.DNS (
  15   Domain,
  16   FileOrNumericHost(RCHostName),
  17   ResolvConf(resolvInfo, resolvTimeout),
  18   defaultResolvConf,
  19   makeResolvSeed,
  20   normalize,
  21   normalizeCase,
  22   withResolver )
  23 import System.Exit (ExitCode(ExitFailure), exitWith)
  24 import System.IO (hPutStrLn, stderr)
  25
  26 import CommandLine (
  27    Args(NS,MX,delegates,no_append_root,server,timeout),
  28    get_args)
  29 import DNS (
  30   LookupResult,
  31   lookupMX',
  32   lookupNS',
  33   resolve_address )
  34 import ExitCodes (exit_bad_server)
  35 import Timeout (Timeout(seconds))
  36
  37
  38 -- | Given a list of delegates, report results for this
  39 --   'LookupResult'.
  40 --
  41 --   If there's an empty list in the second component, there were no
  42 --   query results, so we report that the domain was not delegated. If
  43 --   there were some results and there are leftovers (after removing
  44 --   the delegates), we report those as well.
  45 --
  46 --   Before processing, all names are normalized using the supplied
  47 --   function @normalize_function@. Ideally this should be the same
  48 --   function applied to the user-input names.
  49 --
  50 report :: [Domain] -- ^ The list of @delgts@
  51        -> (Domain -> Domain) -- ^ Domain name normalization function,
  52                              --   @normalize_function@.
  53        -> LookupResult
  54        -> IO ()
  55
  56 -- If the lookup resulted in a DNS error, we just ignore the whole
  57 -- thing.
  58 report _ _ (_, Left _) = return ()
  59
  60 -- If the lookup succeeded but there were no results, report that the
  61 -- domain is not delegated.
  62 report _ _ (d, Right []) =
  63   putStrLn $ "Domain " ++ (show d) ++ " not delegated."
  64
  65 -- Otherwise, subtract our delegates from the list of results and
  66 -- report the leftovers.
  67 report delgts normalize_function (d, Right raw_hosts) = do
  68   let nrml_hosts = map normalize_function raw_hosts
  69   let leftovers = nrml_hosts \\ delgts
  70   unless (null leftovers) $
  71     putStrLn $ "Domain " ++
  72                (show d) ++
  73                " delegates somewhere else: " ++
  74                (join " " (map show leftovers))
  75
  76
  77 main :: IO ()
  78 main = do
  79   cfg <- get_args
  80
  81   -- This reads stdin.
  82   input <- BS.getContents
  83
  84   -- Split the input on any whitespace characters.
  85   let raw_domains = BS.words input
  86
  87   -- Convert these to ByteStrings.
  88   let raw_delegates = map BS.pack (delegates cfg)
  89
  90   let normalize_function =
  91         if (no_append_root cfg)
  92         then normalizeCase
  93         else normalize
  94
  95   -- Normalize the given names and delegates
  96   let nrml_domains   = map normalize_function raw_domains
  97   let nrml_delegates = map normalize_function raw_delegates
  98
  99   rc' <- case (server cfg) of
 100            Nothing -> return defaultResolvConf
 101            Just s -> do
 102              s' <- resolve_address s
 103              case s' of
 104                Left err -> do
 105                  let errmsg = show err
 106                  hPutStrLn stderr ("Bad DNS server or lookup error: " ++ errmsg)
 107                  exitWith (ExitFailure exit_bad_server)
 108                Right []  -> do
 109                  hPutStrLn stderr ("Hostname " ++ s ++ " has no 'A' records.")
 110                  exitWith (ExitFailure exit_bad_server)
 111                Right (srv:_) ->
 112                  return $ defaultResolvConf { resolvInfo =
 113                                                 RCHostName (show srv) }
 114
 115   -- Set the timeout from the command line. The resolvTimeout field is
 116   -- in microseconds, so we multiply by one million.
 117   let a_million = 1000 * 1000 :: Int
 118   let rc = rc' { resolvTimeout = a_million * seconds (timeout cfg) }
 119   rs <- makeResolvSeed rc
 120
 121   let lookup_function = case cfg of
 122                           NS{} -> lookupNS'
 123                           MX{} -> lookupMX'
 124
 125   let lookup' d = withResolver rs $ \resolver ->
 126                     lookup_function resolver d
 127
 128   -- Construct a list of [IO whatever]. The withResolver calls
 129   -- are the ones that should be run in parallel.
 130   let actions = map lookup' nrml_domains
 131
 132   -- Run the lookup actions in parallel.
 133   results <- parallelInterleaved actions
 134
 135   -- Output the results.
 136   _ <- mapM (report nrml_delegates normalize_function) results
 137
 138   stopGlobalPool