{-# LANGUAGE BangPatterns #-}
{-# LANGUAGE DoAndIfThenElse #-}

module Main
where

import Control.Concurrent (threadDelay)
import Control.Exception.Base (bracket)
import Control.Monad (when)
import Data.List (isPrefixOf)
import Data.Maybe (isNothing)
import Data.Monoid ((<>))
import Network (
  connectTo,
  PortID (PortNumber) )
import System.Console.CmdArgs (def)
import System.Directory (doesFileExist)
import System.Exit (ExitCode(..), exitWith)
import System.FilePath ((</>))
import System.IO (
  BufferMode (NoBuffering),
  Handle,
  hClose,
  hGetChar,
  hGetLine,
  hPutStr,
  hSetBuffering,
  stderr,
  stdout )
import System.IO.Error (catchIOError)
import System.Timeout (timeout)

import CommandLine (get_args)
import Configuration (Configuration(..), merge_optional)
import ExitCodes (
  exit_no_feed_hosts,
  exit_no_password,
  exit_no_username )
import qualified OptionalConfiguration as OC (
  OptionalConfiguration(..),
  from_rc )
import Terminal (putGreenLn, report_error)
import TSN.FeedHosts (FeedHosts(..))
import TSN.Xml (parse_xmlfid, xml_prologue)


-- | Receive a single line of text from a Handle, echoing it to stdout
--   in the process.
--
recv_line :: Handle -> IO String
recv_line h = do
  line <- hGetLine h
  putStrLn line
  return line


-- | Takes a Configuration, and an XML document (as a String). The XML
--   document is written to the output directory, as specified by the
--   Configuration.
--
--   This can fail, but we don't purposefully throw any exceptions. If
--   something goes wrong, we would rather log it and keep going.
--
save_document :: Configuration -> String -> IO ()
save_document cfg doc =
  case maybe_path of
    Nothing ->
      report_error "ERROR: document missing XML_File_ID element."
    Just path -> do
      already_exists <- doesFileExist path
      when already_exists $ do
        let msg = "WARNING: file " ++ path ++ " already exists. Overwriting."
        report_error msg
      writeFile path doc
  where
    xmlfid = fmap show (parse_xmlfid doc)
    filename = fmap (++ ".xml") xmlfid
    maybe_path = fmap ((output_directory cfg) </>) filename


-- | Loop forever, writing the buffer to file whenever a new XML
--   prologue is seen. This is the low-level "loop forever" function
--   that we stay in as long as we are connected to one feed.
--
loop :: Configuration -> Handle -> [String] -> IO ()
loop !cfg !h !buffer = do
  line <- recv_line h

  if (xml_prologue `isPrefixOf` line && not (null buffer))
  then do
    -- This is the beginning of a new document, and we have an "old"
    -- one to save. The buffer is in reverse (newest first) order,
    -- though, so we have to reverse it first. We then concatenate all
    -- of its lines into one big string.
    let document = concat $ reverse buffer
    save_document cfg document
    loop cfg h [line] -- empty the buffer before looping again
  else
    -- append line to the head of the buffer and loop
    loop cfg h (line : buffer)


log_in :: Configuration -> Handle -> IO ()
log_in cfg h = do
  prompt1 <- recv_prompt h

  if prompt1 /= username_prompt then
    report_error "ERROR: didn't receive username prompt."
  else do
    send_line h (username cfg)
    prompt2 <- recv_prompt h

    if prompt2 /= password_prompt then
      report_error "ERROR: didn't receive password prompt."
    else do
      send_line h (password cfg)
      _ <- recv_line h -- "The Sports Network"
      return ()
  where
    username_prompt = "Username: "
    password_prompt = "Password: "

    send_line :: Handle -> String -> IO ()
    send_line h' s = do
      hPutStr h' (s ++ "\r\n")
      putGreenLn s

    recv_chars :: Int -> Handle -> IO String
    recv_chars n h' = do
      s <- sequence [ hGetChar h' | _ <- [1..n] ]
      putStr s
      return s

    recv_prompt :: Handle -> IO String
    recv_prompt = recv_chars 10

connect_and_loop :: Configuration -> String -> IO ()
connect_and_loop cfg host = do
  putStrLn $ "Connecting to " ++ host ++ "..."
  bracket acquire_handle release_handle action
  return ()
  where
    five_seconds :: Int
    five_seconds = 5000000

    acquire_handle = connectTo host (PortNumber 4500)
    release_handle = hClose
    action h = do
      -- No buffering anywhere.
      hSetBuffering h NoBuffering

      -- The feed is often unresponsive after we send out username. It
      -- happens in a telnet session, too (albeit less frequently?),
      -- so there might be a bug on their end.
      --
      -- If we dump the packets with tcpdump, it looks like their
      -- software is getting confused: they send us some XML in
      -- the middle of the log-in procedure. In any case, the easiest
      -- fix is to disconnect and try again.
      --
      login_worked <- timeout five_seconds $ log_in cfg h
      case login_worked of
        Nothing -> putStrLn "Login timed out (5s)."
        Just _ ->  loop cfg h []


-- | A wrapper around threadDelay which takes seconds instead of
--   microseconds as its argument.
--
thread_sleep :: Int -> IO ()
thread_sleep seconds = do
  let microseconds = seconds * (10 ^ (6 :: Int))
  threadDelay microseconds


-- | The entry point of the program.
main :: IO ()
main = do
  rc_cfg <- OC.from_rc
  cmd_cfg <- get_args

  -- Merge the config file options with the command-line ones,
  -- prefering the command-line ones.
  let opt_config = rc_cfg <> cmd_cfg

  -- This is necessary because if the user specifies an empty list of
  -- hostnames in e.g. the config file, we want to bail rather than
  -- fall back on the default list (which gets merged from a
  -- Configuration below).
  when (null $ get_feed_hosts (OC.feed_hosts opt_config)) $ do
    report_error "ERROR: no feed hosts supplied."
    exitWith (ExitFailure exit_no_feed_hosts)

  when (isNothing (OC.password opt_config)) $ do
    report_error "ERROR: no password supplied."
    exitWith (ExitFailure exit_no_password)

  when (isNothing (OC.username opt_config)) $ do
    report_error "ERROR: no username supplied."
    exitWith (ExitFailure exit_no_username)

  -- Finally, update a default config with any options that have been
  -- set in either the config file or on the command-line.
  let cfg = (def :: Configuration) `merge_optional` opt_config

  -- This may be superstition (and I believe stderr is unbuffered),
  -- but it can't hurt.
  hSetBuffering stderr NoBuffering
  hSetBuffering stdout NoBuffering

  -- Begin connecting to our feed hosts, starting with the first one.
  round_robin cfg 0

  where
    -- | This is the top-level "loop forever" function. If an
    --   exception is thrown, it will propagate up to this point, where
    --   it will be logged and ignored in style.
    --
    --   Afterwards, we recurse (call ourself) again to loop more forevers.
    --
    round_robin :: Configuration -> Int -> IO ()
    round_robin cfg feed_host_idx = do
      let hosts = get_feed_hosts $ feed_hosts cfg
      let host = hosts !! feed_host_idx
      catchIOError (connect_and_loop cfg host) (report_error . show)
      thread_sleep 10 -- Wait 10s before attempting to reconnect.
      round_robin cfg $ (feed_host_idx + 1) `mod` (length hosts)