{-# LANGUAGE TypeFamilies #-}

-- | General XML stuff.
--
module Xml (
  DtdName(..),
  FromXml(..),
  FromXmlFk(..),
  parse_opts,
  pickle_unpickle,
  unpickleable )
where

-- System imports.
import Control.Exception ( SomeException(..), catch )
import Database.Groundhog.Core ( DefaultKey )
import Text.XML.HXT.Core (
  (>>>),
  (/>),
  PU,
  SysConfigList,
  isElem,
  no,
  readDocument,
  runX,
  withRemoveWS,
  withValidate,
  xpickleVal,
  xunpickleVal,
  yes )


-- | A typeclass for XML types that can be converted into an
--   associated database type. The story behind this is long, but
--   basically, we need to different types most XML thingies we're
--   going to import: a database type and an XML type.
--
--   Both Groundhog and HXT are very particular about the types that
--   they can use, and there's no way to reuse e.g. a type that HXT
--   can pickle in Groundhog. This typeclass gives us a standard way
--   to get the database type from the XML type that we have to define
--   for HXT.
--
class FromXml a where
  -- | Each instance @a@ must declare its associated database type @Db a@.
  type Db a :: *

  -- | And provide a function for getting a @Db a@ out of an @a@.
  from_xml :: a -> Db a


-- | Some database types cannot be constructed from the XML type
--   alone; they must be supplied a foreign key to a parent object
--   first. Members of this class can be converted from an XML
--   representation to a database representation in this manner.
--
class FromXmlFk a where
  -- | Each instance @a@ must declare its associated database type @DbFk a@.
  type DbFk a :: *

  -- | The type of our parent object, i.e. to the type to whom our
  --   foreign key will point.
  type Parent a :: *

  -- | The function that produces a @DbFk a@ out of an @a@ and a foreign
  --   key.
  from_xml_fk :: a -> DefaultKey (Parent a) -> DbFk a


-- | Represents the DTD filename (\"SYSTEM\") part of the DOCTYPE
--   definition.
newtype DtdName = DtdName String

-- | A list of options passed to 'readDocument' when we parse an XML
--   document. All cosmetic whitespace should be removed, otherwise we
--   would have to parse whitespace in each (un)pickler.
--
parse_opts :: SysConfigList
parse_opts = [ withRemoveWS yes, withValidate no ]


-- | Given an @unpickler@ and a @filepath@, attempt to unpickle the
--   root element of @filepath@ using @unpickler@ and return both the
--   original unpickled object and one constructed by pickling and
--   unpickling that original. This is used in a number of XML tests
--   which pickle/unpickle and then make sure that the output is the
--   same as the input.
--
--   We return the object instead of an XmlTree (which would save us
--   an unpickle call) because otherwise the type of @a@ in the call
--   to 'xpickle' would be ambiguous. By returning some @a@s, we allow
--   the caller to annotate its type.
--
--   Note that this will happily pickle nothing to nothing and then
--   unpickle it back to more nothing. So the fact that the
--   before/after results from this function agree does not mean that
--   the document was successfully unpickled!
--
pickle_unpickle :: PU a -- ^ @unpickler@ returning an @a@
                -> FilePath -- ^ Path to the document to unpickle.
                -> IO ([a], [a])
pickle_unpickle unpickler filepath = do
  -- We need to check only the root message element since
  -- readDocument produces a bunch of other junk.
    expected <- runX arr_getobj
    actual <- runX $ arr_getobj
                     >>>
                     xpickleVal unpickler
                     >>>
                     xunpickleVal unpickler

    return (expected, actual)
  where
    arr_getobj = readDocument parse_opts filepath
                   />
                   isElem -- Drop the extra junk readDocument pulls in.
                   >>>
                   xunpickleVal unpickler



-- | Is the given XML file unpickleable? Unpickling will be attempted
--   using the @unpickler@ argument. If we unilaterally used the
--   generic 'xpickle' function for our unpickler, a type ambiguity
--   would result. By taking the unpickler as an argument, we allow
--   the caller to indirectly specify a concrete type.
--
--   Apologies the the name; unpickleable means \"we can unpickle
--   it\", not \"not pickleable.\"
--
unpickleable :: FilePath -> PU a -> IO Bool
unpickleable filepath unpickler = do
  xmldoc <- try_unpickle `catch` (\(SomeException _) -> return [])
  return $ (not . null) xmldoc
  where
    try_unpickle = runX $ readDocument parse_opts filepath
                          >>>
                          xunpickleVal unpickler