-- | (Un)picklers for data types present in The Sports Network XML
--   feed.
--
module TSN.Picklers (
  xp_date,
  xp_team_id )
where

import Data.Time.Clock ( UTCTime )
import Data.Time.Format ( formatTime, parseTime )
import System.Locale ( defaultTimeLocale )
import Text.Printf ( printf )
import Text.Read ( readMaybe )
import Text.XML.HXT.Arrow.Pickle (
  XmlPickler(..),
  xpText,
  xpWrapMaybe )
import Text.XML.HXT.Arrow.Pickle.Xml ( PU )

instance XmlPickler Bool where
  xpickle =
    (to_bool, from_bool) `xpWrapMaybe` xpText
    where
      to_bool :: String -> Maybe Bool
      to_bool = readMaybe

      from_bool :: Bool -> String
      from_bool = show


-- | (Un)pickle a UTCTime without the time portion.
--
xp_date :: PU UTCTime
xp_date =
  (to_date, from_date) `xpWrapMaybe` xpText
  where
    format = "%-m/%-d/%Y"

    to_date :: String -> Maybe UTCTime
    to_date = parseTime defaultTimeLocale format

    from_date :: UTCTime -> String
    from_date = formatTime defaultTimeLocale format


-- | Parse a team_id. This *should* just be an 'Int', but TSN is doing
--   something weird. First of all, player IDs do look like normal
--   'Int's. But the team IDs are all stuck in the triple digits, and
--   double-digit team IDs appear to be padded to three characters
--   with a leading '0'. So maybe they're treating these as text?
--
--   In any case, we do the simplest thing that is correct for all the
--   XML we've got: pad it to (only) three digits on pickling.
--
xp_team_id :: PU Int
xp_team_id =
  (to_team_id, from_team_id) `xpWrapMaybe` xpText
  where
    to_team_id :: String -> Maybe Int
    to_team_id = readMaybe

    from_team_id :: Int -> String
    from_team_id = printf "%03d"