{-# LANGUAGE NoMonomorphismRestriction #-}
{-# LANGUAGE DoAndIfThenElse #-}
module Main
where

import Control.Arrow ( (&&&), arr, returnA )
import Control.Concurrent ( threadDelay )
import Control.Exception ( SomeException, catch )
import Control.Monad ( when )
import Database.Groundhog.Generic ( runDbConn )
import Database.Groundhog.Sqlite (
  withSqliteConn )
import Database.Groundhog.Postgresql (
  withPostgresqlConn )
import Data.Monoid ( (<>) )
import Network.Services.TSN.Logging ( init_logging )
import System.Console.CmdArgs ( def )
import System.Directory ( removeFile )
import System.Exit ( exitWith, ExitCode (ExitFailure) )
import System.IO.Error ( catchIOError )
import Text.XML.HXT.Core (
  ArrowXml,
  IOStateArrow,
  XmlTree,
  (>>>),
  (/>),
  getAttrl,
  getText,
  hasName,
  readDocument,
  runX )

import Backend ( Backend(..) )
import CommandLine ( get_args )
import Configuration ( Configuration(..), merge_optional )
import ConnectionString ( ConnectionString(..) )
import ExitCodes ( exit_no_xml_files )
import qualified OptionalConfiguration as OC (
  OptionalConfiguration ( xml_files ),
  from_rc )
import Network.Services.TSN.Report (
  report_info,
  report_error )
import TSN.DbImport ( DbImport(..), ImportResult(..) )
import qualified TSN.XML.Heartbeat as Heartbeat ( verify )
import qualified TSN.XML.Injuries as Injuries ( Listing )
import qualified TSN.XML.InjuriesDetail as InjuriesDetail ( PlayerListing )
import qualified TSN.XML.News as News ( Message )
import Xml ( parse_opts )



import_file :: Configuration -> FilePath -> IO Bool
import_file cfg path = do
  results <- parse_and_import `catch` exception_handler
  case results of
    -- If results' is empty, one of the arrows return "nothing."
    []    -> do
      report_error $ "Unable to determine DTD for file " ++ path ++ "."
      return False
    (Err errmsg:_) -> do
      report_error errmsg
      return False
    (Info infomsg:_) -> do
      report_info infomsg
      return True
    (Succ count:_) -> do
      report_info $ "Successfully imported " ++ (show count) ++
                    " records from " ++ path ++ "."
      return True
  where
    exception_handler :: SomeException -> IO [ImportResult]
    exception_handler e = do
      report_error (show e)
      let errdesc = "Failed to import file " ++ path ++ "."
      -- Return a nonempty list so we don't claim incorrectly that
      -- we couldn't parse the DTD.
      return [Err errdesc]

    -- | An arrow that reads a document into an 'XmlTree'.
    readA :: IOStateArrow s a XmlTree
    readA = readDocument parse_opts path

    -- | An arrow which parses the doctype "SYSTEM" of an 'XmlTree'.
    --   We use these to determine the parser to use.
    doctypeA :: ArrowXml a => a XmlTree String
    doctypeA = getAttrl >>> hasName "doctype-SYSTEM" /> getText

    -- | Combine the arrows above as well as the function below
    --   (arrowized with 'arr') into an IO action that does everything
    --   (parses and then runs the import on what was parsed).
    --
    --   The result of runX has type IO [IO ImportResult]. We thus use
    --   bind (>>=) and sequence to combine all of the IOs into one
    --   big one outside of the list.
    parse_and_import :: IO [ImportResult]
    parse_and_import =
      runX (readA >>> (doctypeA &&& returnA) >>> (arr import_with_dtd))
      >>=
      sequence

    -- | Takes a 'Doctype', 'XmlTree' pair and uses the 'Doctype' to
    --   determine which function to call on the 'XmlTree'.
    import_with_dtd :: (String, XmlTree) -> IO ImportResult
    import_with_dtd (dtd,xml)
      | dtd == "Heartbeat.dtd" = Heartbeat.verify xml
      | otherwise =
        -- We need NoMonomorphismRestriction here.
        if backend cfg == Postgres
        then withPostgresqlConn cs $ runDbConn $ importer xml
        else withSqliteConn cs $ runDbConn $ importer xml
        where
          -- | Pull the real connection String out  of the configuration.
          cs :: String
          cs = get_connection_string $ connection_string cfg

          importer
            | dtd == "injuriesxml.dtd" =
                dbimport (undefined :: Injuries.Listing)

            | dtd == "Injuries_Detail_XML.dtd" =
                dbimport (undefined :: InjuriesDetail.PlayerListing)

            | dtd == "newsxml.dtd" =
                dbimport (undefined :: News.Message)

            | otherwise = \_ -> do -- Dummy arg simplifies the other cases.
              let infomsg =
                    "Unrecognized DTD in " ++ path ++ ": " ++ dtd ++ "."
              return $ Info infomsg


main :: IO ()
main = do
  rc_cfg <- OC.from_rc
  cmd_cfg <- get_args

  -- Merge the config file options with the command-line ones,
  -- prefering the command-line ones.
  let opt_config = rc_cfg <> cmd_cfg

  -- Update a default config with any options that have been set in
  -- either the config file or on the command-line.  We initialize
  -- logging before the missing parameter checks below so that we can
  -- log the errors.
  let cfg = (def :: Configuration) `merge_optional` opt_config
  init_logging (log_file cfg) (log_level cfg) (syslog cfg)

  -- Check the optional config for missing required options.
  when (null $ OC.xml_files opt_config) $ do
    report_error "No XML files given."
    exitWith (ExitFailure exit_no_xml_files)

  -- We don't do this in parallel (for now?) to keep the error
  -- messages nice and linear.
  results <- mapM (import_file cfg) (OC.xml_files opt_config)

  -- Zip the results with the files list to find out which ones can be
  -- deleted.
  let result_pairs = zip (OC.xml_files opt_config) results
  let victims = filter (\(_,result) -> result) result_pairs
  mapM_ ((kill True) . fst) victims

  where
    kill try_again path = do
      removeFile path `catchIOError` exception_handler
      report_info $ "Removed imported file " ++ path ++ "."
      where
        -- | A wrapper around threadDelay which takes seconds instead of
        --   microseconds as its argument.
        thread_sleep :: Int -> IO ()
        thread_sleep seconds = do
          let microseconds = seconds * (10 ^ (6 :: Int))
          threadDelay microseconds

        exception_handler :: IOError -> IO ()
        exception_handler e = do
          report_error (show e)
          report_error $ "Failed to remove imported file " ++ path ++ "."
          if try_again then do
            report_info $ "Waiting 5 seconds to attempt removal again..."
            thread_sleep 5
            kill False path
          else
            report_info $ "Giving up on " ++ path ++ "."