X-Git-Url: http://gitweb.michael.orlitzky.com/?a=blobdiff_plain;f=net-dns%2Frbldnsd%2Frbldnsd-0.997a.ebuild;fp=net-dns%2Frbldnsd%2Frbldnsd-0.997a.ebuild;h=6011b000e5e3b964346d25bc1e17c1db25fa3d51;hb=d6bb6525447b7a8c3f20e1f40c0a96ecf24de0f7;hp=0000000000000000000000000000000000000000;hpb=3c2cde2ad4e7d7fc26fbe3db8020bcedc02531d4;p=mjo-overlay.git

diff --git a/net-dns/rbldnsd/rbldnsd-0.997a.ebuild b/net-dns/rbldnsd/rbldnsd-0.997a.ebuild
new file mode 100644
index 0000000..6011b00
--- /dev/null
+++ b/net-dns/rbldnsd/rbldnsd-0.997a.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-dns/rbldnsd/rbldnsd-0.997.ebuild,v 1.3 2013/09/05 18:59:06 mgorny Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python{2_6,2_7} )
+
+inherit eutils toolchain-funcs user python-single-r1
+
+DESCRIPTION="DNS server designed to serve blacklist zones"
+HOMEPAGE="http://www.corpit.ru/mjt/rbldnsd.html"
+SRC_URI="http://www.corpit.ru/mjt/rbldnsd/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~sparc ~x86 ~x86-fbsd"
+IUSE="ipv6 test zlib"
+
+RDEPEND="zlib? ( sys-libs/zlib )"
+DEPEND="${RDEPEND}
+	test? ( ${PYTHON_DEPS}
+		dev-python/pydns:2[${PYTHON_USEDEP}] )"
+
+src_prepare() {
+	epatch "${FILESDIR}/${P}-robust-ipv6-test-support.patch"
+}
+
+src_configure() {
+	# The ./configure file is handwritten and doesn't support a `make
+	# install` target, so there are no --prefix options. The econf
+	# function appends those automatically, so we can't use it.
+	./configure \
+		$(use_enable ipv6) \
+		$(use_enable zlib) \
+		|| die "./configure failed"
+}
+
+src_compile() {
+	emake \
+		AR="$(tc-getAR)" \
+		CC="$(tc-getCC)" \
+		RANLIB="$(tc-getRANLIB)"
+}
+
+src_test() {
+	emake check \
+		CC="$(tc-getCC)" \
+		PYTHON="${PYTHON}"
+}
+
+src_install() {
+	dosbin rbldnsd
+	doman rbldnsd.8
+	keepdir /var/db/rbldnsd
+	dodoc CHANGES* TODO NEWS README*
+	newinitd "${FILESDIR}"/initd-${PV} rbldnsd
+	newconfd "${FILESDIR}"/confd-${PV} rbldnsd
+}
+
+pkg_postinst() {
+	enewgroup rbldns
+	enewuser rbldns -1 -1 /var/db/rbldnsd rbldns
+	chown rbldns:rbldns /var/db/rbldnsd
+}