configure.ac

   1 AC_INIT([libsvgtiny-pixbuf],[0.0.1],[michael@orlitzky.com])
   2 AC_CONFIG_AUX_DIR([build-aux])
   3 AM_INIT_AUTOMAKE([-Wall foreign no-dist-gzip dist-xz tar-ustar])
   4 AC_CONFIG_MACRO_DIRS([m4])
   5
   6 AC_PROG_CC
   7 AM_PROG_AR
   8
   9 PKG_CHECK_MODULES([CAIRO], [cairo])
  10 PKG_CHECK_MODULES([GDKPIXBUF], [gdk-pixbuf-2.0])
  11 PKG_CHECK_MODULES([GTK4], [gtk4])
  12 PKG_CHECK_MODULES([LIBSVGTINY], [libsvgtiny])
  13 PKG_CHECK_MODULES([LIBXML2], [libxml-2.0])
  14
  15 AC_MSG_CHECKING([for gdk-pixbuf module location])
  16 # Hack alert: we need to install our module into this specific
  17 # location... BUT, we also want to respect --prefix, at least to the
  18 # extent that we won't try to install something to, say, /usr when
  19 # we've passed --prefix=/tmp. This little libdir trick prevents
  20 # pkg-config from substituting for ${libdir} where it appears in the
  21 # *.pc file. When we go to actually use gdk_pixbuf_moduledir, the
  22 # variable ${libdir} will be valid in our own build system, and will
  23 # respect the prefix. This means that if you configure this package
  24 # with a different prefix than gdk-pixbuf was, it won't install
  25 # correctly. But hey, make distcheck works?
  26 gdk_pixbuf_moduledir=$($PKG_CONFIG --define-variable=libdir="\${libdir}" --variable gdk_pixbuf_moduledir gdk-pixbuf-2.0)
  27 AC_MSG_RESULT([$gdk_pixbuf_moduledir])
  28 AC_SUBST([gdk_pixbuf_moduledir])
  29
  30 AC_MSG_CHECKING([for gdk-pixbuf-thumbnailer location])
  31 gdk_pixbuf_bindir=$($PKG_CONFIG --variable bindir gdk-pixbuf-2.0)
  32 gdk_pixbuf_thumbnailer="${gdk_pixbuf_bindir}/gdk-pixbuf-thumbnailer"
  33
  34 AS_IF([test -x "${gdk_pixbuf_thumbnailer}"], [
  35   AC_MSG_RESULT([$gdk_pixbuf_thumbnailer])
  36   AC_SUBST([gdk_pixbuf_thumbnailer])
  37 ],[
  38   AC_MSG_RESULT([no])
  39 ])
  40
  41
  42 AC_CONFIG_FILES([
  43   Makefile
  44   libsvgtiny.thumbnailer
  45 ])
  46
  47 LT_INIT([disable-static])
  48 AC_OUTPUT